Arch Linux User Repository

I kept the old qt5+x11 branch in https://github.com/gbin/Projecteur/tree/legacy/qt5 so we can still patch it for security or compatibility.

We might want to reenable at least Gnome on the main dev but x11 at this point we are better off leaving that as legacy, the codepath are completely diverged with the way we use a video capture now + shaders.

@gbin Thanks a lot for picking up the upstream project !

I picked up this package from m4dz a while ago while it was orphaned.

I saw wayland as part of the dependencies in your proposed PKGBUILD, but I have personally been using it with Xorg so far.

Does the package still support / compile for Xorg as it is ? I will look into it when I get some time, but asking you now in the meantime.

EDIT: Ok I saw the note on the develop branch of the new upstream about KD6 / Wayland.

Will probably to split this into a legacy package that still works with X and the new one you are working on that mainly targets Wayland.

Cheers !

Hi @m4dz, I took over the project from Jahnf, the project had been transferred and now hosted at https://github.com/gbin/Projecteur and the git version should look more like this as I focused first on putting 100% in line with a KDE/qt6 application.

Thanks for your help maintaining arch packages!

Feel free to ping me if you have any questions or if you see I did something stupid somewhere.

pkgname=projecteur-git
pkgver=1.0.0alpha.77.r723.8f187bf
pkgrel=1
pkgdesc='Virtual laser pointer for inertial pointer devices on KDE Plasma Wayland'
arch=('x86_64')
url='https://github.com/gbin/Projecteur'
license=('MIT')
depends=(
  'glibc'
  'hicolor-icon-theme'
  'kcolorscheme>=6.7'
  'kconfig>=6.7'
  'kconfigwidgets>=6.7'
  'kcoreaddons>=6.7'
  'kdbusaddons>=6.7'
  'kglobalaccel>=6.7'
  'kguiaddons>=6.7'
  'ki18n>=6.7'
  'kirigami>=6.7'
  'knotifications>=6.7'
  'kpipewire>=6.7'
  'kwidgetsaddons>=6.7'
  'kwindowsystem>=6.7'
  'kxmlgui>=6.7'
  'layer-shell-qt>=6.7'
  'libgcc'
  'libglvnd'
  'libplasma>=6.7'
  'libstdc++'
  'qt6-base>=6.10'
  'qt6-declarative>=6.10'
  'qt6-wayland>=6.10'
  'udev'
  'wayland'
)
makedepends=(
  'cmake>=3.20'
  'extra-cmake-modules>=6.7'
  'gettext'
  'git'
  'qt6-shadertools>=6.10'
)
provides=('projecteur')
conflicts=('projecteur')
source=('projecteur::git+https://github.com/gbin/Projecteur.git#branch=develop')
sha256sums=('SKIP')

prepare() {
  cmake -S "$srcdir/projecteur" -B "$srcdir/build" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_UDEVRULESDIR=/usr/lib/udev/rules.d \
    -DPACKAGE_TARGETS=OFF
}

pkgver() {
  cd "$srcdir/projecteur"
  printf '%s.r%s.%s' \
    "$(<"$srcdir/build/version-string.archlinux")" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short=7 HEAD)"
}

build() {
  cmake --build "$srcdir/build"
}

package() {
  DESTDIR="$pkgdir" cmake --install "$srcdir/build"
  install -Dm644 "$srcdir/projecteur/LICENSE.md" \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

Did not build with qt6 for me. Using qt5 (-DPROJECTEUR_QT_VERSION:STRING="5" in prepare() of PKGBUILD) worked.

Error was qt_generate_foreign_qml_types() is only available in Qt 6.