Arch Linux User Repository

Update PKGBUILD

pkgname='proot-git'
_pkgname='proot'
pkgver=5.4.0.r2.g5f780cb
pkgrel=1
pkgdesc='chroot, mount --bind, and binfmt_misc without privilege/setup'
arch=('any')
url='https://proot-me.github.io'
license=('GPL')
provides=('proot')
conflicts=('proot' 'proot-bin')
depends=('talloc' 'python')
makedepends=('python-docutils' 'libxslt' 'python-libseccomp')
source=("git+https://github.com/proot-me/${_pkgname}.git")
sha1sums=('SKIP')

pkgver() {
    cd "$srcdir/${_pkgname}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}


build() {
    cd "${srcdir}/${_pkgname}/src"
    make -f GNUmakefile

    cd "${srcdir}/${_pkgname}/doc"
    make -f GNUmakefile
}

package() {
    cd "${srcdir}/${_pkgname}"

    install -m755 -d "${pkgdir}/usr/bin"
    install -m755 "src/${_pkgname}" "${pkgdir}/usr/bin"

    install -m755 -d "${pkgdir}/usr/share/man/man1/"
    install -m644 -T 'doc/proot/man.1' "${pkgdir}/usr/share/man/man1/${_pkgname}.1"

    install -m755 -d "${pkgdir}/usr/share/doc/proot/"

    install -m644 'CHANGELOG.rst' "${pkgdir}/usr/share/doc/proot"
    install -m644 'doc/proot/index.html' "${pkgdir}/usr/share/doc/proot"
    install -m644 'doc/proot/manual.rst' "${pkgdir}/usr/share/doc/proot"

    install -m755 -d "${pkgdir}/usr/share/doc/proot/stylesheets"
    install -m644 'doc/proot/stylesheets/'* "${pkgdir}/usr/share/doc/proot/stylesheets"
}

install: cannot stat 'doc/proot/changelog.rst': No such file or directory this is still an issue

This will definitely built successfully on the other architectures than just i686 and x86_64...

You should use any architecture in the PKGBUILD in my opinion instead of typing the specific architectures.

Failing just on package with:

==> Starting package()...
install: cannot stat 'doc/proot/changelog.txt': No such file or directory

Could it be possible to add aarch64 architecture?

I can confirm the package builds succesfully and seems to be working properly.

(Might also work on other arm architectures.)