Arch Linux User Repository

Build fails with BlueZ requires SBC support.

Adding sbc to make dependencies should fix it

I'm seeing the following while trying to build 0.5-2 in chroot:

:: Running post-transaction hooks...
(1/3) Arming ConditionNeedsUpdate...
(2/3) Warn about old perl modules
(3/3) Updating the info directory file...
==> Retrieving sources...
  -> Found pulseaudio-module-xrdp-0.5.tar.gz
  -> Downloading pulseaudio-.tar.xz...
  % Total    % Received % Xferd  Average Speed   Time    Time     Time  Current
                                 Dload  Upload   Total   Spent    Left  Speed
  0   278    0     0    0     0      0      0 --:--:-- --:--:-- --:--:--     0
curl: (22) The requested URL returned error: 404
==> ERROR: Failure while downloading https://freedesktop.org/software/pulseaudio/releases/pulseaudio-.tar.xz
    Aborting...

I believe the _pulseaudio_ver=$(pulseaudio --version | awk '{print $NF}') line is returning empty due to the chroot, so perhaps pulseaudio should be a makedepends?

If anyone's trying to debug why sound isn't working, I added some fixes to the wiki.

Here is fix.

# Maintainer: kballen <ken@kballentine.net>

pkgname=pulseaudio-module-xrdp
pkgver=0.5
pkgrel=1
pkgdesc="PulseAudio modules for xrdp"
arch=('i686' 'x86_64')
url="https://github.com/neutrinolabs/pulseaudio-module-xrdp"
license=('Apache')
depends=('pulseaudio' 'xrdp')
makedepends=('libasyncns' 'libcap' 'attr' 'libxtst' 'libsm' 'libsndfile' 'rtkit' 'libsoxr'
    'speexdsp' 'tdb' 'systemd' 'dbus' 'avahi' 'bluez' 'bluez-libs' 'jack2' 'sbc' 
    'lirc' 'openssl' 'fftw' 'orc' 'gtk3' 'webrtc-audio-processing' 'check' 'git' 'meson'
    'xmltoman' 'valgrind' 'doxygen')

source=("${pkgname}-${pkgver}.tar.gz::https://github.com/neutrinolabs/${pkgname}/archive/v${pkgver}.tar.gz"
        "git+https://github.com/pulseaudio/pulseaudio.git"
        "xrdp-script.conf")
sha256sums=('2fdda7b21293941dd671ee2a3557b904e3137eec062f4655a247fe60a4f7b0d1'
            'SKIP'
            '4c6e9c0b1eaf66ea6b8574570d89b292b8554d318ad324f3763f837013b9f44f')

prepare() {
    cd "$srcdir/pulseaudio"
    git checkout v`pkg-config libpulse --modversion|sed 's/[^0-9.]*\([0-9.]*\).*/\1/'`

    cd "$srcdir"

    local meson_options=(
      -D stream-restore-clear-old-devices=true
      -D pulsedsp-location='/usr/\$LIB/pulseaudio'
      -D udevrulesdir=/usr/lib/udev/rules.d
      -D bluez5-gstreamer=disabled
      -D elogind=disabled
      -D tcpwrap=disabled
    )

    arch-meson pulseaudio "$srcdir"/pulseaudio/build "${meson_options[@]}"
    meson compile -C "$srcdir"/pulseaudio/build

    cp -a "$srcdir"/pulseaudio/src/. "$srcdir"/pulseaudio/build/src/
}

build() {
    cd "$srcdir/${pkgname}-${pkgver}"
    ./bootstrap
    ./configure "PULSE_DIR=$srcdir/pulseaudio/build"
    make
}

package() {
    cd "$srcdir/${pkgname}-${pkgver}"
    make DESTDIR="$pkgdir" install

    # This package installs a global drop-in conf for pulseaudio.service to use the xrdp default.pa script instead of
    # the script from the pulseaudio package. If your only desktop sessions will be via xrdp, this should be fine. But
    # if you want to start local sessions too, this will prevent the real audio devices from being detected. If this is
    # a problem for you, delete the drop-in conf file and roll your own solution for loading the xrdp modules for xrdp
    # sessions only (maybe add PULSE_SCRIPT to the user systemd's environment in startwm.sh and create a drop-in for
    # pulseaudio.service that adds PassEnvironment=PULSE_SCRIPT).
    install -Dm644 "$srcdir"/xrdp-script.conf "$pkgdir"/usr/lib/systemd/user/pulseaudio.service.d/xrdp-script.conf
}

sha256sum for v0.5 is: 2fdda7b21293941dd671ee2a3557b904e3137eec062f4655a247fe60a4f7b0d1

please update

"yay --editmenu -Syu pulseaudio-module-xrdp" to install, then update the first sha256sum to:e504d90676c0dd9b9f069b60790f8feb0cc929e2ab1cb1f864c3a49850bed93b

checksum is not updated!