Package Details: python-bencoder-pyx 3.0.1-1

Git Clone URL: https://aur.archlinux.org/python-bencoder-pyx.git (read-only, click to copy)
Package Base: python-bencoder-pyx
Description: Fast bencode implementation in Cython
Upstream URL: https://github.com/whtsky/bencoder.pyx
Keywords: bencode cython python torrent
Licenses: BSD
Submitter: dbermond
Maintainer: cgarz
Last Packager: cgarz
Votes: 1
Popularity: 0.000000
First Submitted: 2019-11-30 17:25 (UTC)
Last Updated: 2024-04-14 04:07 (UTC)

Latest Comments

username227 commented on 2026-01-11 03:47 (UTC) (edited on 2026-01-11 03:48 (UTC) by username227)

for those that need to rebuild for the new python, I got it to work by altering the repo source and making minor changes: 

# Maintainer: cgar <notify-cgar -AT- outlook -DOT- com>
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Daniel Bermond <dbermond@archlinux.org>

pkgname=python-bencoder-pyx
_name=bencoder.pyx
pkgver=3.0.1
pkgrel=2
pkgdesc='Fast bencode implementation in Cython'
arch=('x86_64')
url='https://github.com/3nprob/bencoder.pyx'
license=('BSD')
depends=('python')
makedepends=(
    'cython'
    'python-build'
    'python-installer'
    'python-setuptools'
    'python-wheel')
checkdepends=('python-pytest')
source=("git+https://github.com/3nprob/bencoder.pyx#branch=python3.13")
sha256sums=("SKIP")

prepare() {
    cd "$_name"
    sed -i '/extra_compile_args/s/O3/O2/' setup.py
    sed -i '/requires/s/==/>=/' pyproject.toml
}

build() {
    cd "$_name"
    python -m build --wheel --no-isolation
}

check() {
    cd "$_name"
    local _pyver
    _pyver="$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')"
    PYTHONPATH="$(pwd)/build/lib.linux-$(uname -m)-cpython-${_pyver}" pytest -x
}

package() {
    cd "$_name"
    PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir" dist/*.whl

    local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
    install -d "$pkgdir/usr/share/licenses/$pkgname/"
    ln -s \
        "$_site/$_name-$pkgver.dist-info/LICENSE" \
        "$pkgdir/usr/share/licenses/$pkgname/"
}

Don't worry, it'll still build for python 3.14 even though the branch is 3.13.

xAsh commented on 2025-08-01 04:44 (UTC) (edited on 2025-08-01 04:45 (UTC) by xAsh)

Package currently borken (https://github.com/whtsky/bencoder.pyx/issues/143#issue-3053339996)