Arch Linux User Repository

@not_anonymous You could have done it 4 months ago, the new upstream release is not relevant to your argument.

And the PKGBUILD is still not as it should be, you should not call setup.py and source should be switched to the GitHub archive as I wrote before. Thy PyPI tarball does not contain any tests, and branca uses pytest rather than nosetests now.

Nobody has been ignored here in these comments...PLUS corrections were made upstream PLUS a new version has come out....so the PKGBUILD is now as it should be (and once was) ala the archlinux python packaging guidelines !!

It builds fine for me when I switch to GitHub, except the tests don't pass (and PyPI tarballs do not actually contain any tests). The RFC0020 is accepted, otherwise it wouldn't be published. You should also avoid calling setup.py directly according to the guidelines.

I'll leave my best PKGBUILD here, have to go to work...

# Maintainer: not_anonymous <nmlibertarian@gmail.com>
# Contributor: Jakub Klinkovský <lahwaacz at archlinux dot org>
# Contributor: Guillaume Horel <guillaume.horel@gmail.com>

pkgname=python-branca
_pkgname=branca
pkgver=0.8.0
pkgrel=1
pkgdesc="Generate HTML+JS with Python"
arch=(any)
url="https://github.com/python-visualization/branca"
license=(MIT)
depends=(python python-jinja python-pandas python-numpy)
makedepends=(python-build python-installer python-wheel python-setuptools-scm)
checkdepends=(jupyter-nbconvert python-pytest python-selenium geckodriver)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
b2sums=('46779d59ca981c1f6e76193b1776c77a7c455b67d93115027b17f96b8c4df737502dc32feb6ce242e0f2fec9ed4541ed79c6856e85d740dec40d092000873b32')

build() {
    cd "$_pkgname-$pkgver"
    SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver python -m build --wheel --no-isolation
}

check() {
    cd "$_pkgname-$pkgver"
    # tests expect the package to actually be installed, so here's a temporary environment
    python -m installer --destdir="$PWD/tmp_install" dist/*.whl
    local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
    PYTHONPATH="$PWD/tmp_install/${site_packages}:$PYTHONPATH" \
    PATH="$PWD/tmp_install/usr/bin:${PATH}" \
    pytest
}

package() {
    cd "$_pkgname-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
}

Well...yeah....and I did try the tarball. I couldn't get it to work.

Um, has the RFC been adopted or is it still a request ?

@not_anonymous: Did you read the note on the wiki and RFC0020?

I read through the link to the arch wiki you provided lahwaacz. The examples of what to use for the source array are ALSO from pythonhosted, as is mine ! NONETHELESS, I did try the compile using the github files and ran into problems with not id-ing scm. SO, if you have an example of a way to compile this; outstanding !

Um, OR I suggest we let the python-branca folks fix their release numbering issues. (or ??)

ALSO; many-thanks for rejecting the orphan request. I appreciate your input both on where to get the files and for your insight.

So the 0.8.0 releease is currently missing on PyPI. The source tarballs for 0.7.2 on GitHub and PyPI are actually almost the same, with small difference in setup.cfg and GitHub providing the tests and documentation, which are missing in the PyPI tarball. Why don't you switch to GitHub for the 0.8.0 release? Using PyPI as source for Python packages in Arch is actually discouraged: https://wiki.archlinux.org/title/Python_package_guidelines#Source

Edit: the sha256sum for v0.8.0.tar.gz from GitHub is d267864fb30d3e00c54fe5d9d3e9a9040a81f81d0516d077d12dd5b0619aa6fe, it does not contain a "different project directory". Probably something went wrong with your download...

Well...the "upstream" problem is that while the current version's tarball is 0.8.0 labeled as such, INSIDE it has a different name for the project directory !!

AND, someone wanted to take over the package, from me, because I was waiting for the project3 to correct this anomaly.

SO... I punted !!!

@not_anonymous Why did you add _pkgver=0.7.2 and set pkgver=0.8.0? There is an actual 0.8.0 release and the source is not the same as previous release(s).

Updated via a work-around....SIGH