Package Details: python-clickhouse-connect 0.8.15-1

Git Clone URL: https://aur.archlinux.org/python-clickhouse-connect.git (read-only, click to copy)
Package Base: python-clickhouse-connect
Description: A high performance core database driver for connecting ClickHouse to Python, Pandas, and Superset
Upstream URL: https://github.com/ClickHouse/clickhouse-connect
Licenses: Apache-2.0
Submitter: Felixoid
Maintainer: Felixoid
Last Packager: Felixoid
Votes: 1
Popularity: 0.72
First Submitted: 2022-12-15 13:21 (UTC)
Last Updated: 2025-03-27 10:56 (UTC)

Latest Comments

Felixoid commented on 2025-03-27 10:57 (UTC)

Thanks, I used the most of your changes to update it

a.kudelin commented on 2025-03-18 13:11 (UTC)

An updated PKGBUILD: 

# Maintainer: Mikhail felixoid Shiryaev <mr dot felixoid on gmail>

_pyname=clickhouse-connect
pkgname=python-$_pyname
pkgver=0.8.15
pkgrel=1
pkgdesc='Python driver/sqlalchemy/superset connectors'
arch=(any)
url='https://github.com/ClickHouse/clickhouse-connect'
makedepends=(python-setuptools python-build python-installer python-wheel cython)
depends=(python-requests python-pytz python-lz4 python-zstandard python-certifi)
checkdepends=(python-pytest-asyncio python-sqlalchemy python-pandas)
license=(Apache-2.0)
source=($pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz)
sha256sums=("3b90502ec2ce320b0e57a87d58ecb75570ff7bbdda301c590645182aab9011f4")

build() {
  cd "$srcdir/$_pyname-$pkgver"
  python -m build \
    --wheel \
    --no-isolation \
    --skip-dependency-check
}

check() {
  cd "$srcdir/$_pyname-$pkgver"

  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl

  mv clickhouse_connect $_pyname-orig

  test-env/bin/python -m pytest tests/unit_tests
}

package() {
  cd "$srcdir/$_pyname-$pkgver"
  python -m installer \
    --destdir="$pkgdir" \
    --compile-bytecode=2 \
    dist/*.whl
}