Arch Linux User Repository

Hi, I'm having the following problem:

💥 maturin failed
  Caused by: Cargo metadata failed. Does your crate compile with `cargo build`?
  Caused by: `cargo metadata` exited with an error: cargo: error while loading shared libraries: libssl.so.3: cannot open shared object file: No such file or directory

Any help would be appreciated. Thank you!

And checkdepends should contain python-hypothesis. Here’s a working PKGBUILD:

# Maintainer: Guillaume Horel <guillaume.horel@gmail.com>

pkgname=python-cramjam
_pkgname=cramjam
pkgver=2.5.0
pkgrel=1
pkgdesc="Thin Python bindings to de/compression algorithms in Rust"
arch=('x86_64')
url="https://github.com/milesgranger/pyrus-cramjam"
license=('MIT')
depends=('python')
checkdepends=('python-memory-profiler' 'python-pytest' 'python-hypothesis')
optdepends=()
makedepends=(python-installer maturin rust)
source=("https://files.pythonhosted.org/packages/source/${_pkgname::1}/$_pkgname/$_pkgname-$pkgver.tar.gz")
sha256sums=('a92c0c2db4c6a3804eaffa253c7ca49f849e7a893a31c902a8123d7c36b2b487')

build(){
  cd "$_pkgname-$pkgver"
  maturin build --release --strip --interpreter python 
}

package(){
  cd "$_pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" target/wheels/*.whl
  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}

check() {
  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")

  cd $_pkgname-$pkgver
  rm -rf test_dir
  python -m installer --destdir=test_dir target/wheels/*.whl
  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
  pytest -vv tests
}

# vim:ts=2:sw=2:et:

Also the URL is wrong, should be https://github.com/milesgranger/pyrus-cramjam

This is broken:

error: Found argument '--no-sdist' which wasn't expected, or isn't valid in this context

        Did you mean '--sdist'?

        If you tried to supply `--no-sdist` as a value rather than a flag, use `-- --no-sdist`

USAGE:
    maturin build --release --sdist

For more information try --help