Package Details: python-mattermostdriver 7.3.2-1

Git Clone URL: https://aur.archlinux.org/python-mattermostdriver.git (read-only, click to copy)
Package Base: python-mattermostdriver
Description: Python Mattermost Driver for APIv4
Upstream URL: https://vaelor.github.io/python-mattermost-driver/
Licenses: MIT
Submitter: linkmauve
Maintainer: bleak
Last Packager: bleak
Votes: 1
Popularity: 0.000000
First Submitted: 2017-09-19 18:39 (UTC)
Last Updated: 2022-02-02 11:56 (UTC)

Latest Comments

Xyne commented on 2022-01-02 22:09 (UTC)

The recent update to Python 3.10 broke the mattermostdriver websocket for me. This is an upstream error but here's a patch and updated PKGBUILD to work around it until it's updated.

PKGBUILD

# Maintainer: bleak <bleaktradition@gmail.com>

pkgname=python-mattermostdriver
pkgver=7.3.1
pkgrel=2
pkgdesc="Python Mattermost Driver for APIv4"
arch=('any')
url="https://vaelor.github.io/python-mattermost-driver/"
license=('MIT')
depends=('python' 'python-requests' 'python-websockets')
makedepends=('python-setuptools')
source=(
  "$pkgname-$pkgver.tar.gz::https://github.com/Vaelor/python-mattermost-driver/archive/refs/tags/$pkgver.tar.gz"
  ssl_context.patch
)
_extracted_name="python-mattermost-driver"
sha512sums=('da0392df5cbb044f84ff1e8d53db7b229aacf26ad77fbafaeb649e407e0bc2e5425852283752ae4693f701e35ee20d434cf16aa542bc323af776ecaaf59a9bd7'
            '20c6e47422d3780450b2d245b19a8306f767dc2979d2b25e90aed02d25bf3b4dc6d2468c171d322fe058a30e8b83411f42c0f775576773754c90647279ec2b3d')

prepare() {
  patch "$_extracted_name-$pkgver/src/mattermostdriver/websocket.py" < ssl_context.patch
}

build() {
  cd "$_extracted_name-$pkgver"
  python setup.py build
}

package() {
  cd "$_extracted_name-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:ts=2:sw=2:et:

ssl_context.patch

--- websocket.py.orig   2022-01-02 20:46:35.702603192 +0000
+++ websocket.py    2022-01-02 20:46:55.606189973 +0000
@@ -26,7 +26,7 @@
        :type event_handler: Function(message)
        :return:
        """
-       context = ssl.create_default_context(purpose=ssl.Purpose.CLIENT_AUTH)
+       context = ssl.create_default_context(purpose=ssl.Purpose.SERVER_AUTH)
        if not self.options['verify']:
            context.verify_mode = ssl.CERT_NONE