Arch Linux User Repository

Okay, now I did check the PKGBUILD more carefully. Here is the patch I used to build it locally on a clean chroot env:

diff --git a/PKGBUILD b/PKGBUILD
index cde503a..c56111b 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -4,25 +4,31 @@

 _name=python-measurement
 pkgname=python-measurement
-pkgver=3.2.0 # 4.0a7
+pkgver=3.2.2 # 4.0a7
 pkgrel=1
 pkgdesc='High precision unit-aware measurement objects in Python.'
 arch=(any)
 url='https://github.com/coddingtonbear/python-measurement'
 license=('MIT')
-makedepends=(python-setuptools git)
+makedepends=(
+  git
+  python-build
+  python-installer
+  python-setuptools
+  python-flit-scm
+)
 depends=(python-sympy) # no more needed with v4
 source=(git+https://github.com/coddingtonbear/${_name}.git#tag=$pkgver)
-sha256sums=('SKIP')
+sha256sums=('fd2e02de44b34cd24ba76f514a537fd1c343164d8581fc30077fa780d210ed31')

 build() {
   cd "${_name}"
-  python setup.py build
+  python -m build --wheel --no-isolation
 }

 package() {
   cd "${_name}"
-  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  python -m installer --destdir="$pkgdir" dist/*.whl
   install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
 }

Sorry about last comment (already deleted but maybe you got the email). I opened the PKGBUILD directly in the AUR website and the #tag part was grayed out and I didn't see it. By the way, you can now use checksums with tagged versions from git.