Arch Linux User Repository

Great, thanks. I wasn't aware of the epoch option, now I do :-)

No problem at all, two days is an absolutely fine response time :) Co-maintainership is much appreciated, thanks.

Because the new versioning scheme always counts as "older" than the old one (vercmp 3964.7b50bb0 v0.17.0.r148.2d672d2f is >0), the epoch PKGBUILD variable needs to be increased to make sure any upgrades will count as such in the future (vercmp 3964.7b50bb0 1:v0.17.0.r148.2d672d2f is <0). Just did that in the latest commit.

@xiretza, sorry for late reply. I've applied your patch and made you a co-maintainer (I can also hand it over to you if you prefer that). I am not sure I know what you mean with epoch that requires a bump.

Ah, sorry, epoch needs to be bumped too, forgot that in the patch.

Package is broken in a lot of ways, here's a patch (partly based on python-jedi):

--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,30 +1,50 @@
+# Maintainer: David Verelst <david dott verelst hat gmail com>
+# Contributor: xiretza <xiretza+aur@gmail.com>
+
 pkgname=python2-jedi-git
 _gitname=jedi
-pkgver=3964.7b50bb0
+pkgver=v0.17.0.r146.860d5e88
 pkgrel=1
-pkgdesc="Jedi is an autocompletion tool for Python that can be used in IDEs/editors"
+pkgdesc="An awesome autocompletion, static analysis and refactoring library for Python"
 arch=(any)
 url="https://github.com/davidhalter/jedi"
 license=('MIT')
 depends=('python2')
-makedepends=('git' 'python2-distribute')
-provides=()
-conflicts=()
-replaces=()
-backup=()
+makedepends=('git' 'python2-setuptools')
+provides=('python2-jedi')
+conflicts=('python2-jedi')
 options=(!emptydirs)
-source=('git://github.com/davidhalter/jedi.git')
-# Because the sources are not static, skip Git checksum:
-md5sums=('SKIP')
+source=(git+https://github.com/davidhalter/jedi.git
+        git+https://github.com/davidhalter/typeshed
+        git+https://github.com/typeddjango/django-stubs)
+md5sums=('SKIP'
+         'SKIP'
+         'SKIP')

 pkgver() {
-  cd $_gitname
-  # Use the tag of the last commit
-  #git describe --always | sed 's|-|.|g'
-  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+  cd "$srcdir/$_gitname"
+
+  printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+prepare() {
+  cd "$srcdir/$_gitname"
+
+  git submodule init
+  git config submodule."jedi/third_party/typeshed".url "${srcdir}/typeshed"
+  git config submodule."jedi/third_party/django-stubs".url "${srcdir}/django-stubs"
+  git submodule update --recursive
+}
+
+build() {
+  cd "$srcdir/$_gitname"
+
+  python2 setup.py build
 }

 package() {
-   cd $_gitname
-   python2 setup.py install --root="${pkgdir}" --optimize=1 || exit 1
-}
\ No newline at end of file
+  cd "$srcdir/$_gitname"
+
+  python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
+}