Package Details: qemu-screamer-git r99787.448771a270-2

Git Clone URL: https://aur.archlinux.org/qemu-screamer-git.git (read-only, click to copy)
Package Base: qemu-screamer-git
Description: QEMU PowerPC with sound support for Macintosh emulation
Upstream URL: https://github.com/mcayland/qemu/tree/screamer
Licenses: GPL2
Submitter: myon
Maintainer: myon
Last Packager: myon
Votes: 0
Popularity: 0.000000
First Submitted: 2022-07-03 11:32 (UTC)
Last Updated: 2023-09-10 03:07 (UTC)

Latest Comments

MaximGun commented on 2025-12-12 23:49 (UTC)

Updated PKGBUILD for the 9.1.0 branch. This also works with the classicvirtio tablet driver.

pkgname=qemu-screamer-git
pkgver=r115300.1c47688ed6
pkgrel=1
pkgdesc="QEMU PowerPC with sound support for Macintosh emulation (Screamer)"
arch=('x86_64')
url='https://github.com/mcayland/qemu/tree/screamer-v9.1.0'
license=('GPL2')

depends=('sdl2' 'libpulse' 'libslirp' 'dtc' 'pixman' 'glib2' 'gtk3' 'vte3')
makedepends=('git' 'python' 'python-distlib' 'ninja')

optdepends=('qemu-common: for qemu-bridge-helper')

source=('git+https://github.com/mcayland/qemu.git#branch=screamer-v9.1.0')
sha256sums=('SKIP')

pkgver() {
  cd qemu
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build

  ../qemu/configure \
    --prefix=/usr \
    --with-suffix=qemuscreamer \
    --firmwarepath=share/qemuscreamer \
    --target-list=ppc-softmmu \
    --audio-drv-list=pa,sdl \
    --without-default-features \
    --enable-pixman \
    --enable-pa \
    --enable-gtk \
    --enable-sdl \
    --enable-vte \
    --enable-slirp \
    --enable-avx2 \
    --disable-werror

  make
}

package() {
  cd "${srcdir}/build"

  install -d "${pkgdir}/usr/bin"
  install -m755 qemu-system-ppc "${pkgdir}/usr/bin/qemuscreamer-system-ppc"

  install -d "${pkgdir}/usr/share/qemuscreamer"
  cd "${srcdir}/qemu"
  install -m644 pc-bios/openbios-ppc "${pkgdir}/usr/share/qemuscreamer/"
  install -m644 pc-bios/vgabios-stdvga.bin "${pkgdir}/usr/share/qemuscreamer/"
  install -m644 pc-bios/qemu_vga.ndrv "${pkgdir}/usr/share/qemuscreamer/"
}

gato_lento commented on 2024-07-30 19:50 (UTC)

python-distutils-extra should be added as a build dependency

Twoolp commented on 2024-05-15 13:19 (UTC)

@CountJJ, I had the same error, this is caused by a recent change to the default /etc/makepkg.conf file: https://rfc.archlinux.page/0017-increase-fortification-level/

I was able to get around this by editing /etc/makepkg.conf to change -D_FORTIFY_SOURCE from =3 to =2 while building this package, and changed it back to =3 after I was finished building it.

CountJJ commented on 2024-03-26 03:28 (UTC)

https://pastebin.com/Q6RgXYjB been getting this error when building. Am I doing something wrong?

grainrigi commented on 2023-10-05 14:09 (UTC)

Sorry, I missed your message. Thank you for the fix!

myon commented on 2023-09-10 03:09 (UTC)

Thanks for your detailed report, fixed!

grainrigi commented on 2023-09-10 02:46 (UTC)

Currently, the build fails with the following error:

FAILED: pc-bios/keymaps/ar 
/usr/bin/qemu-keymap -f pc-bios/keymaps/ar -l ar
xkbcommon: ERROR: Couldn't find file "symbols/ar" in include paths
xkbcommon: ERROR: 1 include paths searched:
xkbcommon: ERROR:   /usr/share/X11/xkb
xkbcommon: ERROR: 3 include paths could not be added:
xkbcommon: ERROR:   /home/naoki/.config/xkb
xkbcommon: ERROR:   /home/naoki/.xkb
xkbcommon: ERROR:   /etc/xkb
xkbcommon: ERROR: Abandoning symbols file "(unnamed)"
xkbcommon: ERROR: Failed to compile xkb_symbols
xkbcommon: ERROR: Failed to compile keymap

This issue is already filed in the original qemu: https://gitlab.com/qemu-project/qemu/-/issues/1709

And a patch already exists: https://patchew.org/QEMU/20230620162024.1132013-1-peter.maydell@linaro.org/

So could you add the patch for this package too?