Package Details: quickshell-git 0.2.0.r1.g783b971-1

Git Clone URL: https://aur.archlinux.org/quickshell-git.git (read-only, click to copy)
Package Base: quickshell-git
Description: Flexible toolkit for making desktop shells with QtQuick
Upstream URL: https://git.outfoxxed.me/quickshell/quickshell
Licenses: LGPL-3.0-only
Conflicts: quickshell
Provides: quickshell
Submitter: xiota
Maintainer: entailzwrapped
Last Packager: entailzwrapped
Votes: 18
Popularity: 2.84
First Submitted: 2025-06-11 06:48 (UTC)
Last Updated: 2026-03-25 20:16 (UTC)

Required by (41)

Sources (2)

Pinned Comments

entailzwrapped commented on 2025-06-16 19:06 (UTC)

If you are encountering a weird error while attempting to build, please rebuild the google-breakpad package.

Latest Comments

1 2 3 Next › Last »

goosethedev commented on 2026-04-27 15:29 (UTC)

Hi, when trying to install the package with paru I encountered this error:

CMake Error in /home/myuser/.cache/paru/clone/quickshell-git/src/quickshell/build/CMakeFiles/CMakeScratch/TryCompile-cU8Gux/CMakeLists.txt:
  Imported target "cpptrace::cpptrace" includes non-existent path

    "/include"

  in its INTERFACE_INCLUDE_DIRECTORIES.  Possible reasons include:

  * The path was deleted, renamed, or moved to another location.

  * An install or uninstall procedure did not complete successfully.

  * The installation package was faulty and references files it does not
  provide.

CMake Error at src/crash/CMakeLists.txt:27 (try_run):
  Failed to generate test project build system.

I think it has to do with _IMPORT_PREFIX being "" on /usr/lib/cmake/cpptrace/cpptrace-targets.cmake:

set_target_properties(cpptrace::cpptrace PROPERTIES
  INTERFACE_INCLUDE_DIRECTORIES "${_IMPORT_PREFIX}/include"
)

Building without cpptrace (-DCRASH_HANDLER=off, see https://github.com/quickshell-mirror/quickshell/blob/master/BUILD.md#crash-handler) avoids the issue for now.

gso commented on 2026-04-05 12:52 (UTC) (edited on 2026-04-05 13:01 (UTC) by gso)

It seems that the tag 0.2.1 in quickshell repo is in an unmerged branch (sigh), hence why this PKGBUILD still compiles to a 0.2.0.rXXX.sha when using master. So the problem is in the quickshell repo, not here.

If the master branch is the working one, simply change pkgver=master in your PKGBUILD to rebuild to the latest changes.

They should remove that tag altogether until it's merged. What a mess...

erbil commented on 2026-04-01 11:01 (UTC)

Hello, the upstream repository currently has new tags (the latest appears to be v0.2.1), but the current PKGBUILD is still generating a version string starting with 0.2.0.

This is causing "Out-of-date" warnings in system management tools like DMS, even when the latest commit is installed. Could you please update the pkgver or the metadata to align with the current upstream versioning?

Upstream seems to have moved to 0.2.1 recently. Thanks for the maintainance!

judorange commented on 2026-03-03 17:17 (UTC)

I hit another issue about "error: POSIX thread support was disabled in precompiled file" which lead me to this existing Issue: https://github.com/quickshell-mirror/quickshell/issues/491

Disabling PCH with -DNO_PCH=ON in the pkbuild indeed fixes the issue cf https://github.com/quickshell-mirror/quickshell/blob/master/CONTRIBUTING.md?plain=1#L172

PLuS commented on 2026-03-03 08:04 (UTC)

cpptrace (https://aur.archlinux.org/packages/cpptrace) seems to be a new run dependency.

evertiro commented on 2026-02-25 04:24 (UTC)

Can verify the vulkan-headers issue, but it's worth mentioning that it's a makedepend, not a dependency. Here's a fixed PKGBUILD:

# Maintainer: Entailz <entail-wraps0r at icloud dot com>

_pkgname=quickshell
pkgname="$_pkgname-git"
pkgver=0.2.0.r1.g783b971
pkgrel=1
pkgdesc='Flexible toolkit for making desktop shells with QtQuick'
arch=(x86_64 aarch64)
url='https://git.outfoxxed.me/quickshell/quickshell'
options=(!strip)
license=('LGPL-3.0-only')
depends=(
  'qt6-declarative'
  'qt6-base'
  'jemalloc'
  'qt6-svg'
  'libpipewire'
  'libxcb'
  'wayland'
  'libdrm'
  'mesa'
  'google-breakpad'
  'polkit'
)
makedepends=(
  'spirv-tools'
  'qt6-shadertools'
  'wayland'
  'wayland-protocols'
  'cli11'
  'ninja'
  'cmake'
  'git'
  'vulkan-headers'
)
provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git"
  quickshell-check.hook)
sha256sums=('SKIP'
            '8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')


pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd "$_pkgname"
  cmake -GNinja -B build \
    -DCMAKE_BUILD_TYPE="RelWithDebInfo" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DDISTRIBUTOR="AUR (package: quickshell-git)" \
    -DDISTRIBUTOR_DEBUGINFO_AVAILABLE=NO \
    -DINSTALL_QML_PREFIX=lib/qt6/qml

  cmake --build build
}

package() {
  install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
  cd "$_pkgname"
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
}

micleh commented on 2026-02-24 07:20 (UTC)

@anasgets111 That's exactly the problem I ran into and installing `vulkan-headers' fixed it.

` Could not find a package configuration file provided by "VulkanHeaders" with any of the following names: VulkanHeadersConfig.cmake vulkanheaders-config.cmake

anasgets111 commented on 2026-02-23 09:30 (UTC)

quickshell now added some vulkan support, build fails if vulkan-headers isn't installed, should be added as a dep ? thanks

Cloud0310 commented on 2026-01-01 14:19 (UTC) (edited on 2026-01-01 14:22 (UTC) by Cloud0310)

Here's a fixed version with polkit and qt6-wayland as dependencies. changed: pkgver to latest, adding 

# Maintainer: Entailz <entail-wraps0r at icloud dot com>

_pkgname=quickshell
pkgname="$_pkgname-git"
pkgver=0.2.1.r50.g41828c4
pkgrel=1
pkgdesc='Flexible toolkit for making desktop shells with QtQuick'
arch=(x86_64 aarch64)
url='https://git.outfoxxed.me/quickshell/quickshell'
options=(!strip)
license=('LGPL-3.0-only')
depends=(
  'qt6-declarative'
  'qt6-base'
  'jemalloc'
  'qt6-svg'
  'libpipewire'
  'libxcb'
  'wayland'
  'libdrm'
  'mesa'
  'google-breakpad' # may need rebuild on cachyos, as it has a pre-built package for this.
  'polkit'
)
makedepends=(
  'spirv-tools'
  'qt6-shadertools'
  'wayland'
  'wayland-protocols'
  'cli11'
  'ninja'
  'cmake'
  'git'
  'polkit'
  'qt6-wayland'
)
provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git"
  quickshell-check.hook)
sha256sums=('SKIP'
  '8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' |
    sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd "$_pkgname"
  cmake -GNinja -B build \
    -DCMAKE_BUILD_TYPE="RelWithDebInfo" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DDISTRIBUTOR="AUR (package: quickshell-git)" \
    -DDISTRIBUTOR_DEBUGINFO_AVAILABLE=NO \
    -DINSTALL_QML_PREFIX=lib/qt6/qml

  cmake --build build
}

package() {
  install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
  cd "$_pkgname"
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
}

Shinobu421 commented on 2025-12-07 15:20 (UTC)

the AUR version currently causes my Quickshell to crash on launch, adding 'qt6-wayland' to dependencies and building it manually fixes it.

1 2 3 Next › Last »