Arch Linux User Repository

@HurricanePootis Thank you for your insights! An update is on the way

Hey, this PKGBUILD currently is not compliant with the CMake Packaging Guidelines nor the VCS Packaging Guidelines:

1. Your pkgver() function should use the git tags, as show in the second box here.
2. Your license() is not SPDX compliant
3. You are missing glibc, libstdc++, and libgcc from depends
4. While you have listed those packages in optdepends(), you should provide explanations as to why they are optional
5. You should never build within the actual source code itself. You should use CMake to call a build directory in "$srcdir". Also, do not call make directly, use cmake.
6. You have not put quotes around $srcdir nor $pkgdir. This will cause problems if someone is building in a path with any special characters.
7. You are missing provides=('qzdl'), as this package also provides it while conflicting with it.

diff --git a/PKGBUILD b/PKGBUILD
index 1d9d9c7..ba84e6a 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,15 +1,17 @@
 # Maintainer: Mike Cuche <mike@cuche.cc>
+# Contributor: HurricanePootis <hurricanepootis@protonmail.com>

 pkgname=qzdl-git
-pkgver=541.82cd0a2
+pkgver=3.2.2.3.r114.g82cd0a2
 pkgrel=1
 pkgdesc="A ZDoom launcher using Qt - git version"
 arch=('x86_64')
 url="http://zdl.vectec.net"
-license=('GPL')
-depends=('qt6-base' 'hicolor-icon-theme')
+license=('GPL-3.0-or-later')
+depends=('qt6-base' 'hicolor-icon-theme' 'glibc' 'libgcc' 'libstdc++')
 optdepends=('gzdoom' 'prboom-plus' 'chocolate-doom' 'crispy-doom' 'freedoom')
 conflicts=('qzdl')
+provides=('qzdl')
 makedepends=('git' 'cmake')
 source=("git+https://github.com/qbasicer/qzdl.git"
 "zdl.desktop")
@@ -17,26 +19,29 @@ sha256sums=('SKIP'
             'bd483515ba49b08a60ba7551e9f0b92e4cdb3ace902952f2af35d0608ad51add')

 pkgver() {
-  cd "$SRCDEST/qzdl"
-  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+  cd "$srcdir/${pkgname::-4}"
+  git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//'
 }

 build()
 {
- cd $srcdir/qzdl
- cmake .
- make
+ cd "$srcdir"
+ cmake -B build -S "${pkgname::-4}" \
+ -DCMAKE_BUILD_TYPE=None
+
+ cmake --build build
 }

 package()
 {
-   install -Dm755 $srcdir/qzdl/zdl $pkgdir/usr/bin/zdl
-   install -Dm644 $srcdir/qzdl/ico_icon.xpm $pkgdir/usr/share/pixmaps/zdl.xpm
-   install -Dm644 $srcdir/qzdl/res/zdl3-32x32.png $pkgdir/usr/share/icons/hicolor/32x32/apps/zdl.png
-   install -Dm644 $srcdir/qzdl/res/zdl3-64x64.png $pkgdir/usr/share/icons/hicolor/64x64/apps/zdl.png
-   install -Dm644 $srcdir/qzdl/res/zdl3-128x128.png $pkgdir/usr/share/icons/hicolor/128x128/apps/zdl.png
-   install -Dm644 $srcdir/qzdl/res/zdl3-256x256.png $pkgdir/usr/share/icons/hicolor/256x256/apps/zdl.png
-   install -Dm644 $srcdir/qzdl/res/zdl3-512x512.png $pkgdir/usr/share/icons/hicolor/512x512/apps/zdl.png
-   install -Dm644 $srcdir/qzdl/res/zdl3.svg $pkgdir/usr/share/icons/hicolor/scalable/apps/zdl.svg
-   install -Dm644 $srcdir/zdl.desktop $pkgdir/usr/share/applications/zdl.desktop
+   cd "$srcdir"
+   install -Dm755 build/zdl "$pkgdir/usr/bin/zdl"
+   install -Dm644 qzdl/ico_icon.xpm "$pkgdir/usr/share/pixmaps/zdl.xpm"
+   install -Dm644 qzdl/res/zdl3-32x32.png "$pkgdir/usr/share/icons/hicolor/32x32/apps/zdl.png"
+   install -Dm644 qzdl/res/zdl3-64x64.png "$pkgdir/usr/share/icons/hicolor/64x64/apps/zdl.png"
+   install -Dm644 qzdl/res/zdl3-128x128.png "$pkgdir/usr/share/icons/hicolor/128x128/apps/zdl.png"
+   install -Dm644 qzdl/res/zdl3-256x256.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/zdl.png"
+   install -Dm644 qzdl/res/zdl3-512x512.png "$pkgdir/usr/share/icons/hicolor/512x512/apps/zdl.png"
+   install -Dm644 qzdl/res/zdl3.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/zdl.svg"
+   install -Dm644 zdl.desktop "$pkgdir/usr/share/applications/zdl.desktop"
 }

@aquova I tried to build against Qt6 and it was successful, so I updated the pkgbuild :)

Is qt5-base still a requirement for this package? This is one of the last packages I have on my machine that hasn't migrated to qt6, but from what I can tell from the source, qt6 support was added some time ago.

@SteelT I have removed the mentioned line from the .desktop file, you can rebuild the package

The empty Path[$e]= line ends up breaking the .desktop file, making my file manager thinks it's not a invalid desktop entry file.