Arch Linux User Repository

@InsanelyDefault Actually it's node-gyp (and python), tested in makechrootpkg. Added those to makedepends, thx.

@lunafox This package is for someone who prefer source-built packages. If you prefer the official binary, use r2modman-bin instead.

@gusgalarnyk nodejs-lts-hydrogen is required for building electron24, but not r2modman itself. if you can't build it, I recommend use electron24-bin instead

Edit: Thank you, my apologies. Still new to Linux. I have swapped to r2modman-bin and handled my electron dependencies. The following comment no longer applies.

Not certain this is a helpful comment but I'm getting "could not find all required packages: nodejs-lts-hydrogen" which wasn't happening a week or two ago. I think something is outdated here.

This makedepends on npm as of right now. If the PKGBUILD could be updated to reflect that, that'd be much appreciated.

worth noting that this package is not official. the devs of r2modman provide a .pacman file as part of their release on github: https://github.com/ebkr/r2modmanPlus/releases/

@Shiftyeyesshady Install either electron24 or electron24-bin from AUR first.

Currently fails to build due to a broken electron dependency.

==> Missing dependencies: -> electron24 ==> Checking buildtime dependencies... ==> ERROR: Could not resolve all dependencies.

Whatever, I guess.

My point was that you can make a better package that way, because using system's Electron has its advantages (saved space, better Wayland support with recent Electron versions etc.)

Also I've just built the package with just nvm and yarn, with electron30 and without python2

# Maintainer: su226 <thesu226@outlook.com>

pkgname=r2modman
pkgver=3.1.49
pkgrel=1
pkgdesc="A simple and easy to use mod manager for several games using Thunderstore."
arch=(any)
url="https://github.com/ebkr/r2modmanPlus"
license=("MIT")
_electron=electron30
depends=("$_electron")
makedepends=('nvm' 'yarn')
conflicts=('r2modman-bin' 'r2modman-appimage')
source=("r2modmanPlus-$pkgver.tar.gz::https://github.com/ebkr/r2modmanPlus/archive/refs/tags/v$pkgver.tar.gz"
    "r2modman.desktop")
sha256sums=(b23119297deda09793760f9962b51bbf8887c1738b9befb99b414573316bc743
    6cd96385f1ad7bf6fec0f9a70b429305e6f20153528e415d3c943ff19a45fd0f)

_ensure_local_nvm() {
    which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
    export NVM_DIR="${srcdir}/.nvm"

    source /usr/share/nvm/init-nvm.sh
}

prepare() {
    _ensure_local_nvm
    # Node 14 is required, newer versions might not build node-sass
    nvm install 14

    cd "r2modmanPlus-$pkgver"

    # Modify electron-builder config
    local _electronDist="/usr/lib/$_electron"
    local _electronVersion="$(<$_electronDist/version)"

    sed -e "s/'AppImage', 'tar.gz', 'deb', 'rpm', 'pacman'/'dir'/" \
        -e "/builder: {/a electronDist: \"$_electronDist\", electronVersion: \"$_electronVersion\"," \
        -i quasar.conf.js

    yarn install
}

build() {
    _ensure_local_nvm
    cd "r2modmanPlus-$pkgver"
    yarn build-linux
}

package() {
    cd "r2modmanPlus-$pkgver"
    install -Dm644 dist/electron/Packaged/linux-unpacked/resources/app.asar "$pkgdir/usr/share/r2modman/app.asar"

    install -d "$pkgdir/usr/bin"
    printf '#!/bin/bash\nexec %s /usr/share/r2modman/app.asar "$@"\n' "$_electron" >"$pkgdir/usr/bin/r2modman"
    chmod 755 "$pkgdir/usr/bin/r2modman"

    install -Dm644 "$srcdir/r2modman.desktop" "$pkgdir/usr/share/applications/r2modman.desktop"
    for _icon in src/assets/icon/*; do
        install -Dm644 "$_icon" "$pkgdir/usr/share/icons/hicolor/$(basename -s .png $_icon)/apps/r2modman.png"
    done

    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/r2modman/LICENSE"
}

See for yourself.

@murlakatamenka You need python2 for building (the specific version of) node-sass, in case prebuilt binary is unavailable. Besides, I use electron11 because upstream uses it, thus working on other Electron versions is not guaranteed. If you really want it, try customizepkg.