Arch Linux User Repository

THIS PACKAGE NOR ITS CODE IS NOT UPDATED.

Try the upstream rofi with XWayland, or try fork rofi-lbonn-wayland-git, available on the AUR.

---

@tinywrkb: I have pushed "Abandoned code base, try the fork rofi-lbonn-wayland-git" as description. I hope this all suffices. I have added you as co-maintainer for if you want to update anything about the description. Thanks for your work!

I don't think it makes much sense to add replaces array.

1. According to the Wiki, it's not like AUR helpers can search for packages based on the replaces array.
2. Even if 1. was possible it's still not strict. Any AUR package can have whatever the maintainer decided in the replaces array. You can end up with multiple replacement packages. Not very helpful and there's no logic to process this automatically.
3. I haven't looked at pacman's code so I don't know how this will affect the local system pacman DB when the opposite will be needed, when the official repo will have an updated wayland code (branch or needed to be enabled on build time). And this only relevant when you have a local repo, when using something like aurutils.

FWIW, you could add replaces=('rofi-wayland-git') to your package, although I'm not sure whether that's something you do on AUR.

I will keep the package and the out-of-date notification, and put a comment in the description. If you know of a better way to signal this, please let me know!

@rubdos I agree with your reasoning. I wouldn't want to create a confusion that will end with the lbonn's fork users reporting Wayland related bugs on the official repo.

rofi-lbonn-wayland-git is now available.

To avoid the possibility of that some user will recreate this package (rofi-wayland-git/) I think it would be best keep it and not request a deletion. Instead, just stick a comment with a link to rofi-lbonn-wayland-git.

Thanks, kepi and tinywrkb, for the reminders. I'll copy the reply I sent to tinywrkb in mail:

The rofi people abandoned the wayland branches, upon which this PKGBUILD was based. I don't think this PKGBUILD should get updated; rather, I would think it should be forked into rofi-lbonn-wayland-git or something like that, and get deleted or deprecated in favour of the fork. I don't think it's fair to the name not to include the fact that it is a fork. Using rofi-wayland-git would imply it is a wayland branch in the official repository, as it used to be.

Let me know if you decide to start such a fork package, because I'd probably try it out. I have in the meanwhile reverted to rofi through XWayland, which works fine (but is obviously not ideal).

I hope you agree with the above, or have a better suggestion.

Thank you for your interest!

I asked the maintainer to update the package or if he doesn't have the time then orphan it, that's before annoying Arch's trusted users with orphan request.

In the meantime here's an updated PKGBUILD.

# Maintainer: tinywrkb <tinywrkb@gmail.com>
# Contributor: Morten Linderud <foxboron@archlinux.org>
# Contributor: Maxim Baz <rofi at maximbaz dot com>
# Contributor: Anatol Pomozov
# Contributor: Benjamin Chrétien <chretien + aur [at] lirmm [dot] fr>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
# Contributor: Rasi <rasi@xssn.at>
# Contributor: Sean Pringle <sean.pringle@gmail.com>
# Contributor: SanskritFritz (gmail)

_gitname=rofi
pkgname=rofi-wayland-git
pkgver=1.3.1.r1315.g498fd2fc
pkgrel=1
pkgdesc='A window switcher, application launcher and dmenu replacement (Wayland fork)'
arch=(x86_64)
url="https://github.com/lbonn/$_gitname"
license=(MIT)
depends=(libxdg-basedir startup-notification libxkbcommon-x11 xcb-util-wm xcb-util-xrm librsvg wayland)
makedepends=(check git meson wayland-protocols)
optdepends=('i3-wm: use as a window switcher')
provides=(rofi)
conflicts=(rofi)
source=("${_gitname}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd $_gitname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd $_gitname
  git submodule update --init
}

build() {
  arch-meson \
    -Dwayland=enabled \
    -Dcheck=enabled \
    $_gitname build
  meson compile -C build
}

check() {
  LC_ALL=C meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build

  cd $_gitname
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  install -dm755 "$pkgdir/usr/share/doc/$_gitname/examples"
  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/$_gitname/examples"
}

Looks like sources for this package are not available any more. There is now new fork with Wayland support officially linked from rofi repo. New implementation uses wayland shell protocol.

Would you be so kind and update PKGBUILD?

Edit: fixed missing dependencies and wrong branch

--- PKGBUILD.orig   2020-07-26 20:07:54.000000000 +0200
+++ PKGBUILD    2020-07-26 21:34:28.504964385 +0200
@@ -7,20 +7,18 @@

 pkgname=rofi-wayland-git
 _gitname=rofi
-pkgver=1.3.1.r384.g3a29d3ec
-pkgrel=2
+pkgver=1.3.1.r1314.ga9c0975e
+pkgrel=1
 pkgdesc="A window switcher, run dialog and dmenu replacement"
-arch=('i686' 'x86_64')
-url="https://davedavenport.github.io/rofi/"
+arch=(x86_64)
+url="https://github.com/davatorium/rofi"
 license=('MIT')
-depends=(freetype2 libxdg-basedir pango xcb-util-xrm wayland-wall)
-optdepends=('sway: use as application runner'
-            'wlc-wall-injector: injects wall wayland protocol in wlc based compositors'
-            'orbment: use as application runner')
-makedepends=('git' 'wayland' 'libxkbcommon' 'xcb-util-wm')
+depends=(libxdg-basedir startup-notification libxkbcommon-x11 xcb-util-wm xcb-util-xrm librsvg)
+optdepends=('sway: use as a window switcher')
+makedepends=('check' 'git' 'meson')
 provides=('rofi')
 conflicts=('rofi')
-source=("git+https://github.com/DaveDavenport/rofi#branch=wip/wayland")
+source=("git+https://github.com/lbonn/rofi.git#branch=wayland")
 md5sums=('SKIP')

 pkgver() {
@@ -31,26 +29,25 @@
 prepare() {
   cd "$srcdir/$_gitname"
   git submodule update --init
-
-  # By default, installs pkg-config file in /usr/local/share/pkgconfig
-  # instead of /usr/share/pkgconfig.
-  export PKG_CONFIG_PATH=/usr/share/pkgconfig:/usr/local/share/pkgconfig
-  autoreconf --install
-
-  # Default compiler = clang, which can be a problem if using hardening-wrapper
-  CC=gcc ./configure --prefix=/usr --with-display-backend=wayland
+  arch-meson build -Dwayland=enabled
 }

 build() {
   cd "$srcdir/$_gitname"
-  make
+  ninja -C build
+}
+
+check() {
+  cd "$srcdir/$_gitname"
+  meson test -C build
 }

 package() {
   cd "$srcdir/$_gitname"
-  make install install-man DESTDIR="$pkgdir"

-  install -Dm644 COPYING "$pkgdir/usr/share/licenses/rofi-wayland-git/COPYING"
-  install -dm755 "$pkgdir/usr/share/doc/rofi/examples"
-  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/rofi/examples"
+  DESTDIR="$pkgdir" ninja install -C build
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+  install -dm755 "$pkgdir/usr/share/doc/$pkgname/examples"
+  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/$pkgname/examples"
 }

I think my edit fell through the gaps. It also needs 'libxkbcommon' and 'xcb-util-wm' in the makedepends array in addition to wayland. Also, you forgot to bump the pkgrel.

Missing 'wayland', 'libxkbcommon' and 'xcb-util-wm' in the makedepends array.

On my machine, this fails to build because wayland-wall-git installs its pkg-config file in /usr/local/shared/pkgconfig instead of /usr/shared/pkgconfig. The following patch solves this for me: diff --git a/PKGBUILD b/PKGBUILD index 53990e6..1046252 100644 --- a/PKGBUILD +++ b/PKGBUILD @@ -31,6 +31,8 @@ pkgver() { prepare() { cd "$srcdir/$_gitname" git submodule update --init + + export PKG_CONFIG_PATH=/usr/share/pkgconfig:/usr/local/share/pkgconfig autoreconf --install # Default compiler = clang, which can be a problem if using hardening-wrapper

If you plan on using this on Sway, read this: https://www.rubdos.be/linux/wayland/2017/03/25/rofi-sway-wayland.html . It's possible, but requires some work for now.