Arch Linux User Repository

Workaround for the GPU process isn't usable error can be found here: https://github.com/Automattic/simplenote-electron/issues/3044#issuecomment-979289305

Please request a binary rebuild upstream for proper fix.

v2.22 is a pre-release, will wait for the release here

I tried to run Simple Note on Manjaro PLASMA last version and it won't open. The icon move a bit and nothing open... How can Help you fix this ?

I'm on garuda kde, why simplenote won't start, it doesn't matter if i click on taskbar icon or from start menu, one of ten times it start...

How can i fix it?

Please don't keep the included Electron runtime. Use an Arch repo electron package as dependency instead.

Workaround for the GPU process isn't usable error can be found here: https://github.com/Automattic/simplenote-electron/issues/3044#issuecomment-979289305

Please request a binary rebuild upstream for proper fix.

taskbar icon is misssing.

Adding complexity and dependencies in order to support non-official architectures is not what I would expect in the AUR. This would maybe fit better in some Arch derivatives repo supporting these architectures. The deb packages are adequate for a x86_64 bin package.

@Kewl Hmm... it appears that fuse is required. So yes, it would add a dependency. Having said that, I'm not sure whether that's fuse2 or fuse3.

@Feakster doesn't ./$_appimage --appimage-extract introduce more dependencies?

Hi @Kewl & @jonathon,

This would be my suggestions for an AppImage-based PKGBUILD:

# Contributor: Feakster <feakster at posteo dot eu>
# Maintainer: Kewl <xrjy@nygb.rh.bet(rot13)>

### Info ###
pkgname=simplenote-electron-bin
_pkgname=${pkgname%-electron-bin}
pkgver=2.13.0
_appimage="simplenote-electron-${pkgver}-${CARCH}.AppImage"
pkgrel=2
pkgdesc='The simplest way to keep notes'
arch=('armv7h' 'aarch64' 'i686' 'pentium4' 'x86_64')
url='https://github.com/Automattic/simplenote-electron'
license=('GPL2')
depends=('gtk3' 'hicolor-icon-theme' 'libxss' 'mesa' 'nss')
optdepends=(
    'libnotify: desktop notifications'
    'noto-fonts-emoji: emoji support'
    'ttf-joypixels: emoji support'
)
makedepends=('zlib')
provides=('simplenote')
replaces=('simplenote-electron-arm-bin')
options=(!strip)
source_armv7h=("simplenote-electron-${pkgver}-armv7h.AppImage"::"${url}/releases/download/v${pkgver}/Simplenote-linux-${pkgver}-armv7l.AppImage")
source_aarch64=("simplenote-electron-${pkgver}-aarch64.AppImage"::"${url}/releases/download/v${pkgver}/Simplenote-linux-${pkgver}-arm64.AppImage")
source_i686=("simplenote-electron-${pkgver}-i686.AppImage"::"${url}/releases/download/v${pkgver}/Simplenote-linux-${pkgver}-i386.AppImage")
source_pentium4=("simplenote-electron-${pkgver}-pentium4.AppImage"::"${url}/releases/download/v${pkgver}/Simplenote-linux-${pkgver}-i386.AppImage")
source_x86_64=("simplenote-electron-${pkgver}-x86_64.AppImage"::"${url}/releases/download/v${pkgver}/Simplenote-linux-${pkgver}-x86_64.AppImage")
noextract=("${source[@]%%::*}")
b2sums_armv7h=('73915723c884d741465b47049159496aadb9378fb487f4bbf165568675e69ad0a2de2a5af18b281eee1a2dc35eb805b3a5c8684885c50c383ee44d645d240a7d')
b2sums_aarch64=('1df436f6b106528d44e4bd3ed3f8ed0fcbf41d129174291545dffba8dbcdca57722fb7447d8d6edcb7df0be6d8d69c695379f07c15df37331a77e8b67098dd63')
b2sums_i686=('45a2c06bf37824b968d28f7c6a94da97218ee51e71b3472c2156f2dfdd01294bd1044e7e4d27255b3071bf14b7d26c86ef33ae454152c32090a0fd24f6ed29f7')
b2sums_pentium4=('45a2c06bf37824b968d28f7c6a94da97218ee51e71b3472c2156f2dfdd01294bd1044e7e4d27255b3071bf14b7d26c86ef33ae454152c32090a0fd24f6ed29f7')
b2sums_x86_64=('27f858e19861cf15b482161f8a6167d1a3839464e76dcdc59fdd5e2472df0544f805813f4711bd76643b1893fbfebc3f90f469e189ba0bac8a034a7ccc77d054')

### Prepare ###
prepare() {
    ## Change Directory ##
    cd "$srcdir"

    ## Mark AppImage as Executable ##
    chmod a+x $_appimage

    ## Extract AppImage into squashfs-root Directory ##
    ./$_appimage --appimage-extract

    ## Remove Unnecessary Files ##
    rm squashfs-root/{.DirIcon,AppRun,$_pkgname.png}

    ## Fix Permissions ##
    find squashfs-root -type d -exec chmod 0755 {} \;
    find squashfs-root -type f -name '*.so' -exec chmod 0755 {} \;

    ## Modify Desktop File ##
    sed -i \
    -e "s|^Exec=.*|Exec=/usr/bin/${_pkgname}|" \
    -e '/^TryExec=.*/d' \
    -e '/^X-AppImage-Version=.*/d' \
    squashfs-root/${_pkgname}.desktop
    echo "TryExec=/opt/${_pkgname}/${_pkgname}" >> squashfs-root/${_pkgname}.desktop
}

### Package ###
package() {
    ## Move AppImage Contents to /opt/$_pkgname ##
    install -dm0755 "$pkgdir"/opt/$_pkgname
    cp -RT "$srcdir"/squashfs-root "$pkgdir"/opt/$_pkgname

    ## SUID Sandbox ##
    chmod 4755 "$pkgdir"/opt/$_pkgname/chrome-sandbox

    ## Executable Binary ##
    install -dm0755 "$pkgdir"/usr/bin
    ln -fs \
    /opt/$_pkgname/$_pkgname \
    "$pkgdir"/usr/bin/$_pkgname

    ## Install Icons ##
    for SIZE in 16 32 48 64 128 256 512 1024
    do
        install -dm0755 "$pkgdir"/usr/share/icons/hicolor/${SIZE}x${SIZE}/apps
        ln -fs \
        /opt/$_pkgname/usr/share/icons/hicolor/${SIZE}x${SIZE}/apps/${_pkgname}.png \
        "$pkgdir"/usr/share/icons/hicolor/${SIZE}x${SIZE}/apps/${_pkgname}.png
    done

    ## Desktop Icon ##
    install -dm0755 "$pkgdir"/usr/share/applications
    ln -fs \
    /opt/$_pkgname/${_pkgname}.desktop \
    "$pkgdir"/usr/share/applications/${_pkgname}.desktop

    ## Licenses ##
    install -dm0755 "$pkgdir"/usr/share/licenses/$pkgname
    ln -fs \
    /opt/$_pkgname/LICENSE.electron.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.electron.txt
    ln -fs \
    /opt/$_pkgname/LICENSES.chromium.html \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSES.chromium.html
}

It could be simplified further. I'm not sure the ## Remove Unnecessary Files ## & ## Fix Permissions ## steps are necessary.

Apologies for pestering. A trusted user has marked the ARM version of the package I maintain for deletion because it doesn't support x86_64 architectures.