Arch Linux User Repository

Please make sure to import the correct GPG key first:

$ curl -sS https://download.spotify.com/debian/pubkey_C85668DF69375001.gpg | gpg --import -

And always build in a clean chroot. It is as easy as:

pacman -S devtools
git clone https://aur.archlinux.org/spotify.git
cd spotify
pkgctl build
pacman -U <path-to-spotify-package>

It is expected that the package will break now and then, as spotify continuously changes download binaries, gpg keys etc (which is not appropriate, but we cannot change this). Please be patient if an update does not occur the next day, you can still use an existing spotify install or update the version yourself.

@lightofpast Just pushed v1:1.2.20.1210-2 that now allows you to set custom launch flags in a spotify-flags.conf file under $XDG_CONFIG_HOME or ~/.config :)

@Antiz Thank you very much! :)

@lsigma Thanks for the insight, I updated the parameter from %U to %u ;)

@jkhsjdhjs Fixed (a new version was available, which I just pushed now) ;)

I'm currently seeing the following error:

==> Starting prepare()...
spotify-1.2.53.440-1-x86_64-Packages: OK
spotify-1.2.53.440-g7b2f582a-x86_64.deb: FAILED
sha512sum: WARNING: 1 computed checksum did NOT match

@kotofyt, what error are you getting? Because it works fine for me :)

Doesn't work correctly with kernel version 6.13.1.arch1-1

Thanks for creating the package!

In the PKGBUILD, the Exec field gets patched with parameter for an URL (%U). According to the Desktop file spec, %u would be the more appropiate variable; using %U in a flag is not allowed in the spec. This would make the resulting Desktop file comply with the spec (hopefully without changing the behavior):

diff --git a/PKGBUILD b/PKGBUILD
index f6ecc38..85763ce 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -68,7 +68,7 @@ package() {
     tar -xzf data.tar.gz --no-same-owner -C "${pkgdir}"

     # Enable spotify to open URLs from the webapp
-    sed -i 's/^Exec=.*/Exec=spotify --uri=%U/' "${pkgdir}/usr/share/spotify/spotify.desktop"
+    sed -i 's/^Exec=.*/Exec=spotify --uri=%u/' "${pkgdir}/usr/share/spotify/spotify.desktop"

     install -Dm 644 "${pkgdir}/usr/share/spotify/spotify.desktop" "${pkgdir}/usr/share/applications/spotify.desktop"
     install -Dm 644 "${pkgdir}/usr/share/spotify/icons/spotify-linux-512.png" "${pkgdir}/usr/share/pixmaps/spotify-client.png"

I've run into this because uwsm is stricter about the spec than KDE for example.

For the update to version 1:1.2.52.442-2 a new GPG key is needed. And despite being mentioned in the build script, the automatic import failed. But manually importing fixed it.

Changing the line from gromit's pinned post to this before running the update did the trick for me:

curl -sS https://download.spotify.com/debian/pubkey_C85668DF69375001.gpg | gpg --import -

Many users experience this error while loading spotify on old CPUs:

 [1]    76568 illegal hardware instruction (core dumped)  spotify

It looks like the new UI uses AVX instructions, if your CPU has no AVX extension, spotify will likely fail to start. The latest version of spotify that can run on non-AVX CPUs is 1.2.45.454-gc16ec9f6.

You can build yourself this outdated but still working perfectly non-AVX spotify version by following these instructions:

• Download the AUR spotify git package revision corresponding to the former published 1.2.45.454 version: https://aur.archlinux.org/cgit/aur.git/commit/?h=spotify&id=86a7174b6f92a794e5d2a4abd5d191734eb0c71d

• Modify the PKGBUILD to this content:

# Maintainer: Christian Heusel <christian@heusel.eu>
# Maintainer: Robin Candau <antiz@archlinux.org>
# Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
# Contributor: TobFromme < TobFromme {hat} pm {dont} me >
# Contributor: Ashley Whetter <(firstname) @ awhetter.co.uk>
# Contributor: Eothred <yngve.levinsen@gmail.com>

pkgname=spotify
pkgver='1.2.45.454'
epoch=1
_commit=gc16ec9f6
pkgrel=1
pkgdesc='A proprietary music streaming service'
arch=('x86_64')
license=('custom')
url='https://www.spotify.com'
depends=('alsa-lib>=1.0.14' 'gtk3' 'libxss' 'desktop-file-utils' 'openssl' 'nss' 'at-spi2-atk' 'libcurl-gnutls' 'libsm' 'libayatana-appindicator')
optdepends=('ffmpeg4.4: Adds support for playback of local files'
            'zenity: Adds support for importing local files'
            'libnotify: Desktop notifications')
options=('!strip')

# NOTE: We switched from stable to testing on 18th march, as the spotify
# stable repository is always outdated. Testing seems to be in sync with snap:
# https://snapcraft.io/spotify
# http://repository.spotify.com/dists/testing/Release
# http://repository.spotify.com/dists/testing/non-free/binary-amd64/Packages
# http://repository.spotify.com/dists/testing/Release.gpg
source=("${pkgname}-${pkgver}-${_commit}-x86_64.deb"
        "spotify.sh"
        "spotify.protocol"
        "LICENSE")
sha512sums=('4396ac2c05cbf4b64e57d4ace40967c6d14061471597d1884d6b8420587f0f3689038a35534bb0b4c75e9f01675246e2c36261048880c677a8897caa60b7a8c9'
            'da48b628a4ea925dd8521133ebf364b261b11aed252d264dde6605d915cdb631919ffe672c58534bcdb60869e5d87a49a60a8198780b99517123f0031e83fdb1'
            '999abe46766a4101e27477f5c9f69394a4bb5c097e2e048ec2c6cb93dfa1743eb436bde3768af6ba1b90eaac78ea8589d82e621f9cbe7d9ab3f41acee6e8ca20'
            '2e16f7c7b09e9ecefaa11ab38eb7a792c62ae6f33d95ab1ff46d68995316324d8c5287b0d9ce142d1cf15158e61f594e930260abb8155467af8bc25779960615')

# Import key with:
# curl -sS https://download.spotify.com/debian/pubkey_6224F9941A8AA6D1.gpg | gpg --import -
validpgpkeys=('63CBEEC9006602088F9B19326224F9941A8AA6D1') # Spotify Public Repository Signing Key <tux@spotify.com>
# Old Keys:
# E27409F51D1B66337F2D2F417A3A762FAFD4A51F
# F9A211976ED662F00E59361E5E3C45D7B312C643
# 8FD3D9A8D3800305A9FFF259D1742AD60D811D58
# 931FF8E79F0876134EDDBDCCA87FF9DF48BF1C90
# 2EBF997C15BDA244B6EBF5D84773BD5E130D1D45

package() {
    tar -xzf data.tar.gz --no-same-owner -C "${pkgdir}"

    # Enable spotify to open URLs from the webapp
    sed -i 's/^Exec=.*/Exec=spotify --uri=%U/' "${pkgdir}/usr/share/spotify/spotify.desktop"

    install -Dm 644 "${pkgdir}/usr/share/spotify/spotify.desktop" "${pkgdir}/usr/share/applications/spotify.desktop"
    install -Dm 644 "${pkgdir}/usr/share/spotify/icons/spotify-linux-512.png" "${pkgdir}/usr/share/pixmaps/spotify-client.png"

    for size in 22 24 32 48 64 128 256 512; do
        install -Dm 644 "${pkgdir}/usr/share/spotify/icons/spotify-linux-${size}.png" \
            "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/spotify.png"
    done

    # Move spotify binary to its proper location
    mkdir -p "${pkgdir}/opt/spotify"
    mv "${pkgdir}/usr/share/spotify" "${pkgdir}/opt/"

    # Copy launch script which allows the use of custom flags
    install -Dm 755 spotify.sh "${pkgdir}/usr/bin/spotify"

    # Copy protocol file for KDE
    install -Dm 644 spotify.protocol "${pkgdir}/usr/share/kservices5/spotify.protocol"

    # Install license
    # https://www.spotify.com/legal/end-user-agreement
    install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    # Fix permissions
    chmod -R go-w "${pkgdir}"
}