Package Details: stardrop 1.9.0-1

Git Clone URL: https://aur.archlinux.org/stardrop.git (read-only, click to copy)
Package Base: stardrop
Description: An open-source, cross-platform mod manager for Stardew Valley
Upstream URL: https://github.com/Floogen/Stardrop
Keywords: modding mods stardew valley
Licenses: GPL3
Submitter: aquova
Maintainer: aquova
Last Packager: aquova
Votes: 1
Popularity: 0.000006
First Submitted: 2024-11-05 13:50 (UTC)
Last Updated: 2026-06-08 00:03 (UTC)

Latest Comments

Remyrios commented on 2025-01-05 18:54 (UTC) (edited on 2025-01-05 18:54 (UTC) by Remyrios)

The build process requires zip. Would be a decent idea to add it as a make dependency.

aquova commented on 2024-11-25 17:05 (UTC)

Excellent, thanks! I've made the changes.

Timur1324 commented on 2024-11-25 08:44 (UTC)

Main changes: 1) Dsktop file and icon support 2) Only linux runtime

PKGBUILD

# Maintainer: aquova <mail at aquova dot net>
# Contributor: Timur Bagautdinov <mr.bagautdinov14 at gmail dot com>

pkgname=stardrop
_pkgname=Stardrop
pkgver=1.2.1
pkgrel=3
pkgdesc='An open-source, cross-platform mod manager for Stardew Valley'
url='https://github.com/Floogen/Stardrop'
arch=("x86_64")
options=("strip" "!debug")
license=("GPL3")
depends=('dotnet-runtime-7.0')
makedepends=('dotnet-sdk-7.0' 'libicns')
source=(
    "${url}/archive/refs/tags/v${pkgver}.tar.gz"
    "stardrop.desktop"
)
sha256sums=(
    '39fb06ed5cbfc80c80b8f86cea56ddd575d604890fff4df93d601e62b80d88b9'
    'e91d6d814966e1854cfa6c33c9d63a078c23332fe9c136c0669061c891bfe633'
)

prepare() {
    # Prepare icon
    icns2png -x -s 512x512 "$srcdir/$_pkgname-$pkgver/$_pkgname/Assets/Stardrop.icns"
}

build() {
    cd $_pkgname-$pkgver
    dotnet publish $_pkgname -c "Release" --runtime "linux-x64"
}

package() {
    mkdir -p $pkgdir/opt/$pkgname
    mkdir -p $pkgdir/usr/bin
    mkdir -p $pkgdir/usr/share/icons/hicolor/512x512/apps/
    mkdir -p $pkgdir/usr/share/applications

    cd $srcdir/$_pkgname-$pkgver/$_pkgname/bin/Release/linux-x64
    cp -a * $pkgdir/opt/$pkgname
    ln -sf /opt/$pkgname/$_pkgname $pkgdir/usr/bin/$pkgname

    # Icon
    install -m 644 "$srcdir/Stardrop_512x512x32.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/stardrop.png"

    # Desktop file
    install -m 644 "$srcdir/stardrop.desktop" "$pkgdir/usr/share/applications/stardrop.desktop"
}

stardrop.desktop

#!/usr/bin/env xdg-open
[Desktop Entry]
Name=Stardrop
Version=1.2.1
Comment=Stardrop is an open-source, cross-platform mod manager for the game Stardew Valley.
Comment[ru_RU]=Stardrop это кросс-платформенный менеджер модов, с открытым исходным кодом для игры Stardew Valley.
Exec=stardrop
Icon=stardrop
Type=Application
Terminal=false
StartupNotify=true
Categories=Game;
Encoding=UTF-8