Arch Linux User Repository

Confirmed v3.0.1 fixes module naming issue.

Also confirming that https://aur.archlinux.org/packages/python-rtslib-fb 2.2.2-1 works without a hitch.

Updated for 3.0.1 including @bobpaul modifications:

# Contributor: Johannes Dewender  arch at JonnyJD dot net
pkgname=targetcli-fb
pkgver=3.0.1
pkgrel=1
pkgdesc="free branch of the targetcli LIO administration shell (iSCSI + Co)"
arch=('any')
url="https://github.com/open-iscsi/targetcli-fb"
license=('Apache')
groups=()
depends=(
  'python-rtslib-fb'
  'python-configshell-fb'
  'python-dbus'
  'python-gobject'
)
makedepends=(
  'python-build'
  'python-hatch-vcs'
  'python-hatchling'
  'python-installer'
  'python-wheel'
)
optdepends=()
provides=('targetcli')
backup=()
options=()
install=
source=(https://github.com/open-iscsi/targetcli-fb/archive/v${pkgver}.tar.gz)
sha512sums=('e4ed5b1911ba8858fcf8fe39580462b7b645672f836b195fba0549fb5f9532bf5223a7034bf92c14e5d01c106e388d8ec942cacac421dfd1271f9916ac47f4c0')


build() {
  cd "$srcdir/$pkgname-$pkgver"
  SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver python -m build --wheel --no-isolation
  gzip --stdout targetcli.8 > "targetcli.8.gz"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl

  install -d -m 750 "${pkgdir}/etc/target"
  install -D -m 644 targetcli.8.gz "$pkgdir/usr/share/man/man8/targetcli.8.gz"
  install -D -m 644 systemd/targetclid.service "$pkgdir/usr/lib/systemd/system/targetclid.service"
  install -D -m 644 systemd/targetclid.socket "$pkgdir/usr/lib/systemd/system/targetclid.socket"
  install -D -m 644 README.md "$pkgdir/usr/share/doc/targetcli/README.md"
  install -D -m 644 THANKS "$pkgdir/usr/share/doc/targetcli/THANKS"
}

Confirmed it works and starts up, shell able to connect. Haven't tried setting up any targets yet.

@bobpaul 3.0.1 was released and it fixed the module name problem.

@sanerb's PKGBUILD builds for me, but I needed to add python-hatchling and python-hatch-vcs to the makedepends. I also had to add mkdir -p "$pkgdir"/etc/target to the package() function

And I when I try to run targetcli I get ModuleNotFoundError: No module named 'rtslib_fb.utils'; 'rtslib_fb' is not a package. I had to downgrade python-rtslib-fb to v2.1.76 and that fixed it.

PKGBUILD for v3.0.0 (probably needs further work):

# Contributor: Johannes Dewender  arch at JonnyJD dot net
pkgname=targetcli-fb
pkgver=3.0.0
pkgrel=1
pkgdesc="free branch of the targetcli LIO administration shell (iSCSI + Co)"
arch=('any')
url="https://github.com/open-iscsi/targetcli-fb"
license=('Apache')
groups=()
depends=('python-rtslib-fb' 'python-configshell-fb'
         'python-dbus' 'python-gobject')
makedepends=(python-build python-installer python-wheel)
optdepends=()
provides=('targetcli')
backup=()
options=()
install=
source=(https://github.com/open-iscsi/targetcli-fb/archive/v${pkgver}.tar.gz)
sha512sums=('b9a0dac75d979df7639b88f755194c41ea2156af7ebfa43aae27186ebe5e46ca7d9e24782c53da9d8915ca0772a7ba089dd725ce8c7cf05b1c0a85b7cd1fc929')


build() {
  cd "$srcdir/$pkgname-$pkgver"
  SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver python -m build --wheel --no-isolation
  gzip --stdout targetcli.8 > "targetcli.8.gz"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl

  install -D -m 644 targetcli.8.gz "$pkgdir/usr/share/man/man8/targetcli.8.gz"
  install -D -m 644 systemd/targetclid.service "$pkgdir/usr/lib/systemd/system/targetclid.service"
  install -D -m 644 systemd/targetclid.socket "$pkgdir/usr/lib/systemd/system/targetclid.socket"
  install -D -m 644 README.md "$pkgdir/usr/share/doc/targetcli/README.md"
  install -D -m 644 THANKS "$pkgdir/usr/share/doc/targetcli/THANKS"
}

Hello, please consider dropping python-ethtool optdepend, it's dead upstream and fails to build with python3.12.

Updated for 2.1.56

# Contributor: Johannes Dewender  arch at JonnyJD dot net
pkgname=targetcli-fb
pkgver=2.1.56
pkgrel=1
pkgdesc="free branch of the targetcli LIO administration shell (iSCSI + Co)"
arch=('any')
url="https://github.com/open-iscsi/targetcli-fb"
license=('Apache')
groups=()
depends=('python-rtslib-fb>=2.1.fb52' 'python-configshell-fb>=1.1.fb17'
         'python-dbus' 'python-gobject')
makedepends=('python-setuptools')
optdepends=('python-ethtool')
provides=('targetcli')
backup=()
options=()
install=
source=(https://github.com/open-iscsi/targetcli-fb/archive/v${pkgver}.tar.gz)
sha512sums=('ad115fc996a33d4b1800edec702cfcae2c4e86cceeb539163a6686cbdbdf285169aae94dd30d0bc7c5ac9c96e47d30bdb85006826c2345e67f0096a5b86143bd')


build() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i "s|/lib/systemd/system|lib/systemd/system|" setup.py
  python setup.py build
  gzip --stdout targetcli.8 > "targetcli.8.gz"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python setup.py install --skip-build --root="$pkgdir/" --optimize=1

  install -D -m 644 targetcli.8.gz "$pkgdir/usr/share/man/man8/targetcli.8.gz"
}

As of yesterday, Version 2.1.56 is available

This is already fixed in upstream, they just didn't release new version: https://github.com/open-iscsi/configshell-fb/commit/f3ac914861bd605e3d634aeeb5e706abdbd39259

This is not targetcli bug, this is configshell-fb bug.

Here's quick workaround: https://github.com/pyinvoke/invoke/issues/833#issuecomment-1396931531

The python package has been updated to 3.11 and targetcli no longer works.

Traceback (most recent call last):
  File "/usr/bin/targetcli", line 24, in <module>
    from targetcli import UIRoot
ModuleNotFoundError: No module named 'targetcli'

I run makepkg -si and the library is placed in the 3.11 path, but I am getting the following error

targetcli shell version 2.1.54
Copyright 2011-2013 by Datera, Inc and others.
For help on commands, type 'help'.

/> saveconfig 
Traceback (most recent call last):
  File "/usr/bin/targetcli", line 329, in <module>
    main()
  File "/usr/bin/targetcli", line 317, in main
    shell.run_interactive()
  File "/usr/lib/python3.11/site-packages/configshell_fb/shell.py", line 900, in run_interactive
    self._cli_loop()
  File "/usr/lib/python3.11/site-packages/configshell_fb/shell.py", line 729, in _cli_loop
    self.run_cmdline(cmdline)
  File "/usr/lib/python3.11/site-packages/configshell_fb/shell.py", line 843, in run_cmdline
    self._execute_command(path, command, pparams, kparams)
  File "/usr/lib/python3.11/site-packages/configshell_fb/shell.py", line 818, in _execute_command
    result = target.execute_command(command, pparams, kparams)
             ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
  File "/usr/lib/python3.11/site-packages/configshell_fb/node.py", line 1405, in execute_command
    self.assert_params(method, pparams, kparams)
  File "/usr/lib/python3.11/site-packages/configshell_fb/node.py", line 1420, in assert_params
    spec = inspect.getargspec(method)
           ^^^^^^^^^^^^^^^^^^
AttributeError: module 'inspect' has no attribute 'getargspec'. Did you mean: 'getargs'?

The same problem occurs when I install targetcli-fb using pip in python 3.11, but not in 3.10 built with pyenv, so this is most likely an upstream compatibility issue.

I think you need to add python 3.10 to the dependencies of this package or make it work in some other way.