Package Details: taskd-git 1.2.0-1

Git Clone URL: https://aur.archlinux.org/taskd-git.git (read-only)
Package Base: taskd-git
Description: A lightweight secure server providing multi-user, multi-client access to task data
Upstream URL: http://tasktools.org/projects/taskd.html
Licenses: MIT
Provides: taskd
Submitter: philpirj
Maintainer: alexei
Last Packager: alexei
Votes: 3
Popularity: 0.000001
First Submitted: 2013-08-25 20:58
Last Updated: 2017-09-24 23:17

Latest Comments

x25e0 commented on 2018-02-22 20:44

The package doesn't build because the repositories have moved, changing the source and the git submodules seems to be a slightly evil temporary fix.

# Maintainer: Pablo Couto <pablo at 0x221e dot net>
# Contributor: Alan Young <harleypig at gmail dot com>
# Contributor: Phil Pirozhkov <pirjsuka at gmail dot com>
#
# This PKGBUILD is based on the one written by Alan Young <harleypig at gmail
# dot com> (https://github.com/harleypig/abs/tree/463a8ac/aur/taskd-git)

pkgname=taskd-git
pkgver=1.2.0.r354.g1c16d7f
pkgrel=1
_branch=1.2.0
pkgdesc="A lightweight secure server providing multi-user, multi-client
 access to task data"
url='http://tasktools.org/projects/taskd.html'
license=('MIT')

install=taskd.install

source=("${pkgname}::git+https://github.com/GothenburgBitFactory/taskserver#branch=${_branch}"
        'taskd.conf'
        'taskd.notes'
        'taskd.service')

sha256sums=('SKIP'
            '5e518f8dda08c8b8d564f2a52452227924ebb15ec8182e7af83cc1f82cfa4cf1'
            '784116a5f749d113f05f46c3e1f362c0237d3e8748abd1f5856b9baaa26bd935'
            '8881a2272471762309748b4fcfe6e442ddca618757c08160f9e388fb43a2a208')

arch=('i686' 'x86_64' 'armv6h' 'armv7h')
backup=('etc/conf.d/taskd')
depends=('libutil-linux' 'gnutls')
makedepends=('git' 'cmake')
provides=('taskd')

pkgver() {
    cd "${pkgname}"
    git describe --long origin/$_branch | sed 's/^s//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd ${srcdir}/${pkgname}
    sed -i 's:git.tasktools.org/TM:github.com/GothenburgBitFactory:' ./.gitmodules
    sed -i 's:git.tasktools.org/TM:github.com/GothenburgBitFactory:' ./.git/config
    git submodule init
    git config submodule.libshared.url src/libshared
    git submodule update
}

build() {
    cd "${srcdir}/${pkgname}"

    cmake_opts="${cmake_opts} -Wno-devs"
    cmake_opts="${cmake_opts} -DCMAKE_INSTALL_PREFIX=/usr"

    cmake $cmake_opts .
    make
}

check() {
    cd "${srcdir}/${pkgname}"
    make test
    cd test
    make
    ./run_all
}

package() {
    cd "${srcdir}/${pkgname}"

    make DESTDIR="${pkgdir}" install

    install -Dm644 LICENSE \
            "${pkgdir}/usr/share/licenses/taskd-git/LICENSE"
    install -Dm644 ../taskd.conf \
            "${pkgdir}/etc/conf.d/taskd"
    install -Dm644 ../taskd.notes \
            "${pkgdir}/usr/lib/taskd/taskd.notes"
    install -Dm755 pki/generate.ca \
            "${pkgdir}/usr/lib/taskd/pki/generate.ca"
    install -Dm755 pki/generate.client \
            "${pkgdir}/usr/lib/taskd/pki/generate.client"
    install -Dm755 pki/generate.crl \
            "${pkgdir}/usr/lib/taskd/pki/generate.crl"
    install -Dm755 pki/generate \
            "${pkgdir}/usr/lib/taskd/pki/generate"
    install -Dm755 pki/generate.server \
            "${pkgdir}/usr/lib/taskd/pki/generate.server"
    install -Dm644 pki/vars \
            "${pkgdir}/usr/lib/taskd/pki/vars"
    install -Dm644 pki/README \
            "${pkgdir}/usr/lib/taskd/pki/README"

    # TODO: Install a modified .service where logging is fixed,
    #       until upstream fixes issue TD-136
    #install -Dm644 scripts/systemd/taskd.service \
    #        "${pkgdir}/usr/lib/systemd/system/taskd.service"
    install -Dm644 ${srcdir}/taskd.service \
            "${pkgdir}/usr/lib/systemd/system/taskd.service"
}

bbaserdem commented on 2018-02-06 00:24

Build fails due to copyright page not updated to 2018;

not ok 1 - version.t: Copyright is current

FAIL: AssertionError on file /tmp/trizen/taskd-git/src/taskd-git/test/version.t line 67 in test_version: 'self.assertRegexpMatches(out.decode("utf8"), expected)':
Regexp didn't match: 'Copyright \(C\) \d{4} - 2018' not found in u"
\x1b[1mtaskd 1.2.0\x1b[0m fa9b4ba built for Linux
Copyright (C) 2010 - 2017 G\xf6teborg Bit Factory.

It's a ridiculous upstream problem.

alexei commented on 2017-09-24 23:20

@Zebradil: switched URL, thx.
@lvsv: patched, thx.
@ackthet: got that from upstream .service.
@redfish: incorporated.

Zebradil commented on 2017-04-09 19:31

Source URL changed: https://git.tasktools.org/TM/taskd.git

lvsv commented on 2016-06-26 23:00

if you get something like this:
CMake Error: Cannot determine link language for tar get "libshared"

Just add in PKGBUILD

prepare() {
cd "${srcdir}/${pkgname}"
git submodule init
git config submodule.mysubmodule.url src/libshared
git submodule update
}

And if you have problems with tests (as i had), change makedepeneds
makedepends=('git' 'cmake' 'python' 'python2')
and add export in check()
export LANG="en_US.UTF8"

redfish commented on 2016-05-27 14:45

Currently, the version string generated by pkgver() is wrong. It confuses yaourt into thinking that package is out of date, because the version in .SRCINFO compares unfavorably. Here's a simple fix, please apply it:

_branch=1.2.0
source=(...#branch=1.2.0)
...
pkgver() {
cd $pkgname
git describe --long origin/$_branch | sed 's/^s//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

UPDATE: Also, in taskd.install please do not delete users and groups, this is against policy, because it creates orphan files on the filesystem. Also, do not enable, nor start, nor stop the systemd service in .install - that is up to the user (also, the 'preset' command generates a warning). Basically, remove pre_remove(), post_remove() and the systemctl command from post_install().

Minor: consider adding 'armv7h' to the list. It builds and works on ARM.

ackthet commented on 2016-04-04 12:59

Could you please modify the systemd unit file to use the extra security precautions found in the unit file here: https://taskwarrior.org/docs/taskserver/control.html

philpirj commented on 2014-04-11 06:39

@harleypig Probably you should take over, I'm not using this on my own

harleypig commented on 2014-04-10 16:29

I have a pkgbuild for taskd-git that seems to work for me. It creates a user and group and adds the various systemd stuff.

Feel free to incorporate whatever you want from it.

In any case, I'm new to making packages (excepting perl packages) and would be interested in any feedback on how to improve it.

https://github.com/harleypig/abs/tree/master/aur/taskd-git

philpirj commented on 2013-11-22 07:15

Updated according to last three notes. Sorry for delay.

All comments