Package Details: termusic 0.7.11-4

Git Clone URL: https://aur.archlinux.org/termusic.git (read-only, click to copy)
Package Base: termusic
Description: Music Player TUI written in Rust
Upstream URL: https://github.com/tramhao/termusic
Keywords: music player
Licenses: GPL3, MIT
Submitter: orhun
Maintainer: orhun
Last Packager: orhun
Votes: 5
Popularity: 0.010840
First Submitted: 2021-09-23 20:37 (UTC)
Last Updated: 2023-11-02 11:38 (UTC)

Latest Comments

orhun commented on 2023-07-27 14:31 (UTC)

PKGBUILD updated.

willemw commented on 2023-07-27 14:10 (UTC)

Note: it should be possible have here a single cargo build and a single cargo test line.

orhun commented on 2023-07-26 11:44 (UTC)

PKGBUILD updated.

seeu100 commented on 2023-07-24 15:30 (UTC)

PKGBUILD need update

# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds

pkgname=termusic
pkgver=0.7.11
pkgrel=1
pkgdesc="Music Player TUI written in Rust"
arch=('x86_64')
url="https://github.com/tramhao/termusic"
license=('MIT' 'GPL3')
depends=('gstreamer' 'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-bad' 'gst-plugins-ugly' 'gst-libav' 'dbus' 'ueberzug' 'protobuf')
optdepends=('yt-dlp: download mp3'
            'ffmpeg: download mp3')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('67f0b06ff37dbc3d16c77c6bdd0163dc547fbea1a25b3a7574b4540a4ad3a2059dc547d49411803fd9aa162d4f432ff5b99bef1e0f5c362342943fa76985f443')
options=('!lto')

prepare() {
  cd "$pkgname-$pkgver"
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "$pkgname-$pkgver"
  cargo build --bin termusic --features cover --release --frozen
  cargo build --bin termusic-server --features cover --release --frozen
}

check() {
  cd "$pkgname-$pkgver"
  cargo test --bin termusic --frozen
  cargo test --bin termusic-server --frozen
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  install -Dm 755 "target/release/$pkgname-server" -t "$pkgdir/usr/bin"
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  install -Dm 644 LICENSE_MIT -t "$pkgdir/usr/share/licenses/$pkgname"
}