# Maintainer: Tristelune  <tristelune at archlinux dot info>

pkgname=ufraw-cvs
pkgver=20141214
pkgrel=1
pkgdesc="Standalone or gimp plugin converter for raw files"
arch=('i686' 'x86_64')
url="http://ufraw.sourceforge.net"
license=('GPL2')
depends=('gtkimageview' 'lcms>=1.13' 'lensfun' 'exiv2')
makedepends=('cvs' 'automake')
optdepends=('gimp: to use the gimp import plugin for raw images'
            'cinepaint: to use the cinepaint plugin'
            'libtiff: to create TIFF images'
            'libjpeg-turbo: to create JPEG images'
            'libpng: to create PNG images'
            'cfitsio: to create FITS images'
            'zlib: to read gzipped RAW files'
            'bzip2: to read bzipped RAW files')
provides=('gimp-ufraw')
conflicts=('gimp-ufraw')

_cvsroot=":pserver:anonymous@ufraw.cvs.sourceforge.net:/cvsroot/ufraw" 
_cvsmod="ufraw"

build() {
  cd "$srcdir"
  msg "Connecting to $_cvsmod.sourceforge.net CVS server...."

  if [[ -d "$_cvsmod/CVS" ]]; then
    cd "$_cvsmod"
    cvs -z3 update -d
  else
    cvs -z3 -d "$_cvsroot" co -D "$pkgver" -f "$_cvsmod"
    cd "$_cvsmod"
  fi

  msg "CVS checkout done or server timeout"
  msg "Starting build..."

  rm -rf "$srcdir/$_cvsmod-build"
  cp -r "$srcdir/$_cvsmod" "$srcdir/$_cvsmod-build"
  cd "$srcdir/$_cvsmod-build"

  #
  # BUILD HERE
  #
  ./autogen.sh
  ./configure --prefix=/usr \
  --enable-extras \
  --enable-mime \
  --enable-dst-correction \
  --enable-contrast 
  make 
}

package() {
  cd "$srcdir/$_cvsmod-build"
  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et: