# Maintainer: Andy Weidenbaum <archbaum@gmail.com>

pkgname=vim-lengthmatters-git
pkgver=20140921
pkgrel=1
pkgdesc="Highlight the flooding part of an overly long line"
arch=('any')
depends=('vim')
makedepends=('git')
groups=('vim-plugins')
url="https://github.com/whatyouhide/vim-lengthmatters"
license=('WTFPL')
source=(${pkgname%-git}::git+https://github.com/whatyouhide/vim-lengthmatters)
sha256sums=('SKIP')
provides=('vim-lengthmatters')
conflicts=('vim-lengthmatters')
install=vimdoc.install

pkgver() {
  cd ${pkgname%-git}
  git log -1 --format="%cd" --date=short | sed "s|-||g"
}

package() {
  cd ${pkgname%-git}

  msg 'Installing documentation...'
  install -Dm 644 README.md "$pkgdir/usr/share/doc/vim-lengthmatters/README.md"

  msg 'Installing appdirs...'
  install -dm 755 "$pkgdir/usr/share/vim/vimfiles"
  for _appdir in autoload doc plugin; do
    cp -dpr --no-preserve=ownership $_appdir "$pkgdir/usr/share/vim/vimfiles/$_appdir"
  done

  msg 'Cleaning up pkgdir...'
  find "$pkgdir" -type d -name .git -exec rm -r '{}' +
  find "$pkgdir" -type f -name .gitignore -exec rm -r '{}' +
}