Arch Linux User Repository

@xantares repository wine is compiled with lto disabled, so this flag is not needed. You can compare with repository wine-staging, which does not used this compiler flag, and is basically the same.

wine has -ffat-lto-objects c flag, I dont know if it should be added there too

For build I have to add -I/usr/include/freetype2 to CFLAGS. No idea what exactly broke, but this is needed for the 64Bit build.

EDIT: Apparently I lost some files from libsysprof-capture. No idea how, but reinstalling that fixed it...

@rtentser I modified this PKGBUILD yesterday for a different purpose (applying a patch), but you can easily modify what I used for the same purpose (I removed my stuff that's irrelevant to you).

Just edit pkgver, _pkgver, and the checksum for that tarball; then, delete the hidden .SRCINFO file from the snapshot here and run: makepkg --printsrcinfo &> .SRCINFO, rename wine-git.install to wine.install, then you can make the package.

# Maintainer : Daniel Bermond <dbermond@archlinux.org>
# Contributor: Sidney Crestani <sidneycrestani@archlinux.net>
# Contributor: sxe <sxxe@gmx.de>

pkgname=wine
pkgver=7.0rc4
_pkgver=7.0-rc4
pkgrel=1
pkgdesc='A compatibility layer for running Windows programs (git version)'
arch=('x86_64' 'x86_64_v3')
url='https://www.winehq.org/'
license=('LGPL')
depends=(
    'fontconfig'            'lib32-fontconfig'
    'lcms2'                 'lib32-lcms2'
    'libxml2'               'lib32-libxml2'
    'libxcursor'            'lib32-libxcursor'
    'libxrandr'             'lib32-libxrandr'
    'libxdamage'            'lib32-libxdamage'
    'libxi'                 'lib32-libxi'
    'gettext'               'lib32-gettext'
    'freetype2'             'lib32-freetype2'
    'glu'                   'lib32-glu'
    'libsm'                 'lib32-libsm'
    'gcc-libs'              'lib32-gcc-libs'
    'libpcap'               'lib32-libpcap'
    'faudio'                'lib32-faudio'
    'desktop-file-utils'
)
makedepends=('git' 'autoconf' 'bison' 'perl' 'fontforge' 'flex' 'mingw-w64-gcc'
    'giflib'                'lib32-giflib'
    'libpng'                'lib32-libpng'
    'gnutls'                'lib32-gnutls'
    'libxinerama'           'lib32-libxinerama'
    'libxcomposite'         'lib32-libxcomposite'
    'libxmu'                'lib32-libxmu'
    'libxxf86vm'            'lib32-libxxf86vm'
    'libldap'               'lib32-libldap'
    'mpg123'                'lib32-mpg123'
    'openal'                'lib32-openal'
    'v4l-utils'             'lib32-v4l-utils'
    'libpulse'              'lib32-libpulse'
    'alsa-lib'              'lib32-alsa-lib'
    'libxcomposite'         'lib32-libxcomposite'
    'mesa'                  'lib32-mesa'
    'libgl'                 'lib32-libgl'
    'opencl-icd-loader'     'lib32-opencl-icd-loader'
    'libxslt'               'lib32-libxslt'
    'gst-plugins-base-libs' 'lib32-gst-plugins-base-libs'
    'vulkan-icd-loader'     'lib32-vulkan-icd-loader'
    'vkd3d'                 'lib32-vkd3d'
    'sdl2'                  'lib32-sdl2'
    'libcups'               'lib32-libcups'
    'libgphoto2'            'tar'
    'sane'
    'gsm'
    'vulkan-headers'
    'opencl-headers'
    'samba'
)
optdepends=(
    'giflib'                'lib32-giflib'
    'libpng'                'lib32-libpng'
    'libldap'               'lib32-libldap'
    'gnutls'                'lib32-gnutls'
    'mpg123'                'lib32-mpg123'
    'openal'                'lib32-openal'
    'v4l-utils'             'lib32-v4l-utils'
    'libpulse'              'lib32-libpulse'
    'alsa-plugins'          'lib32-alsa-plugins'
    'alsa-lib'              'lib32-alsa-lib'
    'libjpeg-turbo'         'lib32-libjpeg-turbo'
    'libxcomposite'         'lib32-libxcomposite'
    'libxinerama'           'lib32-libxinerama'
    'opencl-icd-loader'     'lib32-opencl-icd-loader'
    'libxslt'               'lib32-libxslt'
    'gst-plugins-base-libs' 'lib32-gst-plugins-base-libs'
    'vulkan-icd-loader'     'lib32-vulkan-icd-loader'
    'vkd3d'                 'lib32-vkd3d'
    'sdl2'                  'lib32-sdl2'
    'libgphoto2'
    'sane'
    'gsm'
    'cups'
    'samba'
    'dosbox'
)
# LTO has to be disabled for 7.0-rc4 or else the build will fail
options=('staticlibs' '!lto')
install="${pkgname}.install"
provides=("wine=${pkgver}" "bin32-wine=${pkgver}" "wine-wow64=${pkgver}")
conflicts=('wine-git' 'bin32-wine' 'wine-wow64' 'wine-staging')
replaces=('bin32-wine')
source=("${pkgname}-${_pkgver}.tar.gz::https://github.com/wine-mirror/wine/archive/refs/tags/${pkgname}-${_pkgver}.tar.gz"
        '30-win32-aliases.conf'
        'wine-binfmt.conf'
        )
sha256sums=('7a294575bdc5ded333121db9c6d392a36cc506a0ee66c4089442a15e1dc42fdf'
            '9901a5ee619f24662b241672a7358364617227937d5f6d3126f70528ee5111e7'
            '6dfdefec305024ca11f35ad7536565f5551f09119dda2028f194aee8f77077a4')

prepare() {
    rm -rf build-{32,64}
    mkdir -p build-{32,64}
    tar xvf ${pkgname}-${_pkgver}.tar.gz
    mv ${pkgname}-${pkgname}-${_pkgver} wine

    # fix path of opencl headers
    sed 's|OpenCL/opencl.h|CL/opencl.h|g' -i wine/configure*

    # fix openldap 2.5+ detection
    sed 's/-lldap_r/-lldap/' -i wine/configure
}

## Leftover from wine-git PKGBUILD; commented out to prevent makepkg failure
#pkgver() {
#    git -C wine describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^wine.//;s/^v//;s/\.rc/rc/'
#}

build() {
    # workaround for FS#55128
    # https://bugs.archlinux.org/task/55128
    # https://bugs.winehq.org/show_bug.cgi?id=43530
    export CFLAGS="${CFLAGS/-fno-plt/}"
    export LDFLAGS="${LDFLAGS/,-z,now/}"

    # Enforce gcc and g++ and unset potential globally set Clang and any potentially globally set LLVM variables
    export CC=gcc
    export CXX=g++
    export LD=ld
    export AR=""
    export NM=""
    export RANLIB=""
    export STRIP=""
    export OBJCOPY=""
    # Reset debug flags to makepkg.conf defaults, in case Clang is globally set
    export DEBUG_CFLAGS="-g -fvar-tracking-assignments"
    export DEBUG_CXXFLAGS="-g -fvar-tracking-assignments"
    # -O3 optimization because we can :p
    export CFLAGS+=" -O3"
    export LDFLAGS+=" -O3"
    export CROSSCFLAGS=" -g -O3"

    # build wine 64-bit
    # (according to the wine wiki, this 64-bit/32-bit building order is mandatory)
    printf '%s\n' '  -> Building wine-64...'
    cd build-64
    ../wine/configure \
        --prefix='/usr' \
        --libdir='/usr/lib' \
        --with-x \
        --with-gstreamer \
        --enable-win64
    make

    # build wine 32-bit
    printf '%s\n' '  -> Building wine-32...'
    cd "${srcdir}/build-32"
    export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
    ../wine/configure \
        --prefix='/usr' \
        --libdir='/usr/lib32' \
        --with-x \
        --with-gstreamer \
        --with-wine64="${srcdir}/build-64"
    make
}

package() {
    # package wine 32-bit
    # (according to the wine wiki, this reverse 32-bit/64-bit packaging order is important)
    printf '%s\n' '  -> Packaging wine-32...'
    cd build-32
    make prefix="${pkgdir}/usr" \
         libdir="${pkgdir}/usr/lib32" \
         dlldir="${pkgdir}/usr/lib32/wine" \
         install

    # package wine 64-bit
    printf '%s\n' '  -> Packaging wine-64...'
    cd "${srcdir}/build-64"
    make prefix="${pkgdir}/usr" \
         libdir="${pkgdir}/usr/lib" \
         dlldir="${pkgdir}/usr/lib/wine" \
         install

    # font aliasing settings for win32 applications
    install -d -m755 "${pkgdir}/usr/share/fontconfig/conf.default"
    install -D -m644 "${srcdir}/30-win32-aliases.conf" -t "${pkgdir}/usr/share/fontconfig/conf.avail"
    ln -s ../conf.avail/30-win32-aliases.conf "${pkgdir}/usr/share/fontconfig/conf.default/30-win32-aliases.conf"

    # wine binfmt
    install -D -m644 "${srcdir}/wine-binfmt.conf" "${pkgdir}/usr/lib/binfmt.d/wine.conf"

    # strip native PE libraries
    i686-w64-mingw32-strip --strip-unneeded "${pkgdir}/usr/lib32/wine/i386-windows"/*.dll
    "${CARCH}-w64-mingw32-strip" --strip-unneeded "${pkgdir}/usr/lib/wine/${CARCH}-windows"/*.dll
}

@katt implemented.

Could you include the recent fontconfig changes? https://github.com/archlinux/svntogit-community/commit/07fccfd3a8e0951146a6d907bae3b6858c20232a

@rtentser This package is not for building older versions of wine, and neither for bisecting, but it's for building the latest git master code.

@katt I want to be able to build older versions of wine from this package for bisecting.

@rtentser Sounds like you want wine-stable.

Can't build wine-5.0 with this.

winebuild: /usr/bin/ld failed with status 1 winegcc: ../../tools/winebuild/winebuild failed make[1]: [Makefile:755: crypt32.dll.so] Error 2 make[1]: Leaving directory '/home/rtentser/Sources/AUR/wine-git/src/build-64/dlls/crypt32' make: [Makefile:9177: dlls/crypt32] Error 2 ../../tools/winegcc/winegcc -o ctapi32.dll.fake --wine-objdir ../.. -m64 -fPIC -fasynchronous-unwind-tables \ -shared ../../../wine/dlls/ctapi32/ctapi32.spec ctapi32.o -ladvapi32 \ ../../libs/port/libwine_port.a -Wl,-O1,--sort-common,--as-needed,-z,relro make: *** Waiting for unfinished jobs.... ../../../tools/winegcc/winegcc -o cryptui_test-stripped.exe --wine-objdir ../../.. -b x86_64-w64-mingw32 \ --lib-suffix=.cross.a -s -Wb,-F,cryptui_test.exe -mno-cygwin cryptui.cross.o testlist.cross.o \ ../../../dlls/cryptui/libcryptui.cross.a ../../../dlls/crypt32/libcrypt32.cross.a \ ../../../dlls/user32/libuser32.cross.a ../../../tools/winegcc/winegcc -o cryptui_test.exe --wine-objdir ../../.. -b x86_64-w64-mingw32 \ --lib-suffix=.cross.a -mno-cygwin cryptui.cross.o testlist.cross.o \ ../../../dlls/cryptui/libcryptui.cross.a ../../../dlls/crypt32/libcrypt32.cross.a \ ../../../dlls/user32/libuser32.cross.a echo "cryptui_test.exe TESTRES \"cryptui_test-stripped.exe\"" | ../../../tools/wrc/wrc -o ../../../programs/winetest/cryptui_test.res make[1]: Leaving directory '/home/rtentser/Sources/AUR/wine-git/src/build-64/dlls/cryptui/tests' make[1]: Leaving directory '/home/rtentser/Sources/AUR/wine-git/src/build-64/dlls/ctapi32' ==> ERROR: A failure occurred in build(). Aborting...

@ekce xorgproto is being automatically pulled. Package is currently building fine without modifications.

This package now requires xorgproto.

@electricprism The version will be automatically updated by the pkgver() function when you run makepkg. No need to update the major version at each upstream release. This is how VCS packages work. See the Wiki:

https://wiki.archlinux.org/index.php/PKGBUILD#pkgver

https://wiki.archlinux.org/index.php/VCS_package_guidelines#The_pkgver()_function

I noticed that the version on this package is 3.18 prefix but current version of wine is 4.6 https://www.winehq.org/announce/4.6

Maybe if you want to drop the subversion and keep the main number which will increment annually that might be a good idea or use something else to minimize confusion I'd like to suggest it.

I'm not sure why but using this package, I cannot use Steam in offline mode. The standard arch package works fine but with wine-git steam via wine doesn't connect. Is there something I can add to the ./configure or make line to enable networking?

I'm not sure if it's a problem with wine itself or this package but it makes it slightly difficult to try custom patches in wine if you need to test a steam game.

@Morguldir Thank you for reporting this. Package updated.

They applied the freetype patch upstream

https://source.winehq.org/git/wine.git/commitdiff/66e446c5ec5c7f4f072358712151d75305dfbd49?hp=935eed8e980a62557b19b3313e32106752b4e4f6

@Enverex If you are building with avx support enabled then you're modifying the default Arch Linux build flags. By doing this you're pretty aware of the issues that it can cause (like the one you're having). Users wanting the most vanilla experience should 1) not modify the build flags, and/or 2) build the package in a clean chroot. It's user reponsibility to control the build flags, unless some major intervention is required.

Forcedly disabling avx support is not a good idea. Firstly, because it's not intended to use avx by default in any way (due to the default Arch build flags being x86_64 generic ones). Secondly, because it will impact users that want to benefit from avx support. Thirdly, because this is affecting only your application. If it would be a broad wine issue affecting a huge amount of applications, then well, we could disable avx here, but this is not the case.

I suggest you to fill a bug report in upstream wine saying that you're having issues in your application when avx is enabled, instead of asking for forcedly disabling avx here.

@dbermond - Wine will literally just crash if it tries to use it, there is no benefit to leaving it enabled. You have 2 possible situations:

1. The user doesn't have an AVX capable CPU, the flag won't do anything because AVX was never supported in the first place.

2. The user has an AVX capable CPU. As soon as Wine tries to use AVX, Wine will crash. Adding the flag negates this situation.

Essentially leaving AVX enabled will do nothing other than cause Wine to crash whenever it's used (universally, until it's fixed upstream, if that will actually happen). There is zero positive to enabling the flag (which will be enabled by default for anyone using native or CPU specific compiler flags).

But it's up to you.

@Enverex I don't think it's a good idea to force users to compile without avx support. It can be a user choice to use avx.

@dbermond - I've actually tracked down the real reason now. It will technically affect anyone with an AVX capable processor but only triggers in very rare circumstances: https://bugs.winehq.org/show_bug.cgi?id=45289

May be worth adding "-mno-avx" to C/XXFLAGS in the build section somewhere to negate it.

@Enverex I'm glad that you found the answer. But yes, this package is the same as wine from the official repositories, except for being the development version.

Packages from the official repositories are built in a clean chroot to avoid linking against undesired libraries and other interferences that may occur. For example, in a chroot it will not link against any nvidia specific library that the user might have installed. In order to better reproduce the official repository package, the user should build it in a clean chroot. And as you know, official repository packages are built with generic x86_64 compiler flags, and this can also cause runtime differences.

Cemu crashes in Mario Kart 8 with this (even when set to the 3.9 release commit specificall) but not the stock repo Wine.

The actual build looks pretty much the same between this and the stock Arch repo version. Is there anything else different in the build script here that could be responsible for this different behaviour?

EDIT: Looks like it may be a GCC issue. It only happens if compiled with -march=native (i7-8700K).

@EndlessEden Segfault at compile time? Package is building fine for me.

i segfault with this. idk why...