AUR (en) - xfce4-notifyd-git

Git Clone URL:	https://aur.archlinux.org/xfce4-notifyd-git.git (read-only, click to copy)
Package Base:	xfce4-notifyd-git
Description:	notification daemon for the xfce desktop - git checkout
Upstream URL:	http://goodies.xfce.org/projects/applications/xfce4-notifyd
Licenses:	GPL
Groups:	xfce4-goodies
Conflicts:	xfce4-notifyd
Provides:	notification-daemon, xfce4-notifyd
Submitter:	None
Maintainer:	jgmdev
Last Packager:	jgmdev
Votes:	7
Popularity:	0.000137
First Submitted:	2009-02-21 15:59 (UTC)
Last Updated:	2024-09-16 03:26 (UTC)

Latest Comments

kIERO commented on 2025-12-26 16:48 (UTC)

==> Starting build()...
/home/mb/.cache/yay/xfce4-notifyd-git/PKGBUILD: line 35: ./autogen.sh: No such file or directory
==> ERROR: A failure occurred in build().
    Aborting...
 -> error making: xfce4-notifyd-git-exit status 4
 -> Failed to install the following packages. Manual intervention is required:

Here is a clean PKGBUILD that works with meson.

# Maintainer: Jefferson Gonzalez <jgmdev@gmail.com>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Zbyszek Tokarczyk <ztokarczyk (at) Gmail.com>
# Contributor: Manuel Barrio Linares <mbarriolinares at gmail dot com>

pkgname=xfce4-notifyd-git
pkgver=0.9.7.r301.g304f03a-
pkgrel=1
pkgdesc='Notification daemon for the Xfce desktop (git)'
arch=('x86_64')
license=('GPL')
url='https://gitlab.xfce.org/apps/xfce4-notifyd'
groups=('xfce4-goodies')
depends=(
  'libxfce4ui'
  'hicolor-icon-theme'
  'libnotify'
  'wayland'
  'gtk3'
)
makedepends=(
  'git'
  'meson'
  'ninja'
  'xfce4-dev-tools'
  'intltool'
)
conflicts=('xfce4-notifyd')
provides=('xfce4-notifyd' 'notification-daemon')
options=('!lto')
source=('git+https://gitlab.xfce.org/apps/xfce4-notifyd.git')
sha256sums=('SKIP')

pkgver() {
  cd xfce4-notifyd
  git describe --long --tags --abbrev=7 | sed 's/^xfce4-notifyd-//; s/-/.r/; s/-/./'
}

build() {
  cd xfce4-notifyd

  arch-meson build \
    --prefix=/usr \
    -Dx11=enabled \
    -Dwayland=enabled \
    -Ddbus-service-dir= \
    -Dsystemd-user-service-dir=

  meson compile -C build
}

package() {
  cd xfce4-notifyd
  meson install -C build --destdir "$pkgdir"
}

kode54 commented on 2024-09-27 06:01 (UTC)

Still needs libnotify, and also needs a makdepend of glib2-devel, and xfce4-dev-tools-git since the stable version is too old to build it now, and also libxfce4ui>=4.19.0 and xfce4-panel>=4.19.0.

dude commented on 2021-06-21 21:12 (UTC)

Can you add libnotify as a dependency please? Build fails without it.

godlikemouse commented on 2021-06-03 03:12 (UTC) (edited on 2021-06-03 03:13 (UTC) by godlikemouse)

I'm seeing a dependency error on libxfce4ui-1, is there a workaround available for this?

checking for libxfce4ui-1 >= 4.8.0... not found
*** The required package libxfce4ui-1 was not found on your system.
*** Please install libxfce4ui-1 (atleast version 4.8.0) or adjust
*** the PKG_CONFIG_PATH environment variable if you
*** installed the package in a nonstandard prefix so that
*** pkg-config is able to find it.

Current installed libxfce4ui:

$ pacman -Qs libxfce4ui
local/libxfce4ui 4.16.0-1
    Commonly used Xfce widgets among Xfce applications

twa022 commented on 2017-09-09 12:42 (UTC)

Please add xfce4-panel to makedepends (can replace exo since it depends on it) and optdepends. xfce4-notifyd now supplies a panel plugin. Also install script is no longer necessary.