Package Details: xivlauncher-cn 1.0.0.9-2

Git Clone URL: https://aur.archlinux.org/xivlauncher-cn.git (read-only, click to copy)
Package Base: xivlauncher-cn
Description: Custom launcher for FFXIV CN
Upstream URL: https://github.com/ottercorp/FFXIVQuickLauncher/
Licenses: GPL
Conflicts: xivlauncher
Provides: xivlauncher
Submitter: lq95v5
Maintainer: lq95v5
Last Packager: lq95v5
Votes: 1
Popularity: 0.151774
First Submitted: 2022-09-26 07:29 (UTC)
Last Updated: 2022-09-26 08:40 (UTC)

Latest Comments

heddxh commented on 2023-01-15 09:07 (UTC) (edited on 2023-01-15 09:08 (UTC) by heddxh)

仓库又更新了，改了下PKGBUILD 依照上游直接使用core仓库，加上了submodule（照着国际服抄的）

# Maintainer: Qiang <lq95v5@gmail.com>
# Editted by heddxh (2023-01-15)
pkgname=xivlauncher-cn
pkgver=1.0.1.0
_pkgver=ae08df3a025c8178d104ba8356cdb90b82362539
pkgrel=1
pkgdesc="Custom launcher for FFXIV CN"
arch=('x86_64')
url='https://github.com/ottercorp/FFXIVQuickLauncher/'
license=('GPL')
depends=(
    'aria2'
    'sdl2' 'lib32-sdl2'
    'libsecret'
    'attr'                  'lib32-attr'
    'fontconfig'            'lib32-fontconfig'
    'lcms2'                 'lib32-lcms2'
    'libxml2'               'lib32-libxml2'
    'libxcursor'            'lib32-libxcursor'
    'libxrandr'             'lib32-libxrandr'
    'libxdamage'            'lib32-libxdamage'
    'libxi'                 'lib32-libxi'
    'gettext'               'lib32-gettext'
    'freetype2'             'lib32-freetype2'
    'glu'                   'lib32-glu'
    'libsm'                 'lib32-libsm'
    'gcc-libs'              'lib32-gcc-libs'
    'libpcap'               'lib32-libpcap'
    'faudio'                'lib32-faudio'
    'desktop-file-utils'    'jxrlib'
)
makedepends=('dotnet-sdk>=6' 'python-yaml' 'git')
optdepends=('steam')
options=('!strip')
provides=("xivlauncher=${pkgver}")
conflicts=("xivlauncher")
source=(
    "XIVLauncher.Core::git+https://github.com/ottercorp/XIVLauncher.Core.git"
    "XIVLauncher.desktop"
)
sha512sums=(
    'SKIP'
    '7f6324cb31f99194fdd44c34b49bb3b7f04bad1b6cbb1b914959219b545bc3653643edac29134edebec82de00e36a83d1afdcc3e20f9bdaa9cbff8ceac3f5d16'
)

prepare() {
    cd "${srcdir}/XIVLauncher.Core"
    git submodule update --init --recursive
}

build() {
    mkdir -p "${srcdir}/build"
    mkdir -p "${srcdir}/build/Resources"
    cd "${srcdir}/XIVLauncher.Core/src/XIVLauncher.Core/"
    dotnet publish -r linux-x64 --sc -o "${srcdir}/build" --configuration Release -p:DefineConstants=WINE_XIV_ARCH_LINUX
}

package() {
    install -d "${pkgdir}/usr/bin/"
    install -d "${pkgdir}/opt/XIVLauncher/"
    install -D -m644 "${srcdir}/XIVLauncher.desktop" "${pkgdir}/usr/share/applications/XIVLauncher.desktop"
    install -D -m644 "${srcdir}/XIVLauncher.Core/misc/linux_distrib/512.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/xivlauncher.png"
    cp -r "${srcdir}/build/." "${pkgdir}/opt/XIVLauncher/"
    ln -s ../../opt/XIVLauncher/XIVLauncher.Core "${pkgdir}/usr/bin/XIVLauncher.Core"
}

leonacco commented on 2023-01-10 09:11 (UTC)

这个AUR git使用的是老把版本github软件源，下载后请将PKGBUILD文件下的_pkgver更改为_pkgver=3856b7394cc61d0cd93852c281c607c9cdf35277 进行安装。

参考文件：https://github.com/flathub/cn.ottercorp.xivlaunchercn/commit/0e988ce282bc12f9e4a2a6883717bed1f28a6c0a