Arch Linux User Repository

This is a working PKGBUILD:

# Maintainer: JonnyRobbie

pkgbase=xsane-git
pkgname=('xsane-git' 'xsane-gimp-git')
_gitname=xsane
pkgver=0.999.r319.g87edc38
# Bump pkgrel for our fixes
pkgrel=1
arch=('x86_64')
url="https://gitlab.com/sane-project/frontend/xsane"
license=('GPLv2')
# Add autoconf and automake for generating build scripts
makedepends=('autoconf' 'automake' 'gtk2' 'lcms2' 'sane' 'zlib' 'libjpeg' 'gimp')
source=("git+https://gitlab.com/sane-project/frontend/$_gitname.git")
sha512sums=('SKIP')

pkgver() {
  cd "$srcdir/$_gitname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

# Use prepare() to set up the source code before building
prepare() {
  cd "$srcdir/$_gitname"

  # Generate the ./configure script and other necessary build files
  # The -fiv flags mean: force, install missing auxiliary files, and be verbose
  autoreconf -fiv

  # Fix GTK+ timer callbacks that now require a pointer argument
  sed -i 's/static gint xsane_batch_scan_gamma_event()/static gint xsane_batch_scan_gamma_event(gpointer data)/' src/xsane-gamma.c
  sed -i 's/static gint xsane_slider_hold_event()/static gint xsane_slider_hold_event(gpointer data)/' src/xsane-gamma.c

  # Fix conflicting function types between declaration (.h) and definition (.c)
  sed -i 's/extern void xsane_cancel_save();/extern void xsane_cancel_save(int *cancel_save);/' src/xsane-save.h
}

build() {
  cd "$srcdir/$_gitname"

  # make with gimp support
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --enable-gimp
  make
  mv src/xsane src/xsane-gimp

  # make without gimp support
  make clean
  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --mandir=/usr/share/man \
    --disable-gimp
  make
}

package_xsane-git() {
  pkgdesc="A GTK-based X11 frontend for SANE and plugin for Gimp. Git version."
  depends=('gtk2' 'lcms2' 'sane' 'zlib' 'libjpeg')
  optdepends=('xsane-gimp-git: for gimp plugin support')
  conflicts=('xsane')
  provides=("xsane=$pkgver")

  cd "$srcdir/$_gitname"
  make DESTDIR="$pkgdir" install
}

package_xsane-gimp-git() {
  pkgdesc="XSane Gimp plugin. Git version."
  depends=('xsane-git' 'gimp')
  conflicts=('xsane-gimp')
  provides=("xsane-gimp=$pkgver")

  cd "$srcdir/$_gitname"
  # Corrected install path for gimp plugin
  install -D -m755 src/xsane-gimp "$pkgdir/usr/lib/gimp/2.0/plug-ins/xsane"
}

the ./configure script is missing from the source top dir (as it is a git revision. as of upstream commit 2eee8154). a manual running of autoreconf is required to make it available before build can proceed. at least until they'll plug an autogen.sh script or similar (this issue is 5 years old though https://gitlab.com/sane-project/frontend/xsane/-/issues/6)

This commit https://gitlab.com/sane-project/frontend/xsane/-/merge_requests/33/diffs#547fe0db6ad3e73c693d3deaddf315f4b467815d completely changed their build system. The other versions seem to work, because they build on top of old versions. Unfortunately, the new changes lack any documentation whatsoever on how to build it. I'll try to reverse engineer it, but if anyone has a hint, it would be helpful.

build error

/usr/bin/ld: xsane-back-gtk.o: undefined reference to symbol 'log10@@GLIBC_2.2.5'
/usr/bin/ld: /usr/lib/libm.so.6: error adding symbols: DSO missing from command line
collect2: error: ld returned 1 exit status
make[1]: *** [Makefile:118: xsane] Error 1
make[1]: Leaving directory '/home/fre/ARCH-AUR/xsane-git/src/xsane/src'
make: *** [Makefile:63: all-recursive] Error 1

Other "xsane" Aur package builds fine

Do you rely on a backend that may also need to be rebuilt?

I compile and get a segmentation fault when selecting the scanner. Any insight?

I can't reproduce your error, xsane-git works fine with official libtiff 4.5.1-1 and Gimp packages. Did you update your system or are you really using Arch ?

I was getting:

xsane: error while loading shared libraries: libtiff.so.5: cannot open shared object file: No such file or directory

Installing libtiff5 from aur fixed that. You might want to add it as a dependency.

EDIT: I'm actually dumb idiot - I am the owner of the package :D

It doesnt build with gimp-git

checking for pkg-config... /usr/bin/pkg-config
checking for GIMP - version >= 1.3.23...
*** Could not run GIMP test program, checking why...
*** The test program failed to compile or link. See the file config.log for the
*** exact error that occured. This usually means GIMP is incorrectly installed.
*** When gimp-2.0 is not installed but gimp-1.x is installed then you can
*** ignore this error message.

Same error with gimp 3.0 prefix

--with-gimp-prefix=/usr/include/gimp-3.0