Arch Linux User Repository

gimp 3.1 still looks in /usr/lib/gimp/3.0/plug-ins

I needed to fix the actual plugin subdir.

xsane plugin is not showing up in gimp 3.x. Please update installation of gimp 3.0 plugin in the prepare() method:

Gimp 3.0 expects each plugin to reside in a subfolder in /usr/lib/3.0/plugins:

prepare() {
  ...
  mkdir -p "$pkgdir/usr/lib/gimp/3.0/plug-ins/xsane"
  ln -sf /usr/bin/xsane-gimp "$pkgdir"/usr/lib/gimp/3.0/plug-ins/xsane/xsane
}

gimptool --gimplugindir can be used to determine the plugin directory for the installed version of GIMP, however I'm not sure how it can be used at run-time to create the required symbolic link, since the post_install script of a package is "run chrooted inside the pacman install directory" according to https://wiki.archlinux.org/title/PKGBUILD

/usr/lib/gimp/3.0/plug-ins not detected in Gimp 3.1 (git version)

Much thanks, @timothy.lee. I've just updated the pkgbuild.

Latest git switched to GTK3, and supports both GIMP 2.x and 3.x.

Here is an updated PKGBUILD file:

# Maintainer: JonnyRobbie

pkgbase=xsane-git
pkgname=('xsane-git' 'xsane-gimp-git')
_gitname=xsane
pkgver=0.999.r319.g87edc38
pkgrel=1
arch=(x86_64)
url="https://gitlab.com/sane-project/frontend/xsane"
license=('GPLv2')
makedepends=('autoconf' 'automake' 'gtk3' 'lcms2' 'sane' 'zlib' 'libjpeg' 'gimp')
source=(git+https://gitlab.com/sane-project/frontend/$_gitname.git)
sha512sums=('SKIP')

pkgver() {
  cd "$srcdir/$_gitname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$_gitname"
  autoreconf -fiv
}

build() {
  cd "$srcdir/$_gitname"

  # make with gimp support
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --enable-gimp
  make
  mv src/xsane src/xsane-gimp

  # make without gimp support
  make clean
  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --mandir=/usr/share/man \
    --disable-gimp
  make
}

package_xsane-git() {
  pkgdesc="A GTK-based X11 frontend for SANE and plugin for Gimp. Git version."
  depends=('gtk3' 'lcms2' 'sane' 'zlib' 'libjpeg')
  optdepends=('xsane-gimp: for gimp plugin support')
  conflicts=('xsane')
  provides=('xsane')

  cd "$srcdir/$_gitname"
  make DESTDIR=$pkgdir install
}

package_xsane-gimp-git() {
  pkgdesc="XSane Gimp plugin. Git version."
  depends=('xsane' 'gimp')
  conflicts=('xsane-gimp')
  provides=('xsane-gimp')

  cd "$srcdir/$_gitname"
  install -D -m755 src/xsane-gimp "$pkgdir/usr/bin/xsane-gimp"

  ## Link the plugin binary to gimp plug-in directories
  mkdir -p "$pkgdir/usr/lib/gimp/2.0/plug-ins"
  ln -sf /usr/bin/xsane-gimp "$pkgdir"/usr/lib/gimp/2.0/plug-ins/xsane
  mkdir -p "$pkgdir/usr/lib/gimp/3.0/plug-ins"
  ln -sf /usr/bin/xsane-gimp "$pkgdir"/usr/lib/gimp/3.0/plug-ins/xsane
}

For gimp 3.0 to recognize the xsane-gimp plugin it must be placed in the folder /usr/lib/gimp/3.0/plugins/xsane/

like this:

install -D -m755 src/xsane-gimp "$pkgdir/usr/lib/gimp/3.0/plug-ins/xsane/xsane"

This is a working PKGBUILD:

# Maintainer: JonnyRobbie

pkgbase=xsane-git
pkgname=('xsane-git' 'xsane-gimp-git')
_gitname=xsane
pkgver=0.999.r319.g87edc38
# Bump pkgrel for our fixes
pkgrel=1
arch=('x86_64')
url="https://gitlab.com/sane-project/frontend/xsane"
license=('GPLv2')
# Add autoconf and automake for generating build scripts
makedepends=('autoconf' 'automake' 'gtk2' 'lcms2' 'sane' 'zlib' 'libjpeg' 'gimp')
source=("git+https://gitlab.com/sane-project/frontend/$_gitname.git")
sha512sums=('SKIP')

pkgver() {
  cd "$srcdir/$_gitname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

# Use prepare() to set up the source code before building
prepare() {
  cd "$srcdir/$_gitname"

  # Generate the ./configure script and other necessary build files
  # The -fiv flags mean: force, install missing auxiliary files, and be verbose
  autoreconf -fiv

  # Fix GTK+ timer callbacks that now require a pointer argument
  sed -i 's/static gint xsane_batch_scan_gamma_event()/static gint xsane_batch_scan_gamma_event(gpointer data)/' src/xsane-gamma.c
  sed -i 's/static gint xsane_slider_hold_event()/static gint xsane_slider_hold_event(gpointer data)/' src/xsane-gamma.c

  # Fix conflicting function types between declaration (.h) and definition (.c)
  sed -i 's/extern void xsane_cancel_save();/extern void xsane_cancel_save(int *cancel_save);/' src/xsane-save.h
}

build() {
  cd "$srcdir/$_gitname"

  # make with gimp support
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --enable-gimp
  make
  mv src/xsane src/xsane-gimp

  # make without gimp support
  make clean
  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --mandir=/usr/share/man \
    --disable-gimp
  make
}

package_xsane-git() {
  pkgdesc="A GTK-based X11 frontend for SANE and plugin for Gimp. Git version."
  depends=('gtk2' 'lcms2' 'sane' 'zlib' 'libjpeg')
  optdepends=('xsane-gimp-git: for gimp plugin support')
  conflicts=('xsane')
  provides=("xsane=$pkgver")

  cd "$srcdir/$_gitname"
  make DESTDIR="$pkgdir" install
}

package_xsane-gimp-git() {
  pkgdesc="XSane Gimp plugin. Git version."
  depends=('xsane-git' 'gimp')
  conflicts=('xsane-gimp')
  provides=("xsane-gimp=$pkgver")

  cd "$srcdir/$_gitname"
  # Corrected install path for gimp plugin
  install -D -m755 src/xsane-gimp "$pkgdir/usr/lib/gimp/2.0/plug-ins/xsane"
}

the ./configure script is missing from the source top dir (as it is a git revision. as of upstream commit 2eee8154). a manual running of autoreconf is required to make it available before build can proceed. at least until they'll plug an autogen.sh script or similar (this issue is 5 years old though https://gitlab.com/sane-project/frontend/xsane/-/issues/6)

This commit https://gitlab.com/sane-project/frontend/xsane/-/merge_requests/33/diffs#547fe0db6ad3e73c693d3deaddf315f4b467815d completely changed their build system. The other versions seem to work, because they build on top of old versions. Unfortunately, the new changes lack any documentation whatsoever on how to build it. I'll try to reverse engineer it, but if anyone has a hint, it would be helpful.