Arch Linux User Repository

@PedroHLC: Here is what I use. This is basically the zfs-dkms-rc and zfs-utils-rc files just sourcing zfs-2.0.0. I did not change maintainer info etc.

The packages depend on each other. So you want to use the -d option with makepkg to compile the packages.

PKGBUILD zfs-dkms:

# Maintainer: Jan Houben <jan@nexttrex.de>
# Contributor: Jesus Alvarez <jeezusjr at gmail dot com>
#
# This PKGBUILD was generated by the archzfs build scripts located at
#
# http://github.com/archzfs/archzfs
#
pkgname="zfs-dkms"
pkgdesc="Kernel modules for the Zettabyte File System."

pkgver=2.0.0
pkgrel=1
makedepends=()
arch=("x86_64")
url="https://zfsonlinux.org/"
source=("https://github.com/zfsonlinux/zfs/releases/download/zfs-${pkgver/_/-}/zfs-${pkgver/_/-}.tar.gz")
sha256sums=('3403bf8e993f3c9d772f768142117df47bdbbb8e9bbf85a29c0e166f577f9311')
license=("CDDL")
depends=("zfs-utils=${pkgver}" "lsb-release" "dkms")
provides=("zfs" "zfs-headers" "spl" "spl-headers")
groups=("archzfs-dkms")
conflicts=("zfs" "zfs-headers" "spl" "spl-headers")

build() {
    cd "${srcdir}/zfs-${pkgver/_rc*/}"
    ./autogen.sh
}

package() {
    dkmsdir="${pkgdir}/usr/src/zfs-${pkgver}"
    install -d "${dkmsdir}"
    cp -a ${srcdir}/zfs-${pkgver/_rc*/}/. ${dkmsdir}
    cd "${dkmsdir}"
    find . -name ".git*" -print0 | xargs -0 rm -fr --
    scripts/dkms.mkconf -v ${pkgver} -f dkms.conf -n zfs
    chmod g-w,o-w -R .
}

PKGBUILD zfs-utils:

# Maintainer: Jan Houben <jan@nexttrex.de>
# Contributor: Jesus Alvarez <jeezusjr at gmail dot com>
#
# This PKGBUILD was generated by the archzfs build scripts located at
#
# http://github.com/archzfs/archzfs
#
pkgname="zfs-utils"

pkgver=2.0.0
pkgrel=1
pkgdesc="Kernel module support files for the Zettabyte File System."
makedepends=("python" "python-setuptools" "python-cffi")
optdepends=("python: pyzfs and extra utilities", "python-cffi: pyzfs")
arch=("x86_64")
url="http://zfsonlinux.org/"
source=("https://github.com/zfsonlinux/zfs/releases/download/zfs-${pkgver/_/-}/zfs-${pkgver/_/-}.tar.gz"
        "zfs-utils.initcpio.install"
        "zfs-utils.initcpio.hook"
        "zfs-utils.initcpio.zfsencryptssh.install")
sha256sums=('3403bf8e993f3c9d772f768142117df47bdbbb8e9bbf85a29c0e166f577f9311'
            '29a8a6d76fff01b71ef1990526785405d9c9410bdea417b08b56107210d00b10'
            '449a6db4abd3f166562bb67a63950af053e9ec07eabbfcdff827c5ed0113a2d6'
            '29080a84e5d7e36e63c4412b98646043724621245b36e5288f5fed6914da5b68')
license=("CDDL")
groups=("archzfs-linux")
provides=("zfs-utils" "spl-utils")
install=zfs-utils.install
conflicts=("zfs-utils" "spl-utils")
backup=('etc/zfs/zed.d/zed.rc' 'etc/default/zfs' 'etc/modules-load.d/zfs.conf' 'etc/sudoers.d/zfs')

build() {
    cd "${srcdir}/zfs-${pkgver/_rc*/}"
    ./autogen.sh
    ./configure --prefix=/usr --sysconfdir=/etc --sbindir=/usr/bin --with-mounthelperdir=/usr/bin \
                --libdir=/usr/lib --datadir=/usr/share --includedir=/usr/include \
                --with-udevdir=/usr/lib/udev --libexecdir=/usr/lib \
                --with-config=user --enable-systemd --enable-pyzfs
    make
}

package() {
    cd "${srcdir}/zfs-${pkgver/_rc*/}"
    make DESTDIR="${pkgdir}" install
    # Remove uneeded files
    rm -r "${pkgdir}"/etc/init.d
    rm -r "${pkgdir}"/usr/share/initramfs-tools
    rm -r "${pkgdir}"/usr/lib/modules-load.d
    # Autoload the zfs module at boot
    mkdir -p "${pkgdir}/etc/modules-load.d"
    printf "%s\n" "zfs" > "${pkgdir}/etc/modules-load.d/zfs.conf"
    # fix permissions
    chmod 750 ${pkgdir}/etc/sudoers.d
    chmod 440 ${pkgdir}/etc/sudoers.d/zfs
    # Install the support files
    install -D -m644 "${srcdir}"/zfs-utils.initcpio.hook "${pkgdir}"/usr/lib/initcpio/hooks/zfs
    install -D -m644 "${srcdir}"/zfs-utils.initcpio.install "${pkgdir}"/usr/lib/initcpio/install/zfs
    install -D -m644 "${srcdir}"/zfs-utils.initcpio.zfsencryptssh.install "${pkgdir}"/usr/lib/initcpio/install/zfsencryptssh
    install -D -m644 contrib/bash_completion.d/zfs "${pkgdir}"/usr/share/bash-completion/completions/zfs
}

Considering how the zfs-dkms didn't update to 2.0.0 yet. Did someone try updating this one instead? If someone did, could it share the modified PKGBUILD?

@minextu. I understand your point. I did my own patching. rc7 already contains the patch.

@mabod Just updated to rc7 which should include the fix. I generally don't like to include patches in rc releases as they should be used for testing on a common codebase

Can you include - cherry pick - PR #11201 until it is in the offical code? The PR prevents a complete hang of the system when working with .zfs/snapshot directories. See issue https://github.com/openzfs/zfs/issues/11169 The PR is: https://github.com/openzfs/zfs/pull/11201

@freswa dracut modules are now included in all archzfs packages (except for zfs-rc since 0.8 has been released)

Since Arch is considering dracut as an replacement for mkinitcpio, could you please include the dracut directory? See also https://lists.archlinux.org/pipermail/arch-dev-public/2019-May/029570.html.

Thanks!

I don't think that's a packaging issue. Try raising a bug upstream.

dkms install with rc5 results in following errors:

(1/9) Install DKMS modules ==> dkms install zfs/0.8.0_rc5 -k 5.0.13-arch1-1-ARCH sed: can't read conftest.c: No such file or directory /var/lib/dkms/zfs/0.8.0_rc5/build/configure: line 25627: conftest.c: No such file or directory /var/lib/dkms/zfs/0.8.0_rc5/build/configure: line 25652: conftest.h: No such file or directory [...]

DKMS config makes use of lsb-release, so might be worthwhile to add it to runtime deps for completeness.

Looks like it does not build on linux 5.0 because of this: https://github.com/zfsonlinux/zfs/issues/8258, will have to wait for a new release or downgrade kernel...

Why did the checksum change?