Package Details: znc-palaver 1.2.1-1

Git Clone URL: https://aur.archlinux.org/znc-palaver.git (read-only, click to copy)
Package Base: znc-palaver
Description: ZNC module for push notifications
Upstream URL: https://github.com/cocodelabs/znc-palaver
Keywords: irc znc
Licenses: MIT
Submitter: kylef
Maintainer: kylef
Last Packager: kylef
Votes: 1
Popularity: 0.088493
First Submitted: 2020-04-05 14:11 (UTC)
Last Updated: 2021-03-13 08:23 (UTC)

Latest Comments

grawlinson commented on 2022-01-24 07:22 (UTC)

Here's an amended PKGBUILD that compiles successfully, and also passes all tests.

# Maintainer: Kyle Fuller <kyle@fuller.li>
# Contributor: George Rawlinson <grawlinson@archlinux.org>

pkgname=znc-palaver
pkgver=1.2.1
pkgrel=1
pkgdesc="ZNC module for push notifications from Palaver"
arch=('x86_64')
url="https://github.com/cocodelabs/znc-palaver"
license=('MIT')
depends=('znc=1.8.2') # modules require recompilation on every version change
makedepends=(
  'git'
  'python'
  'cmake'
)
checkdepends=(
  'python-pytest'
  'python-pytest-asyncio'
  'python-semantic-version'
)
_commit='825cb6814d64006ca0f85fec23fa0a8a3a2d14ca'
source=(
  "git+https://github.com/cocodelabs/znc-palaver.git#commit=$_commit"
  'fix-deprecated-loop-argument.patch::https://patch-diff.githubusercontent.com/raw/cocodelabs/znc-palaver/pull/65.patch'
  'use-xunit2-for-pytest.patch::https://patch-diff.githubusercontent.com/raw/cocodelabs/znc-palaver/pull/66.patch'
)
b2sums=('SKIP'
        'c764435ddcbe2ae6a00b4c937e030b5bb9f8c5f612d97dab6c655c4658523b66dcd8b0bf99a00dbcaffca704e61e191b2bcce43abbd79952b1f156e47bff2564'
        'c56e25f2961257f2a02e6f50d22542c484285460c51cba2b7e7ae9b115a182d79a2f1f2785f5bbc64381bf33062c0d2ffcad2569670e139f8360c769470fe136')

pkgver() {
  cd "$pkgname"

  git describe --tags | sed 's/^v//'
}

prepare() {
  cd "$pkgname"


  # fix failing tests
  patch -p1 -i ../fix-deprecated-loop-argument.patch
  patch -p1 -i ../use-xunit2-for-pytest.patch
}

build() {
  cd "$pkgname"

  make
}

check() {
  cd "$pkgname"

  make test-integration
}

package() {
  cd "$pkgname"

  install -vDm755 -t "$pkgdir/usr/lib/znc" palaver.so

  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}

tetov commented on 2021-06-06 06:23 (UTC) (edited on 2021-06-06 06:24 (UTC) by tetov)

Thanks for the PKGBUILD! I think cmake should be in makedepends as it's used by znc-buildmod.

Traceback (most recent call last):
  File "/usr/bin/znc-buildmod", line 88, in <module>
    subprocess.check_call(command, cwd=build)
  File "/usr/lib/python3.9/subprocess.py", line 368, in check_call
    retcode = call(*popenargs, **kwargs)
  File "/usr/lib/python3.9/subprocess.py", line 349, in call
    with Popen(*popenargs, **kwargs) as p:
  File "/usr/lib/python3.9/subprocess.py", line 951, in __init__
    self._execute_child(args, executable, preexec_fn, close_fds,
  File "/usr/lib/python3.9/subprocess.py", line 1821, in _execute_child
    raise child_exception_type(errno_num, err_msg, err_filename)
FileNotFoundError: [Errno 2] No such file or directory: 'cmake'
make: *** [Makefile:5: palaver.so] Error 1