Arch Linux User Repository

Hello,

I cannot build the package with the current PKGBUILD configuration, but I can build it just fine with the following:

# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgbase=zed
pkgname=(
  'zed'
  'zq'
)
pkgver=1.15.0
pkgrel=1
pkgdesc='Tooling for super-structured data'
arch=('x86_64')
url='https://zed.brimdata.io/'
license=('BSD')
depends=('glibc')
makedepends=('git' 'go')
options=('!lto')
# source=("$pkgbase::git+https://github.com/brimdata/zed#tag=v${pkgver}")
source=("https://github.com/brimdata/zed/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('e444c996a446bd2f316cdc81ffd2b90f0fc326f11586d98f8a158d01bf3d7e48')

prepare() {
  cd "${srcdir}/zed-${pkgver}"

  # create directory for build output
  mkdir dist

  # download dependencies
  go mod download
}

build() {
  cd "${srcdir}/zed-${pkgver}"

  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"

  go build -v \
    -trimpath \
    -buildmode=pie \
    -mod=readonly \
    -modcacherw \
    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\" \
    -X github.com/brimdata/zed/cli.Version=${pkgver}" \
    -o dist \
    ./cmd/{zed,zq}
}

#check() {
#  cd "$pkgbase"
#
#  go test -v ./...
#}

package_zed() {
  cd "${srcdir}/zed-${pkgver}"

  # binary
  install -vDm755 -t "${pkgdir}/usr/bin" dist/zed

  # license
  install -vDm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE.txt
}

package_zq() {
  cd "${srcdir}/zed-${pkgver}"

  # binary
  install -vDm755 -t "${pkgdir}/usr/bin" dist/zq

  # license
  install -vDm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE.txt
}

Maybe your PKGBUILD is a bit too specific for your own configuration ?

Hi @alerque thanks for pointing out dolt Both zed / zq and dolt introduce some interesting new concepts that I presume will take more traction soon. zq esp. builds on jq but enhances it's power significantly.

Hey if you want a co- I'm definitely on this one as I've been following talk about zed specs for a while, you beat me to posting the official release ;-)

(Semi-related and possibly of interest to people looking at data formats and tooling — I'm considering moving dolt to [community].)