Arch Linux User Repository

posting a patch that fixes most bruh moments in the PKGBUILD

i've already submitted a PR for the makefile; you can remove the Makefile.patch and prepare() function if you merge it to upstream

diff --git a/PKGBUILD b/PKGBUILD
index 0ed9896..f34f747 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,28 +1,31 @@
 # Maintainer: Konrad Sekuła <konradsekula@outlook.com>
+# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
+
 pkgname=bruh
 pkgver=2.0
 pkgrel=1
-pkgdesc="Bruh sound, but as a program. You can use it to make your software more fun."
-arch=('i686' 'x86_64')
-license=('GPL')
+pkgdesc="bruh sound, but as a program"
+arch=('x86_64')
+license=('GPL3')
+url='https://github.com/kejpies/bruh'
 depends=("alsa-utils")
-makedepends=("make" "coreutils" "gcc")
-optdepends=("pulseaudio: for pa support if you don't like ALSA")
-source=("git+https://github.com/kejpies/bruh")
-provides=("bruh")
-pkgver(){
-  cd "$srcdir/$pkgname"
-  cat ver
+optdepends=("pulseaudio: ALSA alternative")
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
+        'Makefile.patch')
+sha256sums=('3fc159835ee7baac6776bbf946e711bbd0337abd6d7b1a8ad97ca9513ea8e1d4'
+            'ecafd2f2d0698deb90c7192a71c83645eb03ca64a4b06a24dc79c93a75fd6d8a')
+
+prepare() {
+   patch -p1 -d "$pkgname-$pkgver" < Makefile.patch
 }
+
 build() {
-  cd "$srcdir/$pkgname"
-  make
+   cd "$pkgname-$pkgver"
+   make
 }
+
 package() {
-  cd "$srcdir/$pkgname"
-  
-  install -Dm 755 -o root bruh $pkgdir"/usr/bin/bruh"
-  install -Dm 644 -o root bruh.wav $pkgdir"/usr/share/bruh/bruh.wav"
+   cd "$pkgname-$pkgver"
+   make install DESTDIR="$pkgdir" PREFIX=/usr
+   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
 }
-
-md5sums=(SKIP)