Package Details: rtklib-git 2.4.3b29-3

Git Clone URL: https://aur.archlinux.org/rtklib-git.git (read-only, click to copy)
Package Base: rtklib-git
Description: An Open Source Program Package for GNSS Positioning
Upstream URL: http://www.rtklib.com/
Keywords: GNSS rtklib
Licenses: GPL
Groups: GNSS
Conflicts: rtklib
Provides: rtklib
Submitter: yinflying
Maintainer: yinflying
Last Packager: yinflying
Votes: 1
Popularity: 0.000000
First Submitted: 2018-03-03 04:31 (UTC)
Last Updated: 2018-05-11 09:16 (UTC)

Required by (0)

Sources (1)

Latest Comments

dreieck commented on 2024-02-16 20:01 (UTC)

https://github.com/rtklibexplorer/RTKLIB is official, see https://github.com/JensReimann/RTKLIB/issues/31#issuecomment-1949147933.

dreieck commented on 2024-02-16 00:10 (UTC)

↗ Fixed PKGBUILD:

# Maintainer: yinflying <yinflying@foxmail.com>
# Contributor: dreieck (https://aur.archlinux.org/account/dreieck)
# Maintainer: yinflying <yinflying@foxmail.com>

_proname=RTKLIB
pkgname=rtklib-git
epoch=1
pkgver=b34i+16.r458.20240213.788504f
pkgrel=1
pkgdesc="An Open Source Program Package for GNSS Positioning"
arch=('x86_64')
url="http://www.rtklib.com/"
license=('BSD-2-Clause')
groups=('GNSS')
depends=('glibc')
makedepends=('git' 'gcc-fortran')
provides=("${pkgname%-git}=${pkgver}")
conflicts=("${pkgname%-git}")
replaces=()
backup=()
source=("${_proname}::git+https://github.com/rtklibexplorer/RTKLIB.git")
noextract=()
md5sums=('SKIP')

prepare() {
    cd "$srcdir/${_proname}"

    git log > git.log
}

pkgver() {
  cd "${srcdir}/${_proname}"

  _ver="$(git describe  --tags | sed 's|^[vV]||' | sed 's|-g[0-9a-fA-F]*$||' | tr '-' '+')"
  _rev="$(git rev-list --count HEAD)"
  _date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
  _hash="$(git rev-parse --short HEAD)"

  if [ -z "${_ver}" ]; then
    error "Version could not be determined."
    return 1
  else
    printf '%s' "${_ver}.r${_rev}.${_date}.${_hash}"
  fi
}

build() {
    cd "$srcdir/${_proname}/lib/iers/gcc"
    make
    cd "$srcdir/${_proname}/app/consapp"
    make
}

package() {
    # install bin file
    for _bin in pos2kml str2str rnx2rtkp convbin rtkrcv; do
      install -Dvm755 -t "${pkgdir}/usr/bin" "$srcdir/${_proname}/app/consapp/${_bin}/gcc/${_bin}"
    done
    # copy share file
    install -dvm755 "$pkgdir/usr/share/${pkgname%-git}/data/"
    cp -rv "$srcdir/${_proname}/data"/* "$pkgdir/usr/share/${pkgname%-git}/data"/
    install -dvm755 "$pkgdir/usr/share/${pkgname%-git}/rnx2rtkp"
    cp -rv "$srcdir/${_proname}/app/consapp/rnx2rtkp/gcc"/*.conf "$pkgdir/usr/share/${pkgname%-git}/rnx2rtkp"/

    install -Dvm644 -t "${pkgdir}/usr/share/doc/${pkgname%-git}" "$srcdir/${_proname}"/{readme.txt,git.log}
    install -Dvm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "$srcdir/${_proname}/license.txt"
}

Please fix your package.
Regards and thanks for maintaining!

dreieck commented on 2024-02-16 00:07 (UTC)

Please add a pkgver() function as required by the VCS packaging guidelines that ensures a increasing $pkgver with each upstream commit.

Or, if you use a fixed commit/ release, remove the -git suffix from $pkgname.

Regards and thanks for maintaining!

dreieck commented on 2024-02-15 23:58 (UTC)

Package rtklib-qt-git builds successfully from a different source, https://github.com/rtklibexplorer/RTKLIB.

Maybe, to have the same codebase, this package here should also be built from that source?

Regards!

dreieck commented on 2024-02-15 23:08 (UTC)

Please remove options=(), since this invalidates any customised default options set in /etc/makepkg.conf.

dreieck commented on 2024-02-15 23:06 (UTC)

License ins not GPL but BSD-2-Clause.
Please install LICENSE.txt.

dreieck commented on 2024-02-15 20:16 (UTC)

Build fails for me with missing make target:

==> Starting build()...
make: 'iers.a' is up to date.
make: *** No targets specified and no makefile found.  Stop.

Regards and thanks for maintaining!

Kasami commented on 2021-03-31 19:47 (UTC) (edited on 2021-03-31 19:48 (UTC) by Kasami)

This package won't build anymore as they've moved RTKLIB/app/ contents to RTKLIB/app/consapp/

Replacing /app with /app/consapp/ in pkg build seems to fix it, though.

polylux commented on 2019-11-22 14:39 (UTC)

Builds smoothly on aarch64 btw!