Package Details: zfs-dkms-rc 2.1.0_rc8-1

Git Clone URL: https://aur.archlinux.org/zfs-dkms-rc.git (read-only, click to copy)
Package Base: zfs-dkms-rc
Description: Kernel modules for the Zettabyte File System.
Upstream URL: https://zfsonlinux.org/
Licenses: CDDL
Groups: archzfs-dkms-rc
Conflicts: spl, spl-headers, zfs, zfs-headers
Provides: spl, spl-headers, zfs, zfs-headers
Submitter: greyltc
Maintainer: None
Last Packager: archzfs-bot
Votes: 3
Popularity: 0.004265
First Submitted: 2017-06-06 12:24 (UTC)
Last Updated: 2021-07-01 12:41 (UTC)

Dependencies (3)

Required by (17)

Sources (1)

Latest Comments

1 2 3 Next › Last »

darkbasic commented on 2023-09-29 09:52 (UTC)

@mabod unfortunately 2.1 is not an option because I desperately need reflink support.

mabod commented on 2023-09-24 07:27 (UTC)

@darkbasic: You can use the 2.1.13 pre-version. It works just fine for me since a few days. This is the PR https://github.com/openzfs/zfs/pull/15268

This is the git repo which I used to build it for me: git clone https://github.com/tonyhutter/zfs.git --branch zfs-2.1.13-hutter

MarsSeed commented on 2023-09-22 19:48 (UTC)

Never mind, I think my last recommendation was wrong. The current name of this package seems to be correct, and it conforms to the established naming patterns used on AUR.

The last suffix in a name indicates the source variant used in each package:

  • zfs-dkms (no special suffix means latest stable source)
  • zfs-dkms-git (git master/main development source)
  • zfs-dkms-rc (release or release candidate tarball or tag)

MarsSeed commented on 2023-09-22 11:06 (UTC)

Instead of waiting for the orphan request to be fulfilled, the updated version of this package should be resubmitted as zfs-rc-dkms. Because this is a DKMS package of the RC version of zfs, not the RC version of a module whose upstream name is zfs-dkms.

darkbasic commented on 2023-09-22 09:54 (UTC)

Updated PKGBUILD (unfortunately 2.2.0rc4 is still not compatible with kernel 6.5):

# Maintainer: Jan Houben <jan@nexttrex.de>
# Contributor: Jesus Alvarez <jeezusjr at gmail dot com>
#
# This PKGBUILD was generated by the archzfs build scripts located at
#
# http://github.com/archzfs/archzfs
#
pkgname="zfs-dkms-rc"
pkgdesc="Kernel modules for the Zettabyte File System."

pkgver=2.2.0rc4
pkgrel=1
makedepends=()
arch=("x86_64")
url="https://zfsonlinux.org/"
source=("https://github.com/zfsonlinux/zfs/releases/download/zfs-${pkgver/rc/-rc}/zfs-${pkgver/rc/-rc}.tar.gz")
sha256sums=('be44b6a27123145c5f0b543bb77ddcc6b21c1e3f00cfeda124c6050b2eb644ed')
license=("CDDL")
depends=("zfs-utils-rc=${pkgver}" "lsb-release" "dkms")
provides=("zfs" "zfs-headers" "spl" "spl-headers")
groups=("archzfs-dkms-rc")
conflicts=("zfs" "zfs-headers" "spl" "spl-headers")

build() {
    cd "${srcdir}/zfs-${pkgver/rc/-rc}"
    ./autogen.sh
}

package() {
    dkmsdir="${pkgdir}/usr/src/zfs-${pkgver}"
    install -d "${dkmsdir}"
    cp -a ${srcdir}/zfs-${pkgver/rc/-rc}/. ${dkmsdir}
    cd "${dkmsdir}"
    find . -name ".git*" -print0 | xargs -0 rm -fr --
    scripts/dkms.mkconf -v ${pkgver} -f dkms.conf -n zfs
    chmod g-w,o-w -R .
}

Time for a new maintainer?

MarsSeed commented on 2023-08-12 16:07 (UTC) (edited on 2023-08-12 16:23 (UTC) by MarsSeed)

Latest release as of now is zfs-2.2.0-rc3 (27 Jul 2023).

The pkgver for that should be 2.2.0rc3, because for pacman/makepkg/vercmp, the following is true:

2.2.0rc3 < 2.2.0 < 2.2.0_rc3

mabod commented on 2020-12-09 07:00 (UTC) (edited on 2020-12-09 07:05 (UTC) by mabod)

@PedroHLC: Here is what I use. This is basically the zfs-dkms-rc and zfs-utils-rc files just sourcing zfs-2.0.0. I did not change maintainer info etc.

The packages depend on each other. So you want to use the -d option with makepkg to compile the packages.

PKGBUILD zfs-dkms:

# Maintainer: Jan Houben <jan@nexttrex.de>
# Contributor: Jesus Alvarez <jeezusjr at gmail dot com>
#
# This PKGBUILD was generated by the archzfs build scripts located at
#
# http://github.com/archzfs/archzfs
#
pkgname="zfs-dkms"
pkgdesc="Kernel modules for the Zettabyte File System."

pkgver=2.0.0
pkgrel=1
makedepends=()
arch=("x86_64")
url="https://zfsonlinux.org/"
source=("https://github.com/zfsonlinux/zfs/releases/download/zfs-${pkgver/_/-}/zfs-${pkgver/_/-}.tar.gz")
sha256sums=('3403bf8e993f3c9d772f768142117df47bdbbb8e9bbf85a29c0e166f577f9311')
license=("CDDL")
depends=("zfs-utils=${pkgver}" "lsb-release" "dkms")
provides=("zfs" "zfs-headers" "spl" "spl-headers")
groups=("archzfs-dkms")
conflicts=("zfs" "zfs-headers" "spl" "spl-headers")

build() {
    cd "${srcdir}/zfs-${pkgver/_rc*/}"
    ./autogen.sh
}

package() {
    dkmsdir="${pkgdir}/usr/src/zfs-${pkgver}"
    install -d "${dkmsdir}"
    cp -a ${srcdir}/zfs-${pkgver/_rc*/}/. ${dkmsdir}
    cd "${dkmsdir}"
    find . -name ".git*" -print0 | xargs -0 rm -fr --
    scripts/dkms.mkconf -v ${pkgver} -f dkms.conf -n zfs
    chmod g-w,o-w -R .
}

PKGBUILD zfs-utils:

# Maintainer: Jan Houben <jan@nexttrex.de>
# Contributor: Jesus Alvarez <jeezusjr at gmail dot com>
#
# This PKGBUILD was generated by the archzfs build scripts located at
#
# http://github.com/archzfs/archzfs
#
pkgname="zfs-utils"

pkgver=2.0.0
pkgrel=1
pkgdesc="Kernel module support files for the Zettabyte File System."
makedepends=("python" "python-setuptools" "python-cffi")
optdepends=("python: pyzfs and extra utilities", "python-cffi: pyzfs")
arch=("x86_64")
url="http://zfsonlinux.org/"
source=("https://github.com/zfsonlinux/zfs/releases/download/zfs-${pkgver/_/-}/zfs-${pkgver/_/-}.tar.gz"
        "zfs-utils.initcpio.install"
        "zfs-utils.initcpio.hook"
        "zfs-utils.initcpio.zfsencryptssh.install")
sha256sums=('3403bf8e993f3c9d772f768142117df47bdbbb8e9bbf85a29c0e166f577f9311'
            '29a8a6d76fff01b71ef1990526785405d9c9410bdea417b08b56107210d00b10'
            '449a6db4abd3f166562bb67a63950af053e9ec07eabbfcdff827c5ed0113a2d6'
            '29080a84e5d7e36e63c4412b98646043724621245b36e5288f5fed6914da5b68')
license=("CDDL")
groups=("archzfs-linux")
provides=("zfs-utils" "spl-utils")
install=zfs-utils.install
conflicts=("zfs-utils" "spl-utils")
backup=('etc/zfs/zed.d/zed.rc' 'etc/default/zfs' 'etc/modules-load.d/zfs.conf' 'etc/sudoers.d/zfs')

build() {
    cd "${srcdir}/zfs-${pkgver/_rc*/}"
    ./autogen.sh
    ./configure --prefix=/usr --sysconfdir=/etc --sbindir=/usr/bin --with-mounthelperdir=/usr/bin \
                --libdir=/usr/lib --datadir=/usr/share --includedir=/usr/include \
                --with-udevdir=/usr/lib/udev --libexecdir=/usr/lib \
                --with-config=user --enable-systemd --enable-pyzfs
    make
}

package() {
    cd "${srcdir}/zfs-${pkgver/_rc*/}"
    make DESTDIR="${pkgdir}" install
    # Remove uneeded files
    rm -r "${pkgdir}"/etc/init.d
    rm -r "${pkgdir}"/usr/share/initramfs-tools
    rm -r "${pkgdir}"/usr/lib/modules-load.d
    # Autoload the zfs module at boot
    mkdir -p "${pkgdir}/etc/modules-load.d"
    printf "%s\n" "zfs" > "${pkgdir}/etc/modules-load.d/zfs.conf"
    # fix permissions
    chmod 750 ${pkgdir}/etc/sudoers.d
    chmod 440 ${pkgdir}/etc/sudoers.d/zfs
    # Install the support files
    install -D -m644 "${srcdir}"/zfs-utils.initcpio.hook "${pkgdir}"/usr/lib/initcpio/hooks/zfs
    install -D -m644 "${srcdir}"/zfs-utils.initcpio.install "${pkgdir}"/usr/lib/initcpio/install/zfs
    install -D -m644 "${srcdir}"/zfs-utils.initcpio.zfsencryptssh.install "${pkgdir}"/usr/lib/initcpio/install/zfsencryptssh
    install -D -m644 contrib/bash_completion.d/zfs "${pkgdir}"/usr/share/bash-completion/completions/zfs
}

1 2 3 Next › Last »