blob: efc504da393d212d63e8e37565f3da2c7ef07189 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Contributor: Ilya Lipnitskiy <ilya.lipnitskiy@gmail.com>
# Maintainer: Wilken Gottwalt <wilken dot gottwalt at posteo dot net>
_target=arm-linux-gnueabihf
pkgname=${_target}-gdb
pkgver=14.2
pkgrel=1
pkgdesc='The GNU Debugger'
arch=(x86_64)
url='http://www.gnu.org/software/gdb/'
license=(GPL3)
depends=(boost expat gdb-common glibc gmp guile libelf mpfr ncurses python readline source-highlight xz zstd)
makedepends=(boost expat gcc glibc gmp guile libelf mpfr ncurses python readline source-highlight xz zstd)
options=(!emptydirs)
source=(http://ftp.gnu.org/gnu/gdb/gdb-${pkgver}.tar.xz{,.sig})
sha256sums=('2d4dd8061d8ded12b6c63f55e45344881e8226105f4d2a9b234040efa5ce7772'
'SKIP')
validpgpkeys=('F40ADB902B24264AA42E50BF92EDB04BFF325CF3') # Joel Brobecker <brobecker@adacore.com>
prepare() {
mkdir -p gdb-build
}
build() {
cd gdb-${pkgver}
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
cd ${srcdir}/gdb-build
../gdb-${pkgver}/configure \
--target=$_target \
--prefix=/usr \
--with-system-readline \
--with-python=/usr/bin/python \
--with-system-gdbinit=/etc/gdb/gdbinit \
--enable-languages=c,c++ \
--enable-tui \
--enable-interwork \
--enable-source-highlight \
--disable-nls \
--disable-multilib
make
}
package() {
cd gdb-build
make -C gdb DESTDIR="${pkgdir}" install
rm -r "${pkgdir}"/usr/share/{gdb,info,man/man5}
rm -r "${pkgdir}"/usr/include/gdb
# strip it manually
find "${pkgdir}"/usr/bin -type f -exec strip --strip-unneeded {} \; 2>/dev/null || true
}
|