blob: 87dd2fcc3da5a7e970fae93454820477b62191a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
pkgname=atopile
pkgver=0.2.47
pkgrel=1
pkgdesc="A tool to build electronic circuit boards with code"
arch=(any)
url="https://github.com/atopile/atopile"
license=(Apache-2.0)
depends=(
python
python-antlr4
python-attrs
python-case-converter
python-cattrs
python-click
python-deepdiff
python-eseries
python-flask
python-flask-cors
python-gitpython
python-jinja
python-natsort
python-pint
python-requests
python-rich
python-ruamel-yaml
python-semver
python-toolz
python-waitress
)
makedepends=(
python-build
python-hatch-vcs
python-installer
python-wheel
)
checkdepends=(python-pytest)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('97f6902b061b01e5268c37fa58c725fb3237f48287d6e6822b6517c8b22a7798')
_archive="$pkgname-$pkgver"
build() {
cd "$_archive"
export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
python -m build --wheel --no-isolation
}
check() {
cd "$_archive"
rm -rf tmp_install
python -m installer --destdir=tmp_install dist/*.whl
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
export PYTHONPATH="$PWD/tmp_install/$site_packages"
pytest --override-ini="addopts="
}
package() {
cd "$_archive"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|