blob: af0a8df0f33f22cad0fce49d49a9bc9a48adc669 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: MatMoul <matmoul at the google email domain which is .com>
pkgname=octopi
pkgver=0.16.0
pkgrel=1
pkgdesc="A powerful Pacman frontend using Qt libs"
arch=('x86_64')
url="https://tintaescura.com/projects/octopi"
license=('GPL-2.0-or-later')
depends=(
'alpm-octopi-utils'
'qt-sudo'
'qt6-5compat'
'qtermwidget'
)
makedepends=(
'cmake'
'git'
'qt6-tools'
)
optdepends=(
'inxi: for SysInfo log'
'lsb-release: for SysInfo log'
'mhwd: for SysInfo log'
'pacaur: for AUR support'
'pacmanlogviewer: to view pacman log files'
'paru: for AUR support'
'pikaur: for AUR support'
'systemd: for SysInfo log'
'trizen: for AUR support'
'yay: for AUR support'
)
provides=(
'octopi-notifier'
'octopi-repoeditor'
'octopi-cachecleaner'
)
conflicts=(
'octopi-notifier'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/aarnt/octopi/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('12438b73009e80fb86b6c126b406624f7df7cd8ebaf006853b2e6c258a79aec8')
prepare() {
cd "$pkgname-$pkgver"
# Don't hardcode qt-sudo path
sed -i 's/usr\/local/usr/g' src/constants.h
}
build() {
cmake -B build -S "$pkgname-$pkgver" \
-DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-Wno-dev
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
# remove duplicate license
rm -r "$pkgdir/usr/share/licenses"
}
|