blob: cef13f3aa42582af6c9cdd4cc953b22060f4b9d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: solsTiCe d'Hiver <solstice.dhiver@gmail.com>
pkgname=atool2-git
_pkgname=atool
pkgver=r24.c135b88
pkgrel=2
pkgdesc="A script for managing file archives of various types (with zstd support)"
arch=('any')
url="https://github.com/solsticedhiver/atool2"
license=('GPL3')
depends=('file' 'perl')
makedepends=('bash')
conflicts=('atool')
provides=('atool')
optdepends=('bzip2: for using atool with bzip2 compressed archives'
'cpio: for using atool with cpio archives'
'gzip: for using atool with gzip compressed archives'
'lha: for using atool with lha, lharc and similar archives'
'xz: for using atool with lzma compressed archives'
'lzop: for using atool with lzop compressed archives'
'p7zip: for using atool with 7z archives'
'tar: for using atool with tar archives'
'unace: for using atool with ace archives'
'unrar: for using atool with rar archives'
'zip: for using atool for creating zip archives'
'unzip: for using atool for unpacking archives'
'zstd: for using atool with zstandard archives')
source=(atool::git+https://github.com/solsticedhiver/atool2.git)
sha256sums=('SKIP')
pkgver() {
cd ${_pkgname}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}"/${_pkgname}
CONFIG_SHELL=/bin/bash ./configure --prefix=/usr --sysconfdir=/etc
}
package() {
cd "${srcdir}"/${_pkgname}
make DESTDIR="${pkgdir}" install
}
|