blob: 2ca7fa03e553f00f8cba55d0f7fb9fe2bb8250ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://readarr.servarr.com/v1/update/readarr/updatefile?os=linux&runtime=netcore&arch=x64
pkgname="readarr-nightly"
pkgver=0.3.28.2546
pkgrel=1
pkgdesc="Audio and eBook download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Readarr/Readarr"
license=("GPL3")
depends=(
'sqlite'
'chromaprint'
)
options=(
'!strip'
'staticlibs'
)
provides=('readarr')
conflicts=('readarr')
optdepends=('calibre: calibre-server as root folder'
'sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'qbittorrent: torrent downloader'
'qbittorrent-nox: torrent downloader (no X)'
'jackett: torrent indexer proxy')
source_x86_64=("readarr.${pkgver}.linux-core-x64.tar.gz::https://readarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("readarr.${pkgver}.linux-core-arm64.tar.gz::https://readarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("readarr.${pkgver}.linux-core-arm.tar.gz::https://readarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=('readarr.service'
'readarr.tmpfiles'
'readarr.sysusers'
'package_info')
sha512sums=('8479a08e504c0e5be48d0e97e849c589f9b49855de5fe8edf8c24b9317263283fd92f8eee9d2bc1fb927b7186eb6721bf0a1c063c68a80811a11efc4105914ec'
'b34389cf2966a7a1a1fe6708303641e144191a95001c5ca6e570e9d50ba334fcbc1603852c3c2bfe008d97aaf54207690c689f00dd63378157af33ceebbbb089'
'99f8210754ea5ec742ba6b0b9f05c8312237cb0225bc0d28a2a8ee8362b464da0880499b64ea58c84b64c0eb727748c3c15630cedb8785d7d94d856c76cf17eb'
'f762a01de8c4448a64da61fc6804587b2679d3c2b874c42cd920d7af0a380ed4c93ff8e89aac72a1cdca90c98596d97f593c98f6528326e4dacfc3f09ab536a5')
sha512sums_x86_64=('7846b4891d073905d0ea2a8e6e118b9294af91c84954d65bf1288684eaa909feea43aaff6dff3dfcca8f63f5e9ea8e68b2300e668a80270541708a0d61e6fbe5')
sha512sums_aarch64=('9a8142c51a57effae639370e3e8a80cbe514fba309eac1fe09cf1e57851e056fdcc522459b04a9927584c4d6b4d0e75ebef4437b66d8c1c5cc87e17d37a9c0bd')
sha512sums_armv7h=('2a13340cb95899eaa66ffa168857e29f13331ca1443f7c0f1693c694946c27cc46b237cccf289c31ffd5b6fa727fa45ef34c757e23de1f7a4509341b152eabf9')
package() {
# Update environment isn't needed.
rm -rf "${srcdir}/Readarr/Readarr.Update"
# Remove unneeded fpcalc
rm -f "${srcdir}/Readarr/fpcalc"
install -d -m 755 "${pkgdir}/usr/lib/readarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Readarr/"* "${pkgdir}/usr/lib/readarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/readarr/bin"
chmod +x "${pkgdir}/usr/lib/readarr/bin/Readarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/readarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/readarr/package_info"
install -D -m 644 "${srcdir}/readarr.service" "${pkgdir}/usr/lib/systemd/system/readarr.service"
install -D -m 644 "${srcdir}/readarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/readarr.conf"
install -D -m 644 "${srcdir}/readarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/readarr.conf"
}
|