blob: cd15b01ecbd29868f34d3f6ebbb6f8dcadf302eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: a821
# Contributor: Moritz Lipp <mlq@pwmt.org>
pkgname=zathura-git
pkgver=0.5.6.r60.g2d6984c
pkgrel=1
pkgdesc="Minimalistic document viewer"
arch=('x86_64')
url="https://pwmt.org/projects/zathura"
license=('Zlib')
depends=('desktop-file-utils' 'file' 'girara-git' 'libseccomp' 'libsynctex' 'sqlite')
makedepends=('appstream-glib' 'check' 'git' 'meson' 'ninja' 'python-sphinx' 'texlive-bin')
conflicts=('zathura')
provides=('zathura')
source=("$pkgname::git+https://github.com/pwmt/zathura.git#branch=develop")
md5sums=('SKIP')
optdepends=(
'zathura-djvu-git: DjVu support'
'zathura-pdf-poppler-git: PDF support using Poppler'
'zathura-pdf-mupdf-git: PDF support using MuPDF'
'zathura-ps-git: PostSctipt support'
'zathura-cb-git: Comic book support'
)
pkgver() {
cd "$pkgname"
git describe --tags --long | sed 's/-/.r/;s/-/./g'
}
build() {
cd "$pkgname"
arch-meson build -Dtests=disabled
ninja -C build
}
package() {
cd "$pkgname"
DESTDIR="$pkgdir/" ninja -C build install
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim:set ts=2 sw=2 et:
|