Initial commit

2 files changed, 83 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..110826ddac97
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,25 @@
+pkgbase = avizo-git
+	pkgdesc = A neat notification daemon
+	pkgver = r93.9cd5319
+	pkgrel = 1
+	url = https://github.com/misterdanb/avizo
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = vala
+	makedepends = meson
+	makedepends = ninja
+	depends = alsa-utils
+	depends = dbus
+	depends = gobject-introspection
+	depends = gtk-layer-shell
+	depends = gtk3
+	optdepends = brightnessctl: for helper script lightctl
+	optdepends = light: for helper script lightctl
+	optdepends = pamixer: for helper script volumectl
+	provides = avizo
+	conflicts = avizo
+	source = avizo::git+https://github.com/misterdanb/avizo.git
+	sha256sums = SKIP
+
+pkgname = avizo-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fc1361038c5f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer: hrdl <aur@hrdl.eu>
+# Contributor: danb (danb) <danb (at) hasi.it>
+
+pkgname=avizo-git
+_pkgname=avizo
+pkgver=r93.9cd5319
+pkgrel=1
+pkgdesc="A neat notification daemon"
+arch=("x86_64")
+url="https://github.com/misterdanb/avizo"
+license=("GPL")
+depends=(
+  "alsa-utils"
+  "dbus"
+  "gobject-introspection"
+  "gtk-layer-shell"
+  "gtk3"
+)
+optdepends=(
+  "brightnessctl: for helper script lightctl"
+  "light: for helper script lightctl"
+  "pamixer: for helper script volumectl"
+)
+makedepends=(
+  "git"
+  "vala"
+  "meson"
+  "ninja"
+)
+provides=('avizo')
+conflicts=('avizo')
+
+source=("$_pkgname::git+https://github.com/misterdanb/avizo.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$_pkgname"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$_pkgname"
+
+  arch-meson . build
+  meson compile -C build
+}
+
+check() {
+  cd "$_pkgname"
+
+  meson test -C build
+}
+
+package() {
+  cd "$_pkgname"
+
+  meson install -C build --destdir "$pkgdir"
+}