initial upload

3 files changed, 102 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..28dbbcc91799
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,28 @@
+pkgbase = dia-nopoppler-git
+	pkgdesc = A GTK+ based diagram creation program (GIT checkout without poppler)
+	pkgver = 6731.b903dd83a
+	pkgrel = 1
+	url = http://live.gnome.org/Dia
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = cmake
+	makedepends = meson
+	makedepends = intltool
+	makedepends = dblatex
+	makedepends = docbook-xsl
+	depends = python
+	depends = libxslt
+	depends = gtk2
+	depends = freetype2
+	depends = graphene
+	provides = dia
+	conflicts = dia
+	options = docs
+	options = !emptydirs
+	source = git+https://gitlab.gnome.org/GNOME/dia.git
+	source = no_poppler.patch
+	sha256sums = SKIP
+	sha256sums = e2e057ca83b0bedcf7e56aad396c6e8a498775ed7f7246b3c271db92e7375ffb
+
+pkgname = dia-nopoppler-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3c7a25e577fd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Contributor: Thorsten Töpper <atsutane-tu@freethoughts.de>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Juergen Hoetzel <juergen@archlinux.org>
+# Contributor: Gregor Ibic <gregor.ibic@intelicom.si>
+# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
+
+pkgname=dia-nopoppler-git
+_pkgname=dia
+pkgver=6731.b903dd83a
+pkgrel=1
+pkgdesc="A GTK+ based diagram creation program (GIT checkout without poppler)"
+arch=('x86_64')
+license=('GPL')
+url="http://live.gnome.org/Dia"
+depends=('python' 'libxslt' 'gtk2' 'freetype2' 'graphene')
+makedepends=('git' 'cmake' 'meson' 'intltool' 'dblatex' 'docbook-xsl')
+provides=('dia')
+conflicts=('dia')
+options=('docs' '!emptydirs')
+source=("git+https://gitlab.gnome.org/GNOME/dia.git" no_poppler.patch)
+sha256sums=('SKIP'
+            'e2e057ca83b0bedcf7e56aad396c6e8a498775ed7f7246b3c271db92e7375ffb')
+
+pkgver() {
+  cd ${_pkgname}
+  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_pkgname}
+  patch -Np1 < "$srcdir"/no_poppler.patch
+}
+
+build() {
+  cd ${_pkgname}
+
+  arch-meson . build
+  ninja -C build
+}
+
+package() {
+  cd ${_pkgname}
+  DESTDIR="${pkgdir}" ninja -C build install
+}
diff --git a/no_poppler.patch b/no_poppler.patch
new file mode 100644
index 000000000000..ec70e79bd3be
--- /dev/null
+++ b/no_poppler.patch
@@ -0,0 +1,30 @@
+diff --git a/meson.build b/meson.build
+index 9e5fe8038..4336243c5 100644
+--- a/meson.build
++++ b/meson.build
+@@ -24,9 +24,9 @@ libm_dep = cc.find_library('m', required: false)
+ libc_dep = cc.find_library('c', required: false)
+ 
+ # Optional deps
+-libpoppler_dep = dependency('poppler', version: '> 0.62.0', required: false)
+-libpopplercpp_dep = dependency('poppler-cpp', required: false)
+-conf.set('HAVE_POPPLER', libpoppler_dep.found() and libpopplercpp_dep.found())
++#libpoppler_dep = dependency('poppler', version: '> 0.62.0', required: false)
++#libpopplercpp_dep = dependency('poppler-cpp', required: false)
++#conf.set('HAVE_POPPLER', libpoppler_dep.found() and libpopplercpp_dep.found())
+ libemf_dep = cc.find_library('emf', required: false)
+ conf.set('HAVE_LIBEMF', libemf_dep.found())
+ libogdf_dep = cc.find_library('ogdf', required: false)
+diff --git a/plug-ins/meson.build b/plug-ins/meson.build
+index 7c386be11..73a646b3d 100644
+--- a/plug-ins/meson.build
++++ b/plug-ins/meson.build
+@@ -17,7 +17,7 @@ subdir('shape')
+ subdir('pixbuf')
+ subdir('layout')  # Non-standard: shared_module
+ subdir('metapost')
+-subdir('pdf')
++#subdir('pdf')
+ subdir('pgf')
+ subdir('postscript')
+ subdir('pstricks')