Initial build (0.3.2)

3 files changed, 70 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..ca84193162cd
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = fast-ssh-git
+	pkgdesc = Quickly connect to your services by navigating through your SSH config
+	pkgver = 0.3.2.r0.g7e62107
+	pkgrel = 1
+	url = https://github.com/Julien-R44/fast-ssh
+	arch = any
+	license = MIT
+	makedepends = git
+	makedepends = cargo
+	depends = glibc
+	depends = gcc-libs
+	depends = openssh
+	provides = fast-ssh=0.3.2
+	conflicts = fast-ssh
+	source = fast-ssh::git+https://github.com/Julien-R44/fast-ssh.git
+	sha256sums = SKIP
+
+pkgname = fast-ssh-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..018a3de08144
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*
+!PKGBUILD
+!.SRCINFO
+!.gitignore
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9fe60d5c58de
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: vitaliikuzhdin <vitaliikuzhdin@gmail.com>
+
+_pkgname="fast-ssh"
+pkgname="${_pkgname}-git"
+pkgver=0.3.2.r0.g7e62107
+pkgrel=1
+pkgdesc="Quickly connect to your services by navigating through your SSH config"
+arch=('any')
+url="https://github.com/Julien-R44/${_pkgname}"
+license=('MIT')
+depends=('glibc' 'gcc-libs' 'openssh')
+makedepends=('git' 'cargo')
+provides=("${_pkgname}=${pkgver%%.r*}")
+conflicts=("${_pkgname}")
+_pkgsrc="${_pkgname}"
+source=("${_pkgsrc}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgsrc}"
+  git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "${srcdir}/${_pkgsrc}"
+  install -Dm755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+}