Kwiboo ffmpeg fork with v4l2 request support

2 files changed, 164 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e06828b54ad4
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,74 @@
+pkgbase = ffmpeg-v4l2-request-git
+	pkgdesc = FFmpeg with v4l2-request support
+	pkgver = r94743.fa3f88530e
+	pkgrel = 1
+	url = https://github.com/Kwiboo/FFmpeg/tree/v4l2-request-hwaccel-4.2.2
+	arch = aarch64
+	license = GPL3
+	makedepends = git
+	depends = alsa-lib
+	depends = bzip2
+	depends = fontconfig
+	depends = fribidi
+	depends = glibc
+	depends = gmp
+	depends = gnutls
+	depends = gsm
+	depends = jack
+	depends = lame
+	depends = libavc1394
+	depends = libdrm
+	depends = libiec61883
+	depends = libmodplug
+	depends = libomxil-bellagio
+	depends = libpulse
+	depends = libraw1394
+	depends = libsoxr
+	depends = libssh
+	depends = libtheora
+	depends = libvdpau
+	depends = libwebp
+	depends = libx11
+	depends = libxcb
+	depends = libxext
+	depends = libxml2
+	depends = libxv
+	depends = opencore-amr
+	depends = openjpeg2
+	depends = opus
+	depends = sdl2
+	depends = speex
+	depends = v4l-utils
+	depends = xz
+	depends = zlib
+	depends = ladspa
+	depends = libass.so
+	depends = libbluray.so
+	depends = libfreetype.so
+	depends = libva-drm.so
+	depends = libva.so
+	depends = libva-x11.so
+	depends = libvidstab.so
+	depends = libvorbisenc.so
+	depends = libvorbis.so
+	depends = libvpx.so
+	depends = libx264.so
+	depends = libx265.so
+	depends = libxvidcore.so
+	optdepends = intel-media-sdk: for Intel Quick Sync Video
+	optdepends = ladspa: for LADSPA filters
+	provides = libavcodec.so
+	provides = libavdevice.so
+	provides = libavfilter.so
+	provides = libavformat.so
+	provides = libavutil.so
+	provides = libpostproc.so
+	provides = libswresample.so
+	provides = libswscale.so
+	provides = ffmpeg
+	conflicts = ffmpeg
+	source = git+https://github.com/Kwiboo/FFmpeg.git#branch=v4l2-request-hwaccel-4.2.2
+	sha256sums = SKIP
+
+pkgname = ffmpeg-v4l2-request-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7029d266c4a9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,90 @@
+# Maintainer: Andre Vallestero < gmail-com: andrevallestero >
+
+pkgname=ffmpeg-v4l2-request-git
+pkgver=r94743.fa3f88530e
+pkgrel=1
+pkgdesc='FFmpeg with v4l2-request support'
+arch=('aarch64')
+url='https://github.com/Kwiboo/FFmpeg/tree/v4l2-request-hwaccel-4.2.2'
+license=('GPL3')
+depends=('alsa-lib' 'bzip2' 'fontconfig' 'fribidi' 'glibc' 'gmp' 'gnutls' 'gsm'
+         'jack' 'lame' 'libavc1394' 'libdrm' 'libiec61883' 'libmodplug'
+         'libomxil-bellagio' 'libpulse' 'libraw1394' 'libsoxr' 'libssh' 'libtheora'
+         'libvdpau' 'libwebp' 'libx11' 'libxcb' 'libxext' 'libxml2' 'libxv'
+         'opencore-amr' 'openjpeg2' 'opus' 'sdl2' 'speex' 'v4l-utils' 'xz' 'zlib'
+         'ladspa' 'libass.so' 'libbluray.so' 'libfreetype.so' 'libva-drm.so'
+         'libva.so' 'libva-x11.so' 'libvidstab.so' 'libvorbisenc.so' 'libvorbis.so'
+         'libvpx.so' 'libx264.so' 'libx265.so' 'libxvidcore.so')
+makedepends=('git')
+optdepends=('intel-media-sdk: for Intel Quick Sync Video'
+            'ladspa: for LADSPA filters')
+provides=('libavcodec.so' 'libavdevice.so' 'libavfilter.so' 'libavformat.so'
+          'libavutil.so' 'libpostproc.so' 'libswresample.so' 'libswscale.so'
+          'ffmpeg')
+conflicts=('ffmpeg')
+source=('git+https://github.com/Kwiboo/FFmpeg.git#branch=v4l2-request-hwaccel-4.2.2')
+sha256sums=('SKIP')
+
+pkgver() {
+	cd FFmpeg
+	printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd FFmpeg
+
+	printf '%s\n' '  -> Running ffmpeg configure script...'
+
+	./configure \
+        --prefix='/usr' \
+        --disable-debug \
+        --disable-static \
+        --disable-stripping \
+        --enable-fontconfig \
+        --enable-gmp \
+        --enable-gnutls \
+        --enable-gpl \
+        --enable-ladspa \
+        --enable-libass \
+        --enable-libbluray \
+        --enable-libdrm \
+        --enable-libfreetype \
+        --enable-libfribidi \
+        --enable-libgsm \
+        --enable-libiec61883 \
+        --enable-libjack \
+        --enable-libmodplug \
+        --enable-libmp3lame \
+        --enable-libopencore_amrnb \
+        --enable-libopencore_amrwb \
+        --enable-libopenjpeg \
+        --enable-libopus \
+        --enable-libpulse \
+        --enable-libsoxr \
+        --enable-libspeex \
+        --enable-libssh \
+        --enable-libtheora \
+        --enable-libv4l2 \
+        --enable-libvidstab \
+        --enable-libvorbis \
+        --enable-libvpx \
+        --enable-libwebp \
+        --enable-libx264 \
+        --enable-libx265 \
+        --enable-libxcb \
+        --enable-libxml2 \
+        --enable-libxvid \
+        --enable-omx \
+        --enable-shared \
+        --enable-version3 \
+        --enable-libudev \
+        --enable-v4l2-request
+
+	make
+	make tools/qt-faststart
+}
+
+package() {
+	make -C FFmpeg DESTDIR="$pkgdir" install
+	install -D -m755 FFmpeg/tools/qt-faststart -t "${pkgdir}/usr/bin"
+}