import from AUR3

3 files changed, 148 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..f8954d332e5b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,44 @@
+pkgbase = flexget-git
+	pkgdesc = Automate downloading or processing content (torrents, podcasts, etc.) from different sources like RSS-feeds, html-pages, various sites and more.
+	pkgver = 1.2.345.r6166.f624fa6
+	pkgrel = 1
+	url = http://flexget.com/
+	arch = any
+	license = MIT
+	makedepends = python2-paver
+	makedepends = python2-setuptools
+	depends = python2
+	depends = python2-feedparser>=5.1.3
+	depends = python2-sqlalchemy>=0.7.5
+	depends = python2-sqlalchemy<=1.999
+	depends = python2-yaml
+	depends = python2-beautifulsoup4>=4.1
+	depends = python2-beautifulsoup4<4.4
+	depends = python2-guessit>=0.9.3
+	depends = python2-html5lib>=0.11
+	depends = python2-pyrss2gen
+	depends = python2-progressbar
+	depends = python2-rpyc
+	depends = python2-jinja
+	depends = python2-path>=5.1
+	depends = python2-requests>=1.0
+	depends = python2-requests<2.99
+	depends = python2-dateutil1
+	depends = python2-jsonschema>=2.0
+	depends = python2-tvrage
+	depends = python2-tmdb3
+	depends = python2-pynzb
+	depends = python2-apscheduler
+	optdepends = python2-guppy: for memusage plugin
+	optdepends = python2-transmissionrpc: Transmission support
+	optdepends = python2-cherrypy: web interface
+	optdepends = python2-flask: web interface
+	provides = flexget
+	conflicts = flexget
+	source = git+https://github.com/Flexget/Flexget
+	source = flexget.service
+	sha256sums = SKIP
+	sha256sums = e2c3a958ed0c286337cd37fba1d6cbdf4306c57fcddf2b9cc43615ce80ae83aa
+
+pkgname = flexget-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b12c38c3f768
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,90 @@
+# Maintainer: Cedric Girard <girard.cedric@gmail.com>
+# Contributor: G. Richard Bellamy <rbellamy@pteradigm.com>
+# Contributor: Andrea Repetto <andrea.repetto85@gmail.com>
+# Contributor: Bogdan Szczurek <thebodzio@gmail.com>
+
+pkgname=flexget-git
+_pkgname=Flexget
+pkgver=1.2.345.r6166.f624fa6
+pkgrel=1
+
+pkgdesc="Automate downloading or processing content (torrents, podcasts, etc.) from different sources like RSS-feeds, html-pages, various sites and more."
+
+arch=('any')
+url="http://flexget.com/"
+license=('MIT')
+
+depends=('python2'
+         # documented in FlexGet.egg-info/requires.txt
+         'python2-feedparser>=5.1.3'
+         'python2-sqlalchemy>=0.7.5'
+         'python2-sqlalchemy<=1.999'
+         'python2-yaml'
+         'python2-beautifulsoup4>=4.1'
+         'python2-beautifulsoup4<4.4'
+         'python2-guessit>=0.9.3'
+         'python2-html5lib>=0.11'
+         'python2-pyrss2gen' #AUR#
+         'python2-progressbar'
+         'python2-rpyc' #AUR#
+         'python2-jinja'
+         'python2-path>=5.1' #AUR#
+         'python2-requests>=1.0'
+         'python2-requests<2.99'
+         'python2-dateutil1' #AUR#
+         'python2-jsonschema>=2.0' #AUR#
+         'python2-tvrage' #AUR#
+         'python2-tmdb3' #AUR#
+         'python2-pynzb' #AUR#
+         'python2-apscheduler' #AUR#
+         # undocumented in FlexGet.egg-info/requires.txt
+         )
+optdepends=('python2-guppy: for memusage plugin' #AUR#
+            'python2-transmissionrpc: Transmission support' #AUR#
+            'python2-cherrypy: web interface'
+            'python2-flask: web interface'
+            )
+makedepends=('python2-paver'
+             'python2-setuptools'
+             )
+
+provides=('flexget')
+conflicts=('flexget')
+
+source=('git+https://github.com/Flexget/Flexget'
+        'flexget.service'
+        )
+
+sha256sums=('SKIP'
+            'e2c3a958ed0c286337cd37fba1d6cbdf4306c57fcddf2b9cc43615ce80ae83aa')
+
+pkgver() {
+  cd Flexget
+  printf "%s.r%s.%s" "$(grep __version__ flexget/_version.py | sed -r "s/.*([0-9].*\.[0-9].*\.[0-9].*)\.dev.*/\1/g")" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${_pkgname}"
+
+  msg "Patching shebangs to point to python2"
+  sed -i 's/\(python\)/\12/' flexget{,/ui}/__init__.py
+  python2 ./gen-changelog.py
+}
+
+package() {
+  cd "${_pkgname}"
+
+  # Python setup
+  python2 setup.py install --root="${pkgdir}"/ --prefix=/usr --optimize=1 || return 1
+
+  # License
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
+
+  # Make sure the perms allow reading by all
+  chmod ugo+r ${pkgdir}/usr/lib/python2.7/site-packages/FlexGet-1.2.*.dev0-py2.7.egg-info/*
+
+  # install systemd user unit
+  install -Dm644 ../flexget.service "${pkgdir}"/usr/lib/systemd/user/flexget.service
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/flexget.service b/flexget.service
new file mode 100644
index 000000000000..924e0aa96681
--- /dev/null
+++ b/flexget.service
@@ -0,0 +1,14 @@
+[Unit]
+Description = FlexGet Daemon
+After = network.target
+
+[Service]
+Type=simple
+RemainAfterExit=yes
+ExecStart = /usr/bin/flexget daemon start
+ExecStop = /usr/bin/flexget daemon stop
+ExecReload = /usr/bin/flexget daemon reload
+KillMode=process
+
+[Install]
+WantedBy = default.target