0.1.2-2: fix build with newer gcc, new maintainer

Took over maintainership of this package. Style update, as well as
removal of inline vim directives. Removed a superfluous variable for the
download URL, as it's only ever used once. Removed a sneaky gitignore
file.

Quick patch for a missing include. It builds now (with gcc).

Upstream code uses assert(), which can-- and does-- hard-code file paths
into the binary. Makepkg will emit warnings about this. So, append
-DNDEBUG to [C,CXX]FLAGS.

Also, ensure RPATHs are not hard-coded into the binary.

TODO: Doesn't seem to build with clang. Upstream CMakeLists hard-codes,
e.g., arbitrary optimizer flags. This is contrary to ArchLinux packaging
guidelines as it could override end-users' makepkg settings.

Signed-off-by: Joe Baldino <pedanticdm@gmx.us>

4 files changed, 54 insertions, 25 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 23fca91f77e8..fe8acd0f1e7e 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,7 +1,7 @@
 pkgbase = octavia
 	pkgdesc = octobanana's customizable text-based audio visualization interactive application
 	pkgver = 0.1.2
-	pkgrel = 1
+	pkgrel = 2
 	url = https://octobanana.com/software/octavia
 	arch = x86_64
 	license = MIT
@@ -9,8 +9,9 @@ pkgbase = octavia
 	makedepends = cmake
 	depends = boost-libs
 	depends = sfml
-	source = octavia-0.1.2.tar.gz::https://github.com/octobanana/octavia/archive/0.1.2.tar.gz
+	source = octavia-0.1.2.tar.gz::https://github.com/octobanana/octavia/archive/refs/tags/0.1.2.tar.gz
+	source = 0001-ArchLinux-Add-missing-include.patch
 	sha256sums = abc0717312178e24780081418ee7d7578ac3b721bce7fd307853688eb4cd1674
+	sha256sums = c53aa1d86eed2c68731e03a2b8f418cf93858e51cbe7d6cab705207a77b7a933
 
 pkgname = octavia
-
diff --git a/.gitignore b/.gitignore
deleted file mode 100644
index 623d0e70ff3e..000000000000
--- a/.gitignore
+++ /dev/null
@@ -1,5 +0,0 @@
-*
-!.gitignore
-!.SRCINFO
-!PKGBUILD
-
diff --git a/0001-ArchLinux-Add-missing-include.patch b/0001-ArchLinux-Add-missing-include.patch
new file mode 100644
index 000000000000..c79556776067
--- /dev/null
+++ b/0001-ArchLinux-Add-missing-include.patch
@@ -0,0 +1,28 @@
+From 0dde7cb8ffd551517b821fe7a69b243ec5f0338e Mon Sep 17 00:00:00 2001
+From: Joe Baldino <pedanticdm@gmx.us>
+Date: Sun, 6 Feb 2022 22:27:47 +0000
+Subject: [PATCH] [ArchLinux] Add missing include
+
+With upstream warning flags-- includes Werror-- compilation will fail
+due to a missing include. Fixed.
+
+Signed-off-by: Joe Baldino <pedanticdm@gmx.us>
+---
+ src/app/window.hh | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/src/app/window.hh b/src/app/window.hh
+index eab5137cac42..80ca9e76fa91 100644
+--- a/src/app/window.hh
++++ b/src/app/window.hh
+@@ -68,6 +68,7 @@ SOFTWARE.
+ #include <complex>
+ #include <utility>
+ #include <fstream>
++#include <optional>
+ #include <iostream>
+ #include <sstream>
+ #include <algorithm>
+-- 
+2.35.1
+
diff --git a/PKGBUILD b/PKGBUILD
index 0541c62aabf0..9b9f6ca70868 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,32 +1,37 @@
-# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
+# Maintainer: Joe Baldino <pedanticdm@gmx.us>
+# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
 
 pkgname='octavia'
 pkgver=0.1.2
-pkgrel=1
+pkgrel=2
 pkgdesc="octobanana's customizable text-based audio visualization interactive application"
 arch=('x86_64')
 url='https://octobanana.com/software/octavia'
-_url_source='https://github.com/octobanana/octavia'
 license=('MIT')
 depends=('boost-libs' 'sfml')
 makedepends=('boost' 'cmake')
-source=("${pkgname}-${pkgver}.tar.gz::${_url_source}/archive/${pkgver}.tar.gz")
-sha256sums=('abc0717312178e24780081418ee7d7578ac3b721bce7fd307853688eb4cd1674')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/octobanana/octavia/archive/refs/tags/${pkgver}.tar.gz"
+        '0001-ArchLinux-Add-missing-include.patch')
+sha256sums=('abc0717312178e24780081418ee7d7578ac3b721bce7fd307853688eb4cd1674'
+            'c53aa1d86eed2c68731e03a2b8f418cf93858e51cbe7d6cab705207a77b7a933')
+
+prepare() {
+    cd "${pkgname}-${pkgver}"
+    patch --forward --strip=1 \
+          --input="${srcdir}/0001-ArchLinux-Add-missing-include.patch"
+}
 
 build() {
-  export CFLAGS+=" ${CPPFLAGS}"
-  export CXXFLAGS+=" ${CPPFLAGS}"
-  cmake -B 'build' -S "${pkgname}-${pkgver}" \
-    -DCMAKE_BUILD_TYPE='None' \
-    -DCMAKE_INSTALL_PREFIX='/usr' \
-    -Wno-dev
-  make -C 'build'
+    CFLAGS="${CFLAGS} -DNDEBUG" CXXFLAGS="${CXXFLAGS} -DNDEBUG" \
+    cmake -B build -S "${pkgname}-${pkgver}" \
+        -DCMAKE_BUILD_TYPE='None' \
+        -DCMAKE_INSTALL_PREFIX='/usr' \
+        -DCMAKE_SKIP_RPATH='TRUE'
+    cmake --build build
 }
 
 package() {
-  install -Dvm755 "build/${pkgname}" -t "${pkgdir}/usr/bin"
-  install -Dvm644 "${pkgname}-${pkgver}/"{'README.md','doc/help.txt'} -t "${pkgdir}/usr/share/doc/${pkgname}"
-  install -Dvm644 "${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+    install -Dvm755 "build/${pkgname}" -t "${pkgdir}/usr/bin"
+    install -Dvm644 "${pkgname}-${pkgver}/"{'README.md','doc/help.txt'} -t "${pkgdir}/usr/share/doc/${pkgname}"
+    install -Dvm644 "${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
 }
-
-# vim: ts=2 sw=2 et: