Initial commit

2 files changed, 64 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a3860de4f713
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = python-pydecor-git
+	pkgdesc = Easy-peasy Python decorators
+	pkgver = 2.0.0.r11.gd506ca8
+	pkgrel = 1
+	url = https://github.com/mplanchard/pydecor
+	arch = any
+	license = MIT
+	checkdepends = python-pytest
+	makedepends = git
+	makedepends = python-setuptools
+	depends = python
+	depends = python-dill
+	depends = python-six
+	provides = python-pydecor=2.0.0.r11.gd506ca8
+	conflicts = python-pydecor
+	source = git+https://github.com/mplanchard/pydecor.git
+	sha256sums = SKIP
+
+pkgname = python-pydecor-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..942e47eab944
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
+
+_pkgname=pydecor
+pkgname=python-$_pkgname-git
+pkgver=2.0.0.r11.gd506ca8
+pkgrel=1
+pkgdesc="Easy-peasy Python decorators"
+arch=(any)
+url="https://github.com/mplanchard/pydecor"
+license=('MIT')
+depends=('python' 'python-dill' 'python-six')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest')
+provides=("${pkgname%%-git}=$pkgver")
+conflicts=("${pkgname%%-git}")
+source=("git+$url.git")
+
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$_pkgname"
+
+	git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	cd "$_pkgname"
+
+	python setup.py build
+}
+
+check() {
+	cd "$_pkgname"
+
+	PYTHONPATH=src pytest
+}
+
+package() {
+	cd "$_pkgname"
+
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+	install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}