[add] sdl2-hg

2 files changed, 79 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a3af8e027c3b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,31 @@
+pkgbase = sdl2-hg
+	pkgdesc = A library for portable low-level access to video, audio and input (development version)
+	pkgver = 2.0.3.r72.0eed6a72e3c1
+	pkgrel = 1
+	url = http://www.libsdl.org
+	arch = i686
+	arch = x86_64
+	license = ZLIB
+	makedepends = mercurial
+	makedepends = cmake
+	makedepends = alsa-lib
+	makedepends = mesa
+	makedepends = libpulse
+	makedepends = libxrandr
+	makedepends = libxinerama
+	makedepends = libxkbcommon
+	depends = sh
+	depends = libxext
+	depends = libxrender
+	depends = libx11
+	depends = libgl
+	depends = libxcursor
+	optdepends = alsa-lib: ALSA audio driver
+	optdepends = libpulse: PulseAudio audio driver
+	provides = sdl2
+	conflicts = sdl2
+	source = sdl2::hg+http://hg.libsdl.org/SDL
+	md5sums = SKIP
+
+pkgname = sdl2-hg
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..51d4337c81fd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
+# Contributor: Daniel Kirchner <daniel at ekpyron dot rog>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail dot com>
+# Contributor: Chase Geigle <sky at skystrife dot com>
+# Contributor: Axper Jan <483ken at gmail dot com>
+
+pkgname=sdl2-hg
+pkgver=2.0.3.r72.0eed6a72e3c1
+pkgrel=1
+pkgdesc="A library for portable low-level access to video, audio and input (development version)"
+arch=('i686' 'x86_64')
+url="http://www.libsdl.org"
+license=('ZLIB')
+provides=('sdl2')
+conflicts=('sdl2')
+depends=('sh' 'libxext' 'libxrender' 'libx11' 'libgl' 'libxcursor')
+makedepends=('mercurial' 'cmake' 'alsa-lib' 'mesa' 'libpulse' 'libxrandr' 'libxinerama' 'libxkbcommon')
+optdepends=('alsa-lib: ALSA audio driver'
+            'libpulse: PulseAudio audio driver')
+source=(sdl2::"hg+http://hg.libsdl.org/SDL")
+md5sums=('SKIP')
+
+pkgver() {
+  cd sdl2
+  _tag=$(hg tags -q | sort -r | grep release- | head -n1)
+  _commits=$(hg log --template "{node}\n" -r $_tag:tip | wc -l)
+  echo "${_tag/release-}.r$_commits.$(hg identify -i)"
+}
+
+prepare() {
+  # reset build folder
+  rm -rf build
+  mkdir build
+}
+
+build() {
+  cd build
+
+  cmake ../sdl2 -DCMAKE_INSTALL_PREFIX=/usr -DARTS=OFF -DNAS=OFF -DESD=OFF \
+                -DSDL_STATIC=OFF -DRPATH=OFF -DVIDEO_WAYLAND=OFF
+  make
+}
+
+package() {
+  make -C build DESTDIR="$pkgdir/" install
+
+  install -Dm644 sdl2/COPYING.txt "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}