initial commit

2 files changed, 59 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e2c7bd28b330
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = tree-sitter-scala-git
+	pkgdesc = Scala grammar for tree-sitter
+	pkgver = 0.19.0.r5.gfb23ed9
+	pkgrel = 1
+	url = https://github.com/tree-sitter/tree-sitter-scala
+	arch = x86_64
+	groups = tree-sitter-grammars
+	license = MIT
+	makedepends = git
+	makedepends = tree-sitter
+	makedepends = npm
+	depends = glibc
+	provides = tree-sitter-scala
+	conflicts = tree-sitter-scala
+	source = tree-sitter-scala-git::git+https://github.com/tree-sitter/tree-sitter-scala
+	sha256sums = SKIP
+
+pkgname = tree-sitter-scala-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..320e6be46670
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-scala-git
+pkgver=0.19.0.r5.gfb23ed9
+pkgrel=1
+pkgdesc="Scala grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/tree-sitter/tree-sitter-scala"
+license=('MIT')
+groups=('tree-sitter-grammars')
+depends=('glibc')
+makedepends=('git' 'tree-sitter' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
+}
+
+prepare() {
+	cd "$pkgname"
+	tree-sitter generate
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c scanner.c
+	cc $LDFLAGS -shared parser.o scanner.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-scala.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-scala.so" "$pkgdir/usr/share/nvim/runtime/parser/scala.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}