initial commit

2 files changed, 44 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..c79496bec208
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = vim-switch-git
+	pkgdesc = Switches segments of text with predefined replacements
+	pkgver = 0.3.0.r128.g900c5d3
+	pkgrel = 1
+	url = https://github.com/andrewradev/switch.vim
+	arch = any
+	groups = vim-plugins
+	license = MIT
+	makedepends = git
+	depends = vim-plugin-runtime
+	provides = vim-switch
+	conflicts = vim-switch
+	source = vim-switch-git::git+https://github.com/andrewradev/switch.vim
+	md5sums = SKIP
+
+pkgname = vim-switch-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..581369188604
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,28 @@
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+
+pkgname=vim-switch-git
+pkgver=0.3.0.r128.g900c5d3
+pkgrel=1
+pkgdesc="Switches segments of text with predefined replacements"
+arch=('any')
+url="https://github.com/andrewradev/switch.vim"
+license=('MIT')
+groups=('vim-plugins')
+depends=('vim-plugin-runtime')
+makedepends=('git')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+md5sums=('SKIP')
+
+pkgver() {
+	git -C "$pkgname" describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
+}
+
+package() {
+	cd "$pkgname"
+	find autoload doc ftplugin plugin spec \
+		-type f -exec install -Dm644 '{}' "$pkgdir/usr/share/vim/vimfiles/{}" \;
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}